File: genvm-scan.l

package info (click to toggle)
gnu-smalltalk 3.2.4-2.1
  • links: PTS, VCS
  • area: main
  • in suites: jessie, jessie-kfreebsd
  • size: 32,688 kB
  • ctags: 14,104
  • sloc: ansic: 87,424; sh: 22,729; asm: 8,465; perl: 4,513; cpp: 3,548; xml: 1,669; awk: 1,581; yacc: 1,357; makefile: 1,237; lisp: 855; lex: 843; sed: 258; objc: 124
file content (273 lines) | stat: -rw-r--r-- 5,968 bytes parent folder | download | duplicates (6)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162
163
164
165
166
167
168
169
170
171
172
173
174
175
176
177
178
179
180
181
182
183
184
185
186
187
188
189
190
191
192
193
194
195
196
197
198
199
200
201
202
203
204
205
206
207
208
209
210
211
212
213
214
215
216
217
218
219
220
221
222
223
224
225
226
227
228
229
230
231
232
233
234
235
236
237
238
239
240
241
242
243
244
245
246
247
248
249
250
251
252
253
254
255
256
257
258
259
260
261
262
263
264
265
266
267
268
269
270
271
272
273
/******************************** -*- C -*- ****************************
 *
 *	GNU Smalltalk genvm tool - lexical analyzer
 *
 ***********************************************************************/

/***********************************************************************
 *
 * Copyright 2003, 2006 Free Software Foundation, Inc.
 * Written by Paolo Bonzini.
 *
 * This file is part of GNU Smalltalk.
 *
 * GNU Smalltalk is free software; you can redistribute it and/or modify it
 * under the terms of the GNU General Public License as published by the Free
 * Software Foundation; either version 2, or (at your option) any later 
 * version.
 * 
 * Linking GNU Smalltalk statically or dynamically with other modules is
 * making a combined work based on GNU Smalltalk.  Thus, the terms and
 * conditions of the GNU General Public License cover the whole
 * combination.
 *
 * In addition, as a special exception, the Free Software Foundation
 * give you permission to combine GNU Smalltalk with free software
 * programs or libraries that are released under the GNU LGPL and with
 * independent programs running under the GNU Smalltalk virtual machine.
 *
 * You may copy and distribute such a system following the terms of the
 * GNU GPL for GNU Smalltalk and the licenses of the other code
 * concerned, provided that you include the source code of that other
 * code when and as the GNU GPL requires distribution of source code.
 *
 * Note that people who make modified versions of GNU Smalltalk are not
 * obligated to grant this special exception for their modified
 * versions; it is their choice whether to do so.  The GNU General
 * Public License gives permission to release a modified version without
 * this exception; this exception also makes it possible to release a
 * modified version which carries forward this exception.
 *
 * GNU Smalltalk is distributed in the hope that it will be useful, but WITHOUT
 * ANY WARRANTY; without even the implied warranty of MERCHANTABILITY or 
 * FITNESS FOR A PARTICULAR PURPOSE.  See the GNU General Public License for
 * more details.
 * 
 * You should have received a copy of the GNU General Public License along with
 * GNU Smalltalk; see the file COPYING.  If not, write to the Free Software
 * Foundation, 51 Franklin Street, Fifth Floor, Boston, MA 02110-1301, USA.  
 *
 ***********************************************************************/

%x C_ARGS
%x C_CODE
%x C_COMMENT
%x C_STRING
%x C_CHAR
%x CPP_CODE

%option nounput
%option noyywrap
%option never-interactive

%{
#include "genvm.h"
#include "genvm-parse.h"

static int from = 0, depth = 0;
#if !defined YY_FLEX_SUBMINOR_VERSION || YY_FLEX_SUBMINOR_VERSION < 31
int yylineno = 1;
#endif
%}

%%

<INITIAL,C_COMMENT>{
  /* All states know how to count lines.  */
  \n+				{
    yylineno += yyleng;
  }

  [ \t\f]+			{
  }
}

<INITIAL>{
  table				return VM_TABLE;
  operation			return VM_OPERATION;
  bytecode			return VM_BYTECODE;

  ^[ \t]*#                     {
    printf ("%s", yytext);
    from = YY_START;
    BEGIN (CPP_CODE);
  }

  "/*"                          {
    from = YY_START;
    BEGIN (C_COMMENT);
  }

  [1-9][0-9]*			|
  0x[0-9A-Fa-f]+		|
  0[0-7]*			{
    yylval.num = strtol(yytext, NULL, 0);
    return (NUMBER);
  }

  \.\.				return VM_DOTS;
  --				return VM_MINUSMINUS;

  [a-zA-Z_][a-zA-Z_0-9]*	yylval.text = strdup (yytext); return ID;

  "("				{
    yylval.ctext = "(";
    if (c_args_on_paren)
      BEGIN (C_ARGS);
    c_args_on_paren = false;
    depth = 1;
    return '(';
  }

  "{"[\n]*			{
    yylineno += yyleng - 1;
    yylval.ctext = "{\n      ";
    if (c_code_on_brace)
      BEGIN (C_CODE);
    c_code_on_brace = false;
    depth = 1;
    return '{';
  }

  .				return *yytext;
}

<C_ARGS,C_CODE>{
  /* Learn how to skip strings.  */
  "'"                           {
    yylval.text =  yytext;
    from = YY_START;
    BEGIN (C_CHAR);
    return (EXPR);
  }

  "\""                          {
    yylval.text =  yytext;
    from = YY_START;
    BEGIN (C_STRING);
    return (EXPR);
  }
}

<C_ARGS>{
  [ \t]*"("             {
    depth++;
    yylval.ctext = yytext;
    return EXPR;
  }

  ","[ \t]*             {
    yylval.ctext = yytext;
    return ',';
  }

  ")"[ \t]*             {
    if (!--depth)
      {
        BEGIN (INITIAL);
        return ')';
      }

    yylval.ctext = yytext;
    return EXPR;
  }

  [^(,)'"\n]*	        {
    yylval.ctext = yytext;
    return (EXPR);
  }
}
  
<C_CODE>{
  [ \t]*"{"             {
    depth++;
    yylval.ctext = yytext;
    return EXPR;
  }

  [ \t]*"}"             {
    if (!--depth)
      {
        BEGIN (INITIAL);
        return '}';
      }

    yylval.ctext = yytext;
    return EXPR;
  }

  \n                    {
    yylineno++;
    yylval.ctext = "\n      ";
    return (EXPR);
  }

  [^{}'"\n]*	        {
    yylval.ctext = yytext;
    return (EXPR);
  }
}
  
<C_CHAR>{
  /* Characters and strings have different terminations...  */
  "'"                           {
    yylval.text =  yytext;
    BEGIN (from);
    return (EXPR);
  }
}

<C_STRING>{
  "\""                          {
    yylval.text =  yytext;
    BEGIN (from);
    return (EXPR);
  }
}

<C_STRING,C_CHAR>{
  /* ... but otherwise they're the same.  */
  \\.                           {
    yylineno += (yytext[1] == '\n');
    yylval.text =  yytext;
    return (EXPR);
  }

  .                             {
    yylineno += (yytext[0] == '\n');
    yylval.text =  yytext;
    return (EXPR);
  }
}

<C_COMMENT>{
  /* And so are comments.  */
  [^*\n]*"*"*\n			{
    yylineno++;
  }

  [^*\n]*"*"+[^/*]		{
  }

  [^*\n]*"*"+"/"		{
    BEGIN (from);
  }
}

<CPP_CODE>{
  /* And preprocessor code; this however is printed to stdout.  */
  [^\n]*"\\"[ \t]*\n?		{
    printf("%s", yytext);
    yylineno += yytext[yyleng - 1] == '\n';
  }
  [^\n]+$			{
    printf("%s", yytext);
  }
  \n+				{
    printf("%s", yytext);
    yylineno += yyleng;
    BEGIN (from);
  }
}

%%