1 2 3 4 5 6 7 8 9 10 11 12 13 14 15 16 17 18 19 20 21 22 23 24 25 26 27 28 29 30 31 32 33 34 35 36 37 38 39 40 41 42 43 44 45 46 47 48 49 50 51 52 53 54 55 56 57 58 59 60 61 62 63 64 65 66 67 68
|
$!
$! GNUPLOT make program for VMS, Vers. 1.2, 1996/07/03
$! (Rolf Niepraschk, niepraschk@ptb.de)
$!
$! This command procedure compiles and links GNUPLOT with MMS or MMK or
$! invokes the dcl procedure BUILDVMS.COM
$!
$! Usage: @MAKE_VMS P1 [P2]
$! P1 = compiler ("DECC" or "VAXC" or "GNUC" or special make file if P2 = "")
$! default is "DECC"
$! P2 = special make file (eg. for testing), default is "DESCRIP.MMS"
$!
$ SAY = "WRITE SYS$OUTPUT"
$ AXP = 0
$ IF F$GETSYI("ARCH_TYPE") .NE. 1 THEN AXP = 1
$!
$ P1 = F$EDIT(P1,"UPCASE")
$ IF P2 .NES. ""
$ THEN D_FILE = P2
$ ELSE D_FILE = "MAKEFILE.VMS"
$ ENDIF
$!
$ COMPILER = ""
$ IF P1 .EQS. "DECC" .OR. P1 .EQS. ""
$ THEN
$ DECC = 1
$ COMPILER = "DECC"
$ ELSE
$ IF P1 .EQS. "VAXC"
$ THEN
$ VAXC = 1
$ COMPILER = "VAXC"
$ ELSE
$ IF P1 .EQS. "GNUC"
$ THEN
$ GNUC = 1
$ COMPILER = "GNUC"
$ ENDIF
$ ENDIF
$ ENDIF
$ IF COMPILER .EQS. ""
$ THEN
$ DECC = 1
$ COMPILER = "DECC"
$ D_FILE = P1
$ ENDIF
$!
$ DCL_PROC = "BUILDVMS.COM"
$ COMMAND = ""
$ IF F$TYPE(MMK) .NES. ""
$ THEN COMMAND = "MMK"
$ ELSE
$ IF F$SEARCH("SYS$SYSTEM:MMS.EXE") .NES. "" THEN COMMAND = "MMS"
$ ENDIF
$!
$ MACRO = ""
$ IF AXP THEN MACRO = "/MACRO=__ALPHA__=1"
$ IF COMMAND .NES. ""
$ THEN
$ SAY "Make Gnuplot with ''COMMAND' and ''COMPILER'."
$ SAY ""
$ 'COMMAND' /DESCRIPTION='D_FILE' 'MACRO' /IGNORE=WARNING
$ ELSE
$ SAY "Make Gnuplot with DCL procedure ''DCL_PROC'."
$ SAY ""
$ @'DCL_PROC'
$ ENDIF
$ EXIT
|