1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
|
# Demonstrate use of user variables
# MOUSE_BUTTON MOUSE_X MOUSE_Y MOUSE_X2 MOUSE_Y2
# and built-in function exists("<varname>")
#
reset
set title "Scripted zoom using exported MOUSE variables"
set samples 200
set label 3 at graph 0.1, graph 0.9 tc lt 3
set label 3 "Click on one corner of desired zoom region"
plot sin(13*besj0(x))/x
#
pause mouse "Click on one corner of desired zoom region"
#
if (exists("MOUSE_BUTTON")) \
print "Mouse button ", MOUSE_BUTTON, " at ", MOUSE_X, " ", MOUSE_Y ;\
set label 1 sprintf(" Mouse button %d\n clicked here!", MOUSE_BUTTON) ;\
set label 1 at MOUSE_X, MOUSE_Y ;\
set label 1 point pt 6 ps 6 ;\
replot ;\
else \
print "No mouse click?" ;\
exit ;
#
BOT_X = MOUSE_X
BOT_Y = MOUSE_Y
set label 3 "Click on diagonal corner of desired zoom region"
replot
#
pause mouse "Click on diagonal corner of desired zoom region"
#
if (exists("MOUSE_BUTTON")) \
print "Mouse button ", MOUSE_BUTTON, " at ", MOUSE_X, " ", MOUSE_Y ;\
set label 2 sprintf(" Mouse button %d\n clicked here!", MOUSE_BUTTON) ;\
set label 2 at MOUSE_X, MOUSE_Y ;\
set label 2 point pt 6 ps 6 ;\
replot ;\
else \
print "No mouse click?" ;\
exit ;
#
#
TOP_X = MOUSE_X
TOP_Y = MOUSE_Y
#
set label 3 "Plot will zoom in 3 seconds"
replot
pause 3
#
set xrange [ BOT_X : TOP_X ]
set yrange [ BOT_Y : TOP_Y ]
set grid
#
unset label 1
unset label 2
unset label 3
set label 4 sprintf("zoom x range %.3f to %.3f",BOT_X,TOP_X)
set label 5 sprintf("zoom y range %.3f to %.3f",TOP_X,TOP_Y)
set label 4 at graph 0.1, graph 0.95 tc lt 3
set label 5 at graph 0.1, graph 0.90 tc lt 3
replot
#
print "Zoomed to xrange ",BOT_X," ",TOP_X
print "Zoomed to yrange ",BOT_Y," ",TOP_Y
#
pause -1 "Type <cr> to continue"
reset
|
