1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162
163
164
165
166
167
168
169
170
171
172
173
174
175
176
177
178
179
180
181
182
183
184
185
186
187
188
189
190
191
192
193
194
195
196
197
198
199
200
201
202
203
204
205
206
207
208
209
210
211
212
213
214
215
216
217
218
219
|
# Test of color modes for pm3d palettes.
#
# Multiplot with some of the recommended rgbformulae palettes
#
set view map
set style function pm3d
set multiplot layout 3,3 \
title "Palettes according to 'help palette rgbformulae'"
g(x)=x
set xrange [0:1]; set xtics 0.2 scale 1.5 nomirror; set mxtics 2
# set palette maxcolors 128
unset colorbox; unset key; set tics out; unset ytics
set palette rgb 7,5,15; set title "traditional pm3d\n(black-blue-red-yellow)"; splot g(x)
set palette rgb 3,11,6; set title "green-red-violet"; splot g(x)
set palette rgb 23,28,3; set title "ocean (green-blue-white)\ntry also other permutations"; splot g(x)
set palette rgb 21,22,23; set title "hot (black-red-yellow-white)"; splot g(x)
set palette rgb 30,31,32; set title "color printable on gray\n(black-blue-violet-yellow-white)"; splot g(x)
set palette rgb 33,13,10; set title "rainbow (blue-green-yellow-red)"; splot g(x)
set palette rgb 34,35,36; set title "AFM hot (black-red-yellow-white)"; splot g(x)
set palette model HSV
set palette rgb 3,2,2; set title "HSV model\n(red-yellow-green-cyan-blue-magenta-red)"; splot g(x)
set pal gray; set title "gray palette"; splot g(x)
unset multiplot
reset
pause -1 "Hit return to continue"
#
# Gradient Palettes
#
set view map
set style function pm3d
set palette color
f(x)=(x+10)/20
set cbrange [f(-10):f(10)] # [0:1]
set xrange [-10:10]
set yrange [*:*]
set xtics 2
set cbtics 0.1
set format cb "%3.1f"
unset ztics
unset ytics
set samples 101
set isosamples 2
unset key
set palette model RGB
set palette defined
set title "set palette defined"
splot f(x)
pause -1 "Hit return to continue"
set palette defined (0 0 0 0, 1 0 0 1, 3 0 1 0, 4 1 0 0, 6 1 1 1)
set title 'set palette defined (0 0 0 0, 1 0 0 1, 3 0 1 0, 4 1 0 0, 6 1 1 1)'
splot f(x)
pause -1 "Hit return to continue"
set palette defined ( 0 "green", 1 "blue", 2 "red", 3 "orange" )
set title 'set palette defined ( 0 "green", 1 "blue", 2 "red", 3 "orange" )'
splot f(x)
pause -1 "Hit return to continue"
set palette defined ( 20 "#101010", 30 "#ff0000", 40 "#00ff00", 50 "#e0e0e0" )
set title 'set palette defined ( 20 "#101010", 30 "#ff0000", 40 "#00ff00", 50 "#e0e0e0" )'
splot f(x)
pause -1 "Hit return to continue"
set palette defined ( 0 0 0 0, 1 1 1 1 )
set title 'set palette defined ( 0 0 0 0, 1 1 1 1 )'
splot f(x)
pause -1 "Hit return to continue"
set palette model HSV defined ( 0 0 1 1, 1 1 1 1 )
set title 'set palette model HSV defined ( 0 0 1 1, 1 1 1 1 )'
splot f(x)
pause -1 "Hit return to continue"
set palette model RGB
set palette model RGB defined (0 "green", 1 "dark-green", 1 "yellow", 2 "dark-yellow", 2 "red", 3 "dark-red" )
set title "set palette model RGB defined\n(0 'green', 1 'dark-green', 1 'yellow', 2 'dark-yellow', 2 'red', 3 'dark-red' )"
splot f(x)
pause -1 "Hit return to continue"
set palette model RGB
set title 'set palette file "-" (file with 3 columns)'
set palette file "-"
0 0 0
0 0 1
0 1 0
1 0 0
1 1 1
e
splot f(x)
pause -1 "Hit return to continue"
set title 'set palette file (2 columns: gray + packed RGB)'
set datafile columnhead
$COLORS << EOD
gray colorname
10 black
20 blue
40 green
60 red
70 white
EOD
set palette file $COLORS using 1:(rgbcolor(strcol(2)))
test palette
pause -1 "Hit return to continue"
set title 'set palette file "-" using 1:2:($1+$2)/2'
set palette file "-" using ($0):1:2:(($1+$2)/2)
0 0
0 1
1 0
1 1
e
splot f(x)
pause -1 "Hit return to continue"
#
# Color Models
#
set palette color
set view map
set xrange [-10:10]
unset ztics
unset ytics
set samples 101
set isosamples 2
set xtics 2
set palette rgbformulae 7,5,15
set palette model RGB rgbformulae 7,5,15
set title "set palette model RGB rgbformulae 7,5,15"
splot f(x)
pause -1 "Hit return to continue"
set palette model HSV rgbformulae 7,5,15
set title "set palette model HSV rgbformulae 7,5,15"
splot f(x)
pause -1 "Hit return to continue"
set palette model CMY rgbformulae 7,5,15
set title "set palette model CMY rgbformulae 7,5,15"
splot f(x)
pause -1 "Hit return to continue"
set palette model HSV rgbformulae 3,2,2
set title "set palette model HSV rrgbformulae 3,2,2"
splot f(x)
pause -1 "Hit return to continue"
#
# User Defined Functions
#
set palette color
set view map
set cbrange [f(-10):f(10)]
set xrange [-10:10]
set yrange [0:1]
unset ztics
unset ytics
set samples 101
set isosamples 2
set xtics 2
set palette model RGB
set palette functions gray, gray, gray
set title "set palette functions gray, gray, gray"
splot f(x)
pause -1 "Hit return to continue"
set palette functions sqrt(gray), gray**3, sin(gray*2*pi)
set title 'set palette functions sqrt(gray), gray**3, sin(gray*2*pi) <--> 7,5,15'
splot f(x)
pause -1 "Hit return to continue"
set palette rgbformulae 7,5,15
set title 'set palette rgbformulae 7,5,15'
splot f(x)
pause -1 "Hit return to continue"
theta(x) = x<0 ? 0 : 1
r(x) = 4*x*(1-theta(x-0.25))
g(x) = 0.5*theta(x-0.25)*(1-theta(x-0.5))
b(x) = x
set palette model RGB functions r(gray),g(gray),b(gray)
set title "set palette model RGB functions\n4*x*(1-theta(x-0.25)), 0.5*theta(x-0.25)*(1-theta(x-0.5)), x"
splot f(x)
pause -1 "Hit return to continue"
unset datafile
reset
|
