1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162
163
164
165
166
167
168
169
170
171
172
173
174
175
176
177
178
179
180
181
182
183
184
185
186
187
188
189
190
191
192
193
194
195
196
197
198
199
200
201
202
203
204
205
206
207
208
209
210
211
212
213
214
215
216
217
218
219
220
221
222
223
224
225
226
227
228
229
230
231
232
233
|
# SPDX-License-Identifier: MIT
# SPDX-FileCopyrightText: 2024 Philip Chimento <philip.chimento@gmail.com>
project(
'gobject-introspection-tests', 'c', version: 'unversioned',
meson_version: '>= 0.61',
default_options: ['c_std=c99', 'warning_level=2']
)
gnome = import('gnome')
cc = meson.get_compiler('c')
msvc = cc.get_argument_syntax() == 'msvc'
build_cairo = get_option('cairo')
install_dir = get_option('install_dir')
install = (install_dir != '')
glib_version = '>= 2.66.8'
glib_dep = dependency('glib-2.0', version: glib_version)
gobject_dep = dependency('gobject-2.0', version: glib_version)
gio_dep = dependency('gio-2.0', version: glib_version)
if build_cairo
cairo_dep = dependency('cairo', required: not msvc)
cairo_gobject_dep = dependency('cairo-gobject', required: not msvc)
# We might need to look for the headers and libs for Cairo manually on
# MSVC/clang-cl builds...
if not cairo_dep.found()
cairo_dep = cc.find_library(
'cairo',
has_headers: ['cairo.h'],
required: true
)
endif
if not cairo_gobject_dep.found()
cairo_gobject_dep = cc.find_library(
'cairo-gobject',
has_headers: ['cairo-gobject.h'],
required: true
)
endif
endif
args = []
if host_machine.system() == 'windows'
extern_def = '__declspec(dllexport) extern'
else
extern_def = '__attribute__((visibility("default"))) extern'
endif
args += ['-DGI_TEST_EXTERN=@0@'.format(extern_def)]
if not build_cairo
args += ['-DGI_TEST_DISABLE_CAIRO']
endif
add_project_arguments(args, language: 'c')
utility_sources = ['utility.c', 'utility.h']
regress_sources = [
'annotation.c',
'annotation.h',
'drawable.c',
'drawable.h',
'foo.c',
'foo.h',
'regress.c',
'regress.h',
'regressextra.c',
'regressextra.h',
]
regress_unix_sources = ['regress-unix.c', 'regress-unix.h']
warnlib_sources = ['warnlib.c', 'warnlib.h']
gimarshallingtests_sources = [
'gimarshallingtests.c',
'gimarshallingtests.h',
'gimarshallingtestsextra.c',
'gimarshallingtestsextra.h',
]
libutility = library(
'utility',
utility_sources,
dependencies: [glib_dep, gobject_dep],
gnu_symbol_visibility: 'hidden',
install: install,
install_dir: install_dir,
)
utility_gir = gnome.generate_gir(
libutility,
sources: utility_sources,
includes: ['GObject-2.0'],
namespace: 'Utility',
nsversion: '1.0',
symbol_prefix: 'utility_',
header: 'utility.h',
fatal_warnings: get_option('werror'),
install_gir: false,
install_typelib: install,
install_dir_typelib: install_dir,
)
utility_typelib = utility_gir[1]
regress_dependencies = [glib_dep, gobject_dep, gio_dep]
regress_gir_includes = ['Gio-2.0', utility_gir[0]]
if build_cairo
regress_gir_includes += 'cairo-1.0'
regress_dependencies += [cairo_dep, cairo_gobject_dep]
endif
libregress = library(
'regress',
regress_sources + regress_unix_sources,
dependencies: regress_dependencies,
gnu_symbol_visibility: 'hidden',
install: install,
install_dir: install_dir,
override_options: ['unity=off'],
)
regress_gir = gnome.generate_gir(
libregress,
sources: regress_sources,
includes: regress_gir_includes,
namespace: 'Regress',
nsversion: '1.0',
identifier_prefix: 'Regress',
symbol_prefix: 'regress_',
header: 'regress.h',
extra_args: ['--warn-all'],
include_directories: meson.current_build_dir(),
fatal_warnings: get_option('werror'),
install_gir: false,
install_typelib: install,
install_dir_typelib: install_dir,
)
regress_typelib = regress_gir[1]
if host_machine.system() != 'windows'
regress_unix_gir = gnome.generate_gir(
libregress,
sources: regress_unix_sources,
includes: regress_gir_includes,
namespace: 'RegressUnix',
nsversion: '1.0',
symbol_prefix: 'regress_unix_',
header: 'regress-unix.h',
include_directories: meson.current_build_dir(),
fatal_warnings: get_option('werror'),
install_gir: false,
install_typelib: install,
install_dir_typelib: install_dir,
)
else
regress_unix_gir = [disabler(), disabler()]
endif
regress_unix_typelib = regress_unix_gir[1]
libwarnlib = library(
'warnlib',
warnlib_sources,
dependencies: [glib_dep, gobject_dep, gio_dep],
gnu_symbol_visibility: 'hidden',
install: install,
install_dir: install_dir,
)
# This should have --warn-all turned off, but there is currently no way to do so
# in gnome.generate_gir(). See https://github.com/mesonbuild/meson/issues/5876
warnlib_gir = gnome.generate_gir(
libwarnlib,
includes: ['Gio-2.0'],
sources: warnlib_sources,
namespace: 'WarnLib',
nsversion: '1.0',
symbol_prefix: 'warnlib_',
header: 'warnlib.h',
fatal_warnings: false,
install_gir: false,
install_typelib: install,
install_dir_typelib: install_dir,
)
warnlib_typelib = warnlib_gir[1]
libgimarshallingtests = library(
'gimarshallingtests',
gimarshallingtests_sources,
dependencies: [glib_dep, gobject_dep, gio_dep],
gnu_symbol_visibility: 'hidden',
install: install,
install_dir: install_dir,
)
gimarshallingtests_gir = gnome.generate_gir(
libgimarshallingtests,
sources: gimarshallingtests_sources,
includes: ['Gio-2.0'],
namespace: 'GIMarshallingTests',
nsversion: '1.0',
symbol_prefix: 'gi_marshalling_tests_',
fatal_warnings: get_option('werror'),
install_gir: false,
install_typelib: install,
install_dir_typelib: install_dir,
)
gimarshallingtests_typelib = gimarshallingtests_gir[1]
deps = [glib_dep]
if build_cairo
deps += [cairo_dep, cairo_gobject_dep]
endif
locations = []
foreach dep: deps
if dep.type_name() == 'pkgconfig'
locations += 'in @0@'.format(dep.get_variable(pkgconfig: 'prefix'))
else
locations += dep.type_name()
endif
endforeach
summary({
'Build type': get_option('buildtype'),
'Install test libraries': install,
'GLib': '@0@ (@1@)'.format(glib_dep.version(), locations[0]),
'Cairo support': build_cairo,
}, bool_yn: true)
if build_cairo
summary({
'Cairo': '@0@ (@1@)'.format(cairo_dep.version(), locations[1]),
'Cairo-gobject': '@0@ (@1@)'.format(cairo_gobject_dep.version(), locations[2])
})
endif
if install
summary('Install location', install_dir)
endif
|
