1 2 3 4 5 6 7 8 9 10 11 12 13 14 15 16 17 18 19 20 21 22 23 24 25 26 27 28 29 30 31 32 33 34 35 36 37 38 39 40 41 42 43 44 45 46 47 48 49 50 51 52 53 54 55 56 57 58 59 60 61 62 63 64 65
|
; GNU Prolog WIN32 installation script for Inno Setup 4
[Setup]
AppName=GNU Prolog
AppVerName=GNU Prolog version 1.3.0
AppVersion=1.3.0
AppPublisher=Daniel Diaz
AppPublisherURL=http://www.gprolog.org
AppSupportURL=http://www.gprolog.org
AppUpdatesURL=http://www.gprolog.org
DefaultDirName={sd}\GNU-Prolog
DefaultGroupName=GNU Prolog
AllowNoIcons=yes
SourceDir=\gprolog_win32
OutputDir=
OutputBaseFileName=setup-gprolog-1.3.0
; TO DO: create an association for .pl and .pro files
; ChangesAssociations=yes
; uncomment the following line if you want your installation to run on NT 3.51 too.
; MinVersion=4,3.51
[Tasks]
Name: "desktopicon"; Description: "Create a &desktop icon"; GroupDescription: "Additional icons:"; MinVersion: 4,4
[Files]
Source: "*.*"; DestDir: "{app}"; Flags: ignoreversion
Source: "bin\*.*"; DestDir: "{app}\bin"; Flags: ignoreversion
Source: "lib\*.*"; DestDir: "{app}\lib"; Flags: ignoreversion
Source: "lib\*.dll"; DestDir: "{app}\bin"; Flags: ignoreversion skipifsourcedoesntexist
Source: "include\*.*"; DestDir: "{app}\include"; Flags: ignoreversion
Source: "doc\*.*"; DestDir: "{app}\doc"; Flags: ignoreversion
Source: "doc\html_node\*.*"; DestDir: "{app}\doc\html_node"; Flags: ignoreversion
Source: "ExamplesPl\*.*"; DestDir: "{app}\ExamplesPl"; Flags: ignoreversion
Source: "ExamplesFD\*.*"; DestDir: "{app}\ExamplesFD"; Flags: ignoreversion
Source: "ExamplesC\*.*"; DestDir: "{app}\ExamplesC"; Flags: ignoreversion
[INI]
Filename: "{app}\gprolog.url"; Section: "InternetShortcut"; Key: "URL"; String: "http://www.gprolog.org"
[Icons]
Name: "{group}\GNU Prolog"; Filename: "{app}\bin\gprolog.exe"
Name: "{group}\Help"; Filename: "{app}\doc\manual.chm"
Name: "{group}\Html Manual"; Filename: "{app}\doc\html_node\index.html"
Name: "{group}\The GNU Prolog Web Site"; Filename: "{app}\gprolog.url"
Name: "{group}\Uninstall GNU Prolog"; Filename: "{uninstallexe}"
Name: "{userdesktop}\GNU Prolog"; Filename: "{app}\bin\gprolog.exe"; MinVersion: 4,4; Tasks: desktopicon
[Registry]
Root: HKCU; Subkey: "Software\GnuProlog"; ValueType: string; ValueName: "Version"; ValueData: "1.3.0"
Root: HKCU; Subkey: "Software\GnuProlog"; ValueType: string; ValueName: "RootPath"; ValueData: "{app}"
[Run]
Filename: "{app}\bin\create_bat.exe"; Parameters: """{sd}"" ""{app}"" install"; Description: "Create {sd}\gprologvars.bat and update autoexec.bat"
Filename: "{app}\bin\gprolog.exe"; Description: "Launch GNU Prolog"; Flags: nowait postinstall skipifsilent
[UninstallRun]
Filename: "{app}\bin\create_bat.exe"; Parameters: """{sd}"" ""{app}"" uninstall"
[UninstallDelete]
Type: files; Name: "{app}\gprolog.url"
|