File: signing.gradle

package info (click to toggle)
groovy 2.4.21-1
  • links: PTS, VCS
  • area: main
  • in suites: bookworm, bullseye, sid
  • size: 30,708 kB
  • sloc: java: 157,114; xml: 728; sh: 357; makefile: 64; javascript: 15
file content (90 lines) | stat: -rw-r--r-- 3,571 bytes parent folder | download | duplicates (3)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
/*
 *  Licensed to the Apache Software Foundation (ASF) under one
 *  or more contributor license agreements.  See the NOTICE file
 *  distributed with this work for additional information
 *  regarding copyright ownership.  The ASF licenses this file
 *  to you under the Apache License, Version 2.0 (the
 *  "License"); you may not use this file except in compliance
 *  with the License.  You may obtain a copy of the License at
 *
 *    http://www.apache.org/licenses/LICENSE-2.0
 *
 *  Unless required by applicable law or agreed to in writing,
 *  software distributed under the License is distributed on an
 *  "AS IS" BASIS, WITHOUT WARRANTIES OR CONDITIONS OF ANY
 *  KIND, either express or implied.  See the License for the
 *  specific language governing permissions and limitations
 *  under the License.
 */

allprojects {
    apply plugin: 'signing'
    signing {
        required {
            rootProject.ext.isReleaseVersion &&
                    (gradle.taskGraph.hasTask(':artifactoryPublish') || rootProject.hasProperty('forceSign'))
        }
    }
}

gradle.taskGraph.whenReady { taskGraph ->
    if (project.ext.isReleaseVersion &&
            (taskGraph.hasTask(':artifactoryPublish') || project.hasProperty('forceSign'))) {
        // Use Java 6's console or Swing to read input (not suitable for CI)
        if (!project.hasProperty('signing.keyId') ||
                !project.hasProperty('signing.secretKeyRingFile') ||
                !project.hasProperty('signing.password')) {
            printf "\n\nWe have to sign some things in this build." +
                    "\n\nPlease enter your signing details.\n\n"
            System.out.flush()

            if (!project.hasProperty('signing.keyId')) {
                project.ext.'signing.keyId' = promptUser('PGP Key Id')
            }
            if (!project.hasProperty('signing.secretKeyRingFile')) {
                project.ext.'signing.secretKeyRingFile' = promptUser('PGP Secret Key Ring File (absolute path)')
            }
            if (!project.hasProperty('signing.password')) {
                project.ext.'signing.password' = promptUser('PGP Private Key Password')
            }

            printf "\nThanks.\n\n"
            System.out.flush()
        }
        allprojects { ext.'signing.keyId' = project.getProperty('signing.keyId') }
        allprojects { ext.'signing.secretKeyRingFile' = project.getProperty('signing.secretKeyRingFile') }
        allprojects { ext.'signing.password' = project.getProperty('signing.password') }
    }
}

def promptUser(String prompt) {
    def response = ''
    if (System.console() == null) {
        new groovy.swing.SwingBuilder().edt {
            dialog(modal: true, // pause build
                    title: 'Reponse required', // dialog title
                    alwaysOnTop: true,
                    resizable: false,
                    locationRelativeTo: null, // centered on screen
                    pack: true,
                    show: true
            ) {
                vbox {
                    label(text: "$prompt:")
                    input = passwordField()
                    button(defaultButton: true, text: 'OK', actionPerformed: {
                        response = new String(input.password)
                        dispose()
                    })
                }
            }
        }
    } else {
        response = new String(System.console().readPassword("\n$prompt: "))
    }

    if (!response) {
        throw new InvalidUserDataException("Null response detected!")
    }
    response
}