File: configure.in

package info (click to toggle)
gtkglextmm 1.2.0-8
  • links: PTS, VCS
  • area: main
  • in suites: bullseye, buster, sid, stretch
  • size: 5,248 kB
  • ctags: 4,387
  • sloc: sh: 8,904; cpp: 4,594; xml: 1,605; ansic: 832; makefile: 353; perl: 179
file content (557 lines) | stat: -rw-r--r-- 15,328 bytes parent folder | download
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162
163
164
165
166
167
168
169
170
171
172
173
174
175
176
177
178
179
180
181
182
183
184
185
186
187
188
189
190
191
192
193
194
195
196
197
198
199
200
201
202
203
204
205
206
207
208
209
210
211
212
213
214
215
216
217
218
219
220
221
222
223
224
225
226
227
228
229
230
231
232
233
234
235
236
237
238
239
240
241
242
243
244
245
246
247
248
249
250
251
252
253
254
255
256
257
258
259
260
261
262
263
264
265
266
267
268
269
270
271
272
273
274
275
276
277
278
279
280
281
282
283
284
285
286
287
288
289
290
291
292
293
294
295
296
297
298
299
300
301
302
303
304
305
306
307
308
309
310
311
312
313
314
315
316
317
318
319
320
321
322
323
324
325
326
327
328
329
330
331
332
333
334
335
336
337
338
339
340
341
342
343
344
345
346
347
348
349
350
351
352
353
354
355
356
357
358
359
360
361
362
363
364
365
366
367
368
369
370
371
372
373
374
375
376
377
378
379
380
381
382
383
384
385
386
387
388
389
390
391
392
393
394
395
396
397
398
399
400
401
402
403
404
405
406
407
408
409
410
411
412
413
414
415
416
417
418
419
420
421
422
423
424
425
426
427
428
429
430
431
432
433
434
435
436
437
438
439
440
441
442
443
444
445
446
447
448
449
450
451
452
453
454
455
456
457
458
459
460
461
462
463
464
465
466
467
468
469
470
471
472
473
474
475
476
477
478
479
480
481
482
483
484
485
486
487
488
489
490
491
492
493
494
495
496
497
498
499
500
501
502
503
504
505
506
507
508
509
510
511
512
513
514
515
516
517
518
519
520
521
522
523
524
525
526
527
528
529
530
531
532
533
534
535
536
537
538
539
540
541
542
543
544
545
546
547
548
549
550
551
552
553
554
555
556
557
# required autoconf version
AC_PREREQ([2.54])

#
# Making releases:
#   gtkglextmm_micro_version += 1;
#   gtkglextmm_interface_age += 1;
#   gtkglextmm_binary_age += 1;
# if any functions have been added, set gtkglextmm_interface_age to 0.
# if backwards compatibility has been broken,
# set gtkglextmm_binary_age and gtkglextmm_interface_age to 0.
#
m4_define([gtkglextmm_major_version], [1])
m4_define([gtkglextmm_minor_version], [2])
m4_define([gtkglextmm_micro_version], [0])
m4_define([gtkglextmm_interface_age], [0])
m4_define([gtkglextmm_binary_age],    [0])
m4_define([gtkglextmm_version],
          [gtkglextmm_major_version.gtkglextmm_minor_version.gtkglextmm_micro_version])

# API version
m4_define([gtkglextmm_api_major_version], [1])
m4_define([gtkglextmm_api_minor_version], [2])
m4_define([gtkglextmm_api_version],
          [gtkglextmm_api_major_version.gtkglextmm_api_minor_version])

# libtool version related macros
m4_define([gtkglextmm_lt_release],
          [gtkglextmm_major_version.gtkglextmm_minor_version])
m4_define([gtkglextmm_lt_current],
          [m4_eval(gtkglextmm_micro_version - gtkglextmm_interface_age)])
m4_define([gtkglextmm_lt_revision],
          [gtkglextmm_interface_age])
m4_define([gtkglextmm_lt_age],
          [m4_eval(gtkglextmm_binary_age - gtkglextmm_interface_age)])
m4_define([gtkglextmm_lt_current_minus_age],
          [m4_eval(gtkglextmm_lt_current - gtkglextmm_lt_age)])

# Versions of dependencies

# GdkGLExt
m4_define([gdkglext_pkg], [gdkglext-1.0])
m4_define([gdkglext_required_version], [1.0.0])

# GtkGLExt
m4_define([gtkglext_pkg], [gtkglext-1.0])
m4_define([gtkglext_required_version], [1.0.0])

# libsigc++
m4_define([sigcxx_pkg], [sigc++-2.0])
m4_define([sigcxx_required_version], [2.0.0])

# glibmm
m4_define([glibmm_pkg], [glibmm-2.4])
m4_define([glibmm_required_version], [2.16.0])

# pangomm
m4_define([pangomm_pkg], [pangomm-1.4])
m4_define([pangomm_required_version], [2.4.0])

# gdkmm
m4_define([gdkmm_pkg], [gdkmm-2.4])
m4_define([gdkmm_required_version], [2.4.0])

# gtkmm
m4_define([gtkmm_pkg], [gtkmm-2.4])
m4_define([gtkmm_required_version], [2.4.0])


# Process this file with autoconf to produce a configure script.
AC_INIT([gtkglextmm], [gtkglextmm_version],
        [gtkglext-develop@lists.sourceforge.net])

AC_CONFIG_SRCDIR([gdkglext/gdkglmm.h])

# Save this value here, since automake will set cflags later
cflags_set=${CFLAGS+set}

# Initialize automake stuff
AM_INIT_AUTOMAKE([1.7 no-define dist-bzip2 dist-zip])

# Specify a configuration file
AM_CONFIG_HEADER([config.h])

dnl Initialize maintainer mode
AM_MAINTAINER_MODE

AC_CANONICAL_HOST

# Required GtkGLExt version
GTKGLEXT_REQUIRED_VERSION=gtkglext_required_version
AC_SUBST([GTKGLEXT_REQUIRED_VERSION])

# gtkglextmm version
GTKGLEXTMM_MAJOR_VERSION=gtkglextmm_major_version
GTKGLEXTMM_MINOR_VERSION=gtkglextmm_minor_version
GTKGLEXTMM_MICRO_VERSION=gtkglextmm_micro_version
GTKGLEXTMM_INTERFACE_AGE=gtkglextmm_interface_age
GTKGLEXTMM_BINARY_AGE=gtkglextmm_binary_age
GTKGLEXTMM_VERSION=gtkglextmm_version
GTKGLEXTMM_API_MAJOR_VERSION=gtkglextmm_api_major_version
GTKGLEXTMM_API_MINOR_VERSION=gtkglextmm_api_minor_version
GTKGLEXTMM_API_VERSION=gtkglextmm_api_version
AC_SUBST([GTKGLEXTMM_MAJOR_VERSION])
AC_SUBST([GTKGLEXTMM_MINOR_VERSION])
AC_SUBST([GTKGLEXTMM_MICRO_VERSION])
AC_SUBST([GTKGLEXTMM_INTERFACE_AGE])
AC_SUBST([GTKGLEXTMM_BINARY_AGE])
AC_SUBST([GTKGLEXTMM_VERSION])
AC_SUBST([GTKGLEXTMM_API_MAJOR_VERSION])
AC_SUBST([GTKGLEXTMM_API_MINOR_VERSION])
AC_SUBST([GTKGLEXTMM_API_VERSION])

# This is the X.Y used in -lgtkglextmm-FOO-X.Y
#LIB_MJR=$GTKGLEXTMM_API_MAJOR_VERSION
#LIB_MNR=$GTKGLEXTMM_API_MINOR_VERSION
LIB_MJR=$GTKGLEXTMM_MAJOR_VERSION
LIB_MNR=$GTKGLEXTMM_MINOR_VERSION
AC_SUBST([LIB_MJR])
AC_SUBST([LIB_MNR])

# libtool versioning
LT_RELEASE=gtkglextmm_lt_release
LT_CURRENT=gtkglextmm_lt_current
LT_REVISION=gtkglextmm_lt_revision
LT_AGE=gtkglextmm_lt_age
LT_CURRENT_MINUS_AGE=gtkglextmm_lt_current_minus_age
AC_SUBST([LT_RELEASE])
AC_SUBST([LT_CURRENT])
AC_SUBST([LT_REVISION])
AC_SUBST([LT_AGE])
AC_SUBST([LT_CURRENT_MINUS_AGE])

dnl Initialize libtool
AC_PROG_CC
AC_PROG_CPP
AC_PROG_CXX
AC_PROG_CXXCPP
AC_ISC_POSIX
#AM_DISABLE_STATIC
AC_LIBTOOL_WIN32_DLL
AC_PROG_LIBTOOL

platform_win32=no
AC_MSG_CHECKING([for some Win32 platform])
case "$host_os" in
  *mingw*|*cygwin*)
    platform_win32=yes
    ;;
  *)
    ;;
esac
AC_MSG_RESULT([$platform_win32])
AM_CONDITIONAL([PLATFORM_WIN32], [test "x$platform_win32" = "xyes"])

os_win32=no
LIBSTDCXX_LIBS=
AC_MSG_CHECKING([for native Win32])
case "$host_os" in
  *mingw*)
    os_win32=yes
    LIBSTDCXX_LIBS=-lstdc++
    ;;
  *)
    ;;
esac
AC_MSG_RESULT([$os_win32])
AM_CONDITIONAL([OS_WIN32], [test "x$os_win32" = "xyes"])

if test "x$platform_win32" = "xyes"; then
  gdktarget=win32
else
  gdktarget=x11
fi

AC_ARG_WITH(gdktarget,
            [AC_HELP_STRING([--with-gdktarget=@<:@x11/win32@:>@],
                            [select GDK target])],
            [gdktarget=$with_gdktarget])

AC_SUBST([gdktarget])
case $gdktarget in
  x11|win32) ;;
  *) AC_MSG_ERROR([Invalid target for GDK: use x11 or win32.]);;
esac

gdkglextmm_targetlib=libgdkglextmm-$gdktarget-$LIB_MJR.$LIB_MNR.la
gtkglextmm_targetlib=libgtkglextmm-$gdktarget-$LIB_MJR.$LIB_MNR.la

AC_SUBST([gdkglextmm_targetlib])
AC_SUBST([gtkglextmm_targetlib])


# Build time sanity check...
AM_SANITY_CHECK

# Checks for programs.
AM_PROG_CC_STDC
AC_PROG_INSTALL
AC_PROG_MAKE_SET
AC_PROG_LN_S
AC_PROG_AWK

AL_PROG_GNU_M4(AC_MSG_ERROR([dnl
SUN m4 does not work for building gtkmm. 
Please install GNU m4.]))

AL_PROG_GNU_MAKE(AC_MSG_ERROR([dnl
SUN make does not work for building gtkmm.
Please install GNU make.]))

# Evaluate the --enable-warnings=level option.
GTKMM_ARG_ENABLE_WARNINGS()

# Ensure MSVC-compatible struct packing convention is used when
# compiling for Win32 with gcc.
# What flag to depends on gcc version: gcc3 uses "-mms-bitfields", while
# gcc2 uses "-fnative-struct".
if test "x$os_win32" = "xyes"; then
  if test "x$GCC" = "xyes"; then
    msnative_struct=''
    AC_MSG_CHECKING([how to get MSVC-compatible struct packing])
    if test -z "$ac_cv_prog_CC"; then
      our_gcc="$CC"
    else
      our_gcc="$ac_cv_prog_CC"
    fi
    case `$our_gcc --version | sed -e 's,\..*,.,' -e q` in
      2.)
	if $our_gcc -v --help 2>/dev/null | grep fnative-struct >/dev/null; then
	  msnative_struct='-fnative-struct'
	fi
	;;
      *)
	if $our_gcc -v --help 2>/dev/null | grep ms-bitfields >/dev/null; then
	  msnative_struct='-mms-bitfields'
	fi
	;;
    esac
    if test x"$msnative_struct" = x ; then
      AC_MSG_RESULT([no way])
      AC_MSG_WARN([produced libraries might be incompatible with MSVC-compiled code])
    else
      CXXFLAGS="$CXXFLAGS $msnative_struct"
      AC_MSG_RESULT([${msnative_struct}])
    fi
  fi
fi

# --export-all-symbols option to build Win32 DLL using MinGW ld.
WIN32_LD_EXPORT_ALL_SYMBOLS=''
if test "x$os_win32" = "xyes"; then
  AC_MSG_CHECKING([whether ld accepts --export-all-symbols])
  if $LD --help 2>&1 | egrep 'export-all-symbols' > /dev/null; then
    WIN32_LD_EXPORT_ALL_SYMBOLS='-Wl,--export-all-symbols'
    AC_MSG_RESULT([yes])
  else
    AC_MSG_RESULT([no])
  fi
fi
AC_SUBST([WIN32_LD_EXPORT_ALL_SYMBOLS])

# Honor aclocal flags
ACLOCAL="$ACLOCAL $ACLOCAL_FLAGS -I $srcdir/m4macros"

## Initial sanity check, done here so that users get told they 
## have the wrong dependencies as early in the process as possible.
## Later on we actually use the cflags/libs from separate pkg-config
## calls. Oh, also the later pkg-config calls don't include 
## the version requirements since those make the module lists 
## annoying to construct
PKG_CHECK_MODULES([BASE_DEPENDENCIES], [dnl
gtkglext_pkg >= gtkglext_required_version dnl
gdkglext_pkg >= gdkglext_required_version dnl
gtkmm_pkg >= gtkmm_required_version dnl
gdkmm_pkg >= gdkmm_required_version dnl
pangomm_pkg >= pangomm_required_version dnl
])

# Checks for GtkGLExt
AM_PATH_GTKGLEXT_1_0([gtkglext_required_version], ,
                     [AC_MSG_ERROR([GtkGLExt not found])])
save_CPPFLAGS="$CPPFLAGS"
CPPFLAGS="$CPPFLAGS $GTKGLEXT_CFLAGS"
save_LIBS="$LIBS"
LIBS="$LIBS $GTKGLEXT_LIBS"
AC_GTKGLEXT_SUPPORTS_MULTIHEAD([GTKGLEXT_SUPPORTS_MULTIHEAD=yes],
	                       [GTKGLEXT_SUPPORTS_MULTIHEAD=no])
CPPFLAGS="$save_CPPFLAGS"
LIBS="$save_LIBS"

# gmmproc
MM_CHECK_PERL([5.6.0])
GMMPROC_DIR=`$PKG_CONFIG --variable=gmmprocdir glibmm-2.4`
AC_SUBST(GMMPROC_DIR)
GMMPROC=$GMMPROC_DIR/gmmproc
AC_SUBST(GMMPROC)

# Checks for libraries.

# Checks for header files.
AC_HEADER_STDC

# Checks for typedefs, structures, and compiler characteristics.
AC_C_CONST

# Checks for library functions.


##################################################
# Checks for gdkmm multihead support
##################################################

GDKGLEXTMM_MULTIHEAD_SUPPORT=no

save_CPPFLAGS="$CPPFLAGS"
CPPFLAGS="$CPPFLAGS $BASE_DEPENDENCIES_CFLAGS"
save_LIBS="$LIBS"
LIBS="$LIBS $BASE_DEPENDENCIES_LIBS"

if test "x$GTKGLEXT_SUPPORTS_MULTIHEAD" = "xyes"; then

  AC_LANG_SAVE
  AC_LANG_CPLUSPLUS

  AC_CHECK_HEADERS([gdkmm/display.h gdkmm/screen.h],
                   [GDKGLEXTMM_MULTIHEAD_SUPPORT=yes],
                   [GDKGLEXTMM_MULTIHEAD_SUPPORT=no])

  if test "x$GDKGLEXTMM_MULTIHEAD_SUPPORT" = "xyes"; then
    AC_MSG_CHECKING([for Gdk::Display::get_default in gdkmm library])
    AC_TRY_LINK([#include <gdkmm/display.h>], 
                [Gdk::Display::get_default();],
                [GDKGLEXTMM_MULTIHEAD_SUPPORT=yes],
                [GDKGLEXTMM_MULTIHEAD_SUPPORT=no])
    AC_MSG_RESULT([$GDKGLEXTMM_MULTIHEAD_SUPPORT])
  fi

  AC_LANG_RESTORE

  if test "x$GDKGLEXTMM_MULTIHEAD_SUPPORT" = "xyes"; then
    AC_MSG_NOTICE([gdkmm supports multihead])
  else
    AC_MSG_NOTICE([gdkmm doesn't support multihead])
  fi

fi

CPPFLAGS="$save_CPPFLAGS"
LIBS="$save_LIBS"

AC_SUBST([GDKGLEXTMM_MULTIHEAD_SUPPORT])
AM_CONDITIONAL([MULTIHEAD_SUPPORT],
               [test "x$GDKGLEXTMM_MULTIHEAD_SUPPORT" = "xyes"])


##################################################
# CFLAGS and LIBS
##################################################

GDKGLEXTMM_PACKAGES="gdkglext_pkg gdkmm_pkg pangomm_pkg"
GDKGLEXTMM_EXTRA_LIBS=""
GDKGLEXTMM_EXTRA_CFLAGS=""
GDKGLEXTMM_DEP_LIBS="`$PKG_CONFIG --libs $GDKGLEXTMM_PACKAGES` $GDKGLEXTMM_EXTRA_LIBS $LIBSTDCXX_LIBS"
GDKGLEXTMM_DEP_CFLAGS="`$PKG_CONFIG --cflags $GDKGLEXTMM_PACKAGES` $GDKGLEXTMM_EXTRA_CFLAGS $MULTIHEAD_SAFE"
AC_SUBST([GDKGLEXTMM_PACKAGES])
AC_SUBST([GDKGLEXTMM_EXTRA_LIBS])
AC_SUBST([GDKGLEXTMM_EXTRA_CFLAGS])
AC_SUBST([GDKGLEXTMM_DEP_LIBS])
AC_SUBST([GDKGLEXTMM_DEP_CFLAGS])

GTKGLEXTMM_PACKAGES="gtkglext_pkg gtkmm_pkg"
GTKGLEXTMM_EXTRA_LIBS=""
GTKGLEXTMM_EXTRA_CFLAGS=""
GTKGLEXTMM_DEP_LIBS="`$PKG_CONFIG --libs $GDKGLEXTMM_PACKAGES $GTKGLEXTMM_PACKAGES` $GTKGLEXTMM_EXTRA_LIBS $GDKGLEXTMM_EXTRA_LIBS $LIBSTDCXX_LIBS"
GTKGLEXTMM_DEP_CFLAGS="`$PKG_CONFIG --cflags $GDKGLEXTMM_PACKAGES $GTKGLEXTMM_PACKAGES` $GDKGLEXTMM_EXTRA_CFLAGS $GTKGLEXTMM_EXTRA_CFLAGS $MULTIHEAD_SAFE"
AC_SUBST([GTKGLEXTMM_PACKAGES])
AC_SUBST([GTKGLEXTMM_EXTRA_LIBS])
AC_SUBST([GTKGLEXTMM_EXTRA_CFLAGS])
AC_SUBST([GTKGLEXTMM_DEP_LIBS])
AC_SUBST([GTKGLEXTMM_DEP_CFLAGS])


##################################################
# Checks for doxygen
##################################################

AC_ARG_WITH(html-dir,
            [AC_HELP_STRING([--with-html-dir=PATH],
                            [path to installed docs [DATADIR/doc]])])

if test "x$with_html_dir" = "x" ; then
  # doxygen's default docdir
  HTML_DIR='${datadir}/doc'
else
  HTML_DIR=$with_html_dir
fi

AC_SUBST([HTML_DIR])

DOXYGEN_DOC=false

PERL_PATH=""
AC_PATH_PROGS([PERL_PATH], [perl perl5])
AC_SUBST([PERL_PATH])

DOT_PATH=""
HAVE_DOT=NO
AC_PATH_PROGS([DOT_PATH], [dot])
if test "x$DOT_PATH" != "x"; then
  HAVE_DOT=YES
fi
AC_SUBST([HAVE_DOT])
AC_SUBST([DOT_PATH])

DOXYGEN_PATH=""
AC_PATH_PROGS([DOXYGEN_PATH], [doxygen])
AC_SUBST([DOXYGEN_PATH])

GLIBMM_INCLUDE_PATH=`$PKG_CONFIG --variable=includedir glibmm_pkg`/glibmm_pkg
PANGOMM_INCLUDE_PATH=`$PKG_CONFIG --variable=includedir pangomm_pkg`/pangomm_pkg
GDKMM_INCLUDE_PATH=`$PKG_CONFIG --variable=includedir gdkmm_pkg`/gdkmm_pkg
GTKMM_INCLUDE_PATH=`$PKG_CONFIG --variable=includedir gtkmm_pkg`/gtkmm_pkg
AC_SUBST([GLIBMM_INCLUDE_PATH])
AC_SUBST([PANGOMM_INCLUDE_PATH])
AC_SUBST([GDKMM_INCLUDE_PATH])
AC_SUBST([GTKMM_INCLUDE_PATH])

if test "x$PERL_PATH" != "x" -a "x$DOXYGEN_PATH" != "x"; then
  DOXYGEN_DOC=true
fi

AC_ARG_ENABLE(doxygen-doc,
              [AC_HELP_STRING([--enable-doxygen-doc],
                              [use doxygen to build documentation [default=no]])], ,
              [enable_doxygen_doc=no])

if test "x$enable_doxygen_doc" = "xyes"; then
  if test "x$DOXYGEN_DOC" != "xtrue"; then
    enable_doxygen_doc=no 
  fi
fi

AM_CONDITIONAL([ENABLE_DOXYGEN_DOC],
               [test "x$enable_doxygen_doc" = "xyes"])


##################################################
# Output configuration header
##################################################

dnl this section will only be run if config.status is invoked with no
dnl arguments, or with "gdkglext/gdkglextmm-config.h" as an argument.
AC_CONFIG_COMMANDS([gdkglext/gdkglextmm-config.h],
[
  outfile=gdkglextmm-config.h-tmp
  cat > $outfile <<\_______EOF
/* gdkglextmm-config.h
 *
 * This is a generated file.  Please modify `configure.in'
 */

#ifndef GDKGLEXTMM_CONFIG_H
#define GDKGLEXTMM_CONFIG_H

#include <gdkglext-config.h>

_______EOF

	cat >>$outfile <<_______EOF
$gdkglextmm_windowing
$gdkglextmm_multihead_support
_______EOF

	cat >>$outfile <<_______EOF

#if !defined(GDKGLEXT_MULTIHEAD_SUPPORT) && defined(GDKGLEXTMM_MULTIHEAD_SUPPORT)
#error "Installed GdkGLExt library doesn't have multihead support."
#endif
_______EOF

	cat >>$outfile <<_______EOF

#endif /* GDKGLEXTMM_CONFIG_H */
_______EOF


  if cmp -s $outfile gdkglext/gdkglextmm-config.h; then
    AC_MSG_NOTICE([gdkglext/gdkglextmm-config.h is unchanged])
    rm -f $outfile
  else
    mv $outfile gdkglext/gdkglextmm-config.h
  fi

],[

if test "x$gdktarget" = "xx11" ; then
  gdkglextmm_windowing='
#define GDKGLEXTMM_WINDOWING_X11'
elif test "x$gdktarget" = "xwin32" ; then
  gdkglextmm_windowing='
#define GDKGLEXTMM_WINDOWING_WIN32'
fi

if test "x$GDKGLEXTMM_MULTIHEAD_SUPPORT" = "xyes"; then
  gdkglextmm_multihead_support='
#define GDKGLEXTMM_MULTIHEAD_SUPPORT'
fi

])


##################################################
# Config files
##################################################

AC_CONFIG_FILES([
gdkglextmm.pc
gtkglextmm.pc
gdkglextmm-uninstalled.pc
gtkglextmm-uninstalled.pc
gtkglextmm.spec
gtkglextmm.nsi
Makefile
tools/Makefile
tools/extra_defs_gen/Makefile
tools/m4/Makefile
gdkglext/Makefile
gdkglext/src/Makefile
gdkglext/gdkmm/Makefile
gdkglext/gdkmm/gl/Makefile
gdkglext/gdkmm/gl/version.h
gdkglext/gdkmm/gl/private/Makefile
gtkglext/Makefile
gtkglext/src/Makefile
gtkglext/gtkmm/Makefile
gtkglext/gtkmm/gl/Makefile
gtkglext/gtkmm/gl/version.h
gtkglext/gtkmm/gl/private/Makefile
examples/Makefile
docs/Makefile
docs/reference/Makefile
docs/reference/Doxyfile
m4macros/Makefile
])

AC_OUTPUT


##################################################
# Print configuration
##################################################

echo "
configuration:
	multihead support:	$GDKGLEXTMM_MULTIHEAD_SUPPORT
"