1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162
163
164
165
166
167
168
169
170
171
172
173
174
175
176
177
178
179
180
181
182
183
184
185
186
187
188
189
190
191
192
193
194
195
196
197
|
// SPDX-License-Identifier: MPL-2.0
// (c) Hare authors <https://harelang.org>
use errors;
use io;
use net;
use net::ip;
use rt;
// Creates a UDP socket and sets the default destination to the given address.
export fn connect(
dest: ip::addr,
port: u16,
options: connect_option...
) (net::socket | net::error) = {
const family = match (dest) {
case ip::addr4 =>
yield rt::AF_INET: int;
case ip::addr6 =>
yield rt::AF_INET6: int;
};
let f = 0i;
for (let i = 0z; i < len(options); i += 1) {
// Only sockflag for now
f |= options[i];
};
f ^= rt::SOCK_CLOEXEC; // invert CLOEXEC
const sockfd = match (rt::socket(family, rt::SOCK_DGRAM | f, 0)) {
case let err: rt::errno =>
return errors::errno(err);
case let fd: int =>
yield fd;
};
const sockaddr = ip::to_native(dest, port);
const sz = size(rt::sockaddr): u32;
match (rt::connect(sockfd, &sockaddr, sz)) {
case void =>
return io::fdopen(sockfd);
case let err: rt::errno =>
return errors::errno(err);
};
};
// Creates a UDP socket bound to an interface.
export fn listen(
addr: ip::addr,
port: u16,
options: listen_option...
) (net::socket | net::error) = {
const family = match (addr) {
case ip::addr4 =>
yield rt::AF_INET: int;
case ip::addr6 =>
yield rt::AF_INET6: int;
};
let f = 0i;
for (let i = 0z; i < len(options); i += 1) {
match (options[i]) {
case let fl: net::sockflag =>
f |= fl;
case => void;
};
};
f ^= rt::SOCK_CLOEXEC; // invert CLOEXEC
const sockfd = match (rt::socket(family, rt::SOCK_DGRAM | f, 0)) {
case let err: rt::errno =>
return errors::errno(err);
case let fd: int =>
yield fd;
};
for (let i = 0z; i < len(options); i += 1) {
match (options[i]) {
case reuseaddr =>
setsockopt(sockfd, rt::SO_REUSEADDR, true)?;
case reuseport =>
setsockopt(sockfd, rt::SO_REUSEPORT, true)?;
case => void;
};
};
const sockaddr = ip::to_native(addr, port);
const sz = size(rt::sockaddr): u32;
match (rt::bind(sockfd, &sockaddr, sz)) {
case void => void;
case let err: rt::errno =>
return errors::errno(err);
};
for (let i = 0z; i < len(options); i += 1) {
let portout = match (options[i]) {
case let p: portassignment =>
yield p;
case =>
continue;
};
let sn = rt::sockaddr {...};
let al = size(rt::sockaddr): u32;
match (rt::getsockname(sockfd, &sn, &al)) {
case let err: rt::errno =>
return errors::errno(err);
case int => void;
};
const addr = ip::from_native(sn);
*portout = addr.1;
};
return io::fdopen(sockfd);
};
// Sends a UDP packet to a [[connect]]ed UDP socket.
export fn send(sock: net::socket, buf: []u8) (size | net::error) = {
match (rt::send(sock, buf: *[*]u8, len(buf), 0)) {
case let sz: size =>
return sz;
case let err: rt::errno =>
return errors::errno(err);
};
};
// Sends a UDP packet using this socket.
export fn sendto(
sock: net::socket,
buf: []u8,
dest: ip::addr,
port: u16,
) (size | net::error) = {
const sockaddr = ip::to_native(dest, port);
const sz = size(rt::sockaddr): u32;
match (rt::sendto(sock, buf: *[*]u8, len(buf), 0, &sockaddr, sz)) {
case let sz: size =>
return sz;
case let err: rt::errno =>
return errors::errno(err);
};
};
// Receives a UDP packet from a [[connect]]ed UDP socket.
export fn recv(
sock: net::socket,
buf: []u8,
) (size | net::error) = {
match (rt::recv(sock, buf: *[*]u8, len(buf), 0)) {
case let sz: size =>
return sz;
case let err: rt::errno =>
return errors::errno(err);
};
};
// Receives a UDP packet from a bound socket.
export fn recvfrom(
sock: net::socket,
buf: []u8,
src: nullable *ip::addr,
port: nullable *u16,
) (size | net::error) = {
let addrsz = size(rt::sockaddr): u32;
const sockaddr = rt::sockaddr { ... };
const sz = match (rt::recvfrom(sock, buf: *[*]u8, len(buf), 0,
&sockaddr, &addrsz)) {
case let sz: size =>
yield sz;
case let err: rt::errno =>
return errors::errno(err);
};
assert(addrsz <= size(rt::sockaddr));
const peer = ip::from_native(sockaddr);
match (src) {
case null => void;
case let src: *ip::addr =>
*src = peer.0;
};
match (port) {
case null => void;
case let port: *u16 =>
*port = peer.1;
};
return sz;
};
fn setsockopt(
sockfd: int,
option: int,
value: bool,
) (void | net::error) = {
let val: int = if (value) 1 else 0;
match (rt::setsockopt(sockfd, rt::SOL_SOCKET, option,
&val: *opaque, size(int): u32)) {
case let err: rt::errno =>
return errors::errno(err);
case int => void;
};
};
|
