1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
|
/*
* Copyright (C)2005-2019 Haxe Foundation
*
* Permission is hereby granted, free of charge, to any person obtaining a
* copy of this software and associated documentation files (the "Software"),
* to deal in the Software without restriction, including without limitation
* the rights to use, copy, modify, merge, publish, distribute, sublicense,
* and/or sell copies of the Software, and to permit persons to whom the
* Software is furnished to do so, subject to the following conditions:
*
* The above copyright notice and this permission notice shall be included in
* all copies or substantial portions of the Software.
*
* THE SOFTWARE IS PROVIDED "AS IS", WITHOUT WARRANTY OF ANY KIND, EXPRESS OR
* IMPLIED, INCLUDING BUT NOT LIMITED TO THE WARRANTIES OF MERCHANTABILITY,
* FITNESS FOR A PARTICULAR PURPOSE AND NONINFRINGEMENT. IN NO EVENT SHALL THE
* AUTHORS OR COPYRIGHT HOLDERS BE LIABLE FOR ANY CLAIM, DAMAGES OR OTHER
* LIABILITY, WHETHER IN AN ACTION OF CONTRACT, TORT OR OTHERWISE, ARISING
* FROM, OUT OF OR IN CONNECTION WITH THE SOFTWARE OR THE USE OR OTHER
* DEALINGS IN THE SOFTWARE.
*/
package sys.io;
import haxe.io.BytesInput;
import cs.system.io.StreamReader;
import cs.system.io.StreamWriter;
import cs.system.diagnostics.Process as NativeProcess;
import cs.system.diagnostics.ProcessStartInfo as NativeStartInfo;
@:coreApi
class Process {
public var stdout(default, null):haxe.io.Input;
public var stderr(default, null):haxe.io.Input;
public var stdin(default, null):haxe.io.Output;
private var native:NativeProcess;
public function new(cmd:String, ?args:Array<String>, ?detached:Bool):Void {
if (detached)
throw "Detached process is not supported on this platform";
this.native = createNativeProcess(cmd, args);
native.Start();
this.stdout = new cs.io.NativeInput(native.StandardOutput.BaseStream);
this.stderr = new cs.io.NativeInput(native.StandardError.BaseStream);
this.stdin = new cs.io.NativeOutput(native.StandardInput.BaseStream);
}
@:allow(Sys)
private static function createNativeProcess(cmd:String, ?args:Array<String>):NativeProcess {
var native = new NativeProcess();
native.StartInfo.CreateNoWindow = true;
native.StartInfo.RedirectStandardError = native.StartInfo.RedirectStandardInput = native.StartInfo.RedirectStandardOutput = true;
if (args != null) {
// mono 4.2.1 on Windows doesn't support relative path correctly
if (cmd.indexOf("/") != -1 || cmd.indexOf("\\") != -1)
cmd = sys.FileSystem.fullPath(cmd);
native.StartInfo.FileName = cmd;
native.StartInfo.UseShellExecute = false;
native.StartInfo.Arguments = buildArgumentsString(args);
} else {
switch (Sys.systemName()) {
case "Windows":
native.StartInfo.FileName = switch (Sys.getEnv("COMSPEC")) {
case null: "cmd.exe";
case var comspec: comspec;
}
native.StartInfo.Arguments = '/C "$cmd"';
case _:
native.StartInfo.FileName = "/bin/sh";
native.StartInfo.Arguments = buildArgumentsString(["-c", cmd]);
}
native.StartInfo.UseShellExecute = false;
}
return native;
}
private static function buildArgumentsString(args:Array<String>):String {
return switch (Sys.systemName()) {
case "Windows":
[
for (a in args)
haxe.SysTools.quoteWinArg(a, false)
].join(" ");
case _:
// mono uses a slightly different quoting/escaping rule...
// https://bugzilla.xamarin.com/show_bug.cgi?id=19296
[
for (arg in args) {
var b = new StringBuf();
b.add('"');
for (i in 0...arg.length) {
var c = arg.charCodeAt(i);
switch (c) {
case '"'.code | '\\'.code:
b.addChar('\\'.code);
case _: // pass
}
b.addChar(c);
}
b.add('"');
b.toString();
}
].join(" ");
}
}
public function getPid():Int {
return native.Id;
}
public function exitCode(block:Bool = true):Null<Int> {
if (block == false && !native.HasExited)
return null;
native.WaitForExit();
return native.ExitCode;
}
public function close():Void {
native.Close();
}
public function kill():Void {
native.Kill();
}
}
|
