1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
|
/*
* Copyright (C)2005-2019 Haxe Foundation
*
* Permission is hereby granted, free of charge, to any person obtaining a
* copy of this software and associated documentation files (the "Software"),
* to deal in the Software without restriction, including without limitation
* the rights to use, copy, modify, merge, publish, distribute, sublicense,
* and/or sell copies of the Software, and to permit persons to whom the
* Software is furnished to do so, subject to the following conditions:
*
* The above copyright notice and this permission notice shall be included in
* all copies or substantial portions of the Software.
*
* THE SOFTWARE IS PROVIDED "AS IS", WITHOUT WARRANTY OF ANY KIND, EXPRESS OR
* IMPLIED, INCLUDING BUT NOT LIMITED TO THE WARRANTIES OF MERCHANTABILITY,
* FITNESS FOR A PARTICULAR PURPOSE AND NONINFRINGEMENT. IN NO EVENT SHALL THE
* AUTHORS OR COPYRIGHT HOLDERS BE LIABLE FOR ANY CLAIM, DAMAGES OR OTHER
* LIABILITY, WHETHER IN AN ACTION OF CONTRACT, TORT OR OTHERWISE, ARISING
* FROM, OUT OF OR IN CONNECTION WITH THE SOFTWARE OR THE USE OR OTHER
* DEALINGS IN THE SOFTWARE.
*/
package js;
import js.html.Storage;
import js.html.XMLHttpRequest;
class Browser {
/** The global scope typed with fields available only in a worker context. */
public static var self(get, never):js.html.WorkerGlobalScope;
static inline function get_self():js.html.WorkerGlobalScope {
return js.Lib.global;
}
/** The global window object. */
public static var window(get, never):js.html.Window;
extern inline static function get_window()
return js.Syntax.code("window");
/** Shortcut to Window.document. */
public static var document(get, never):js.html.HTMLDocument;
extern inline static function get_document()
return window.document;
/** Shortcut to Window.location. */
public static var location(get, never):js.html.Location;
extern inline static function get_location()
return js.Lib.global.location;
/** Shortcut to Window.navigator. */
public static var navigator(get, never):js.html.Navigator;
extern inline static function get_navigator()
return js.Lib.global.navigator;
/** Shortcut to Window.console. */
public static var console(get, never):js.html.ConsoleInstance;
extern inline static function get_console()
return js.Lib.global.console;
/**
* True if a window object exists, false otherwise.
*
* This can be used to check if the code is being executed in a non-browser
* environment such as node.js.
*/
public static var supported(get, never):Bool;
static function get_supported()
return
js.Syntax.typeof(window) != "undefined" &&
js.Syntax.typeof(window.location) != "undefined" &&
js.Syntax.typeof(window.location.protocol) == "string";
/**
* Safely gets the browser's local storage, or returns null if localStorage is unsupported or
* disabled.
*/
public static function getLocalStorage():Null<Storage> {
try {
var s = window.localStorage;
s.getItem("");
if (s.length == 0) {
var key = "_hx_" + Math.random();
s.setItem(key, key);
s.removeItem(key);
}
return s;
} catch (e:Dynamic) {
return null;
}
}
/**
* Safely gets the browser's session storage, or returns null if sessionStorage is unsupported
* or disabled.
*/
public static function getSessionStorage():Storage {
try {
var s = window.sessionStorage;
s.getItem("");
if (s.length == 0) {
var key = "_hx_" + Math.random();
s.setItem(key, key);
s.removeItem(key);
}
return s;
} catch (e:Dynamic) {
return null;
}
}
/**
* Creates an XMLHttpRequest, with a fallback to ActiveXObject for ancient versions of Internet
* Explorer.
*/
public static function createXMLHttpRequest():XMLHttpRequest {
if (js.Syntax.code("typeof XMLHttpRequest") != "undefined") {
return new XMLHttpRequest();
}
if (js.Syntax.code("typeof ActiveXObject") != "undefined") {
return js.Syntax.construct("ActiveXObject", "Microsoft.XMLHTTP");
}
throw "Unable to create XMLHttpRequest object.";
}
/**
Display an alert message box containing the given message. See also `Window.alert()`.
**/
public static inline function alert(v:Dynamic) {
window.alert(Std.string(v));
}
}
|
