#                                               -*- Autoconf -*-
# Process this file with autoconf to produce a configure script.

# Prototype configure.ac for HDF-EOS
# Created 5/2/06 by James Laird (jlaird@ncsa.uiuc.edu)

AC_PREREQ([2.59])
AC_INIT([hdf-eos5], [1.8], null@bogus.email)
AM_CONFIG_HEADER([include/HE5_config.h])

AC_CONFIG_AUX_DIR([config])

AM_INIT_AUTOMAKE([foreign])
AM_MAINTAINER_MODE

# Disable shared libraries (for now)
# AC_DISABLE_SHARED

AM_PROG_LIBTOOL

dnl ----------------------------------------------------------------------
dnl Set prefix default (install directory) to a directory in the build area.
AC_PREFIX_DEFAULT([`pwd`/hdfeos5])

# Check for the math library that HDF5 needs
AC_CHECK_LIB([m], [ceil])

# Check whether zlib is enabled.
# HDF-EOS5 doesn't use zlib, but HDF5 might.  If HDF5 does, it needs
# to be given to the linker or there will be undefined symbols in HDF5.
# Using h5cc avoids the need to specify zlib at configure time.
AC_ARG_WITH([zlib],
            [AC_HELP_STRING([--with-zlib=DIR],
                            [Specify path to external zlib library.
                             Linker must be able to find zlib if HDF5
                             was built with zlib.
                             [default=yes]])],,
            withval=yes)

case $withval in
  yes)
    HAVE_ZLIB="yes"
    AC_CHECK_HEADERS([zlib.h],)
    AC_CHECK_LIB([z], [compress2],, [unset HAVE_ZLIB])

    if test -z "$HAVE_ZLIB"; then
      AC_MSG_ERROR([couldn't find zlib library])
    fi
    ;;
  no)
    HAVE_ZLIB="no"
    AC_MSG_CHECKING([for GNU zlib])
    AC_MSG_RESULT([suppressed])
    ;;
  *)
    HAVE_ZLIB="yes"
    case "$withval" in
      *,*)
        zlib_inc="`echo $withval |cut -f1 -d,`"
        zlib_lib="`echo $withval |cut -f2 -d, -s`"
        ;;
      *)
        if test -n "$withval"; then
          zlib_inc="$withval/include"
          zlib_lib="$withval/lib"
        fi
        ;;
    esac

    dnl Trying to include -I/usr/include and -L/usr/lib is redundant and
    dnl can mess some compilers up.
    if test "X$zlib_inc" = "X/usr/include"; then
      zlib_inc=""
    fi
    if test "X$zlib_lib" = "X/usr/lib"; then
      zlib_lib=""
    fi

    saved_CPPFLAGS="$CPPFLAGS"
    saved_LDFLAGS="$LDFLAGS"

    if test -n "$zlib_inc"; then
      CPPFLAGS="$CPPFLAGS -I$zlib_inc"
    fi

    AC_CHECK_HEADERS([zlib.h], ,
                     [CPPFLAGS="$saved_CPPFLAGS"])

    if test -n "$zlib_lib"; then
      LDFLAGS="$LDFLAGS -L$zlib_lib"
    fi

    AC_CHECK_LIB([z], [compress2],,
                 [LDFLAGS="$saved_LDFLAGS"; unset HAVE_ZLIB])

    if test -z "$HAVE_ZLIB"; then
      AC_MSG_ERROR([couldn't find zlib library])
    fi
    ;;
esac

dnl --------------------------------------------------
dnl Check if -Df2cFortran is specified
dnl Running only the preprocessor may not be a good idea
dnl because this can be hard-coded.
AC_MSG_CHECKING([for fc2Fortran macro])
AC_CACHE_VAL([he5_cv_f2cFortran_defined],
    [AC_TRY_RUN([
    int main(void)
    {
    #ifdef f2cFortran
      return 0;
    #else
      return 1;
    #endif
    }
    ], [he5_cv_f2cFortran_defined=yes], [he5_cv_f2cFortran_defined=no],)])
if test ${he5_cv_f2cFortran_defined} = "yes"; then
  F2CFORTRAN_MACRO="yes"
  AC_MSG_RESULT([defined])
else
  F2CFORTRAN_MACRO="no"
  AC_MSG_RESULT([not defined])
fi

if test ${he5_cv_f2cFortran_defined} = "yes"; then
  AC_CHECK_SIZEOF([int*])
  AC_CACHE_VAL([he5_cv_32ptr],
      [AC_TRY_RUN([
      int main(void)
      {
#ifdef SIZEOF_INTP
	return SIZEOF_INTP == 4 ? 0 : 1;
#else
#error SIZEOF_INTP is not defined
#endif
      }
      ], [he5_cv_32ptr=yes], [he5_cv_32ptr=no],)])
  if test ${he5_cv_32ptr} = "yes"; then
    AC_MSG_NOTICE([possibly 32 bit system])
    F2CFORTRAN_32PTR="yes"
  else
    AC_MSG_NOTICE([possibly 64 bit system])
  fi

  AC_PROG_FC
  if test -n "$FC"; then
    AC_MSG_CHECKING([for fortran compiler $FC])
    AC_LANG_PUSH([Fortran])
    AC_TRY_LINK([], [
	INTEGER :: I
	REAL :: R
	I=TRANSFER(R,I)
	], [he2_cv_fortran90_compiler=yes], [he2_cv_fortran90_compiler=no])
    AC_LANG_POP([Fortran])
    if test ${he2_cv_fortran90_compiler} = "yes"; then
      AC_MSG_RESULT([Fortran 90 code was successfully compiled; assume f90 or later])
      F2CFORTRAN_90="yes"
    else
      AC_MSG_RESULT([Fortran 90 code format was not compiled; assume f77])
    fi
    if test -n "$F77" -o -n "$FFLAGS"; then
      AC_MSG_NOTICE([$FC, $FCFLAGS will override $F77, $FFLAGS.])
    fi
    F77=$FC
    FFLAGS=$FCFLAGS
  else
    AC_MSG_NOTICE([f90 or compatible was not detected.])
    AC_PROG_F77
    if test -n "$F77"; then
      AC_MSG_NOTICE([f77 or compatible was detected. $F77 will be used to check Fortran testdrivers.])
    else
      AC_MSG_ERROR([couldn't find fortran compiler. You may want to FC environment variable])
    fi
  fi
fi

# Check whether szlib (szip) is enabled.
# HDF-EOS5 doesn't use szlib, but HDF5 might.  If HDF5 does, it needs
# to be given to the linker or there will be undefined symbols in HDF5.
# Using h5cc should avoid the need to specify szlib at configure time.
AC_ARG_WITH([szlib],
            [AC_HELP_STRING([--with-szlib=DIR],
                            [Use szlib library for external szlib I/O
                             filter.  Linker must be able to find szlib
                             if HDF5 was build with szip. [default=no]])],,
            withval=no)

case $withval in
  yes)
    HAVE_SZLIB="yes"
    AC_CHECK_HEADERS([szlib.h], [HAVE_SZLIB_H="yes"])
    AC_CHECK_LIB([sz], [SZ_BufftoBuffCompress],, [unset HAVE_SZLIB])

    if test -z "$HAVE_SZLIB"; then
      AC_MSG_ERROR([couldn't find szlib library, you may need to specify szip library path])
    fi
    ;;
  no)
    HAVE_SZLIB="no"
    AC_MSG_CHECKING([for szlib])
    AC_MSG_RESULT([suppressed])
    ;;
  *)
    HAVE_SZLIB="yes"
    case "$withval" in
      *,*)
        szlib_inc="`echo $withval |cut -f1 -d,`"
        szlib_lib="`echo $withval |cut -f2 -d, -s`"
        ;;
      *)
        if test -n "$withval"; then
          szlib_inc="$withval/include"
          szlib_lib="$withval/lib"
        fi
        ;;
    esac

    dnl Check if szlib.h exists. We cannot use AC_CHECK_HEADERS here
    dnl because it will use preprocessor. Preprocessor always succeeds in
    dnl finding szlib.h because h4cc provides the path to szlib.h.
    AC_CHECK_FILE($szlib_inc/szlib.h, , [unset HAVE_SZLIB])
    if test -z "$HAVE_SZLIB"; then
      AC_MSG_ERROR([couldn't find szlib.h, check szip library path])
    fi
    
    dnl Trying to include -I/usr/include and -L/usr/lib is redundant and
    dnl can mess some compilers up.
    if test "X$szlib_inc" = "X/usr/include"; then
      szlib_inc=""
    fi 
    if test "X$szlib_lib" = "X/usr/lib"; then
      szlib_lib=""
    fi
    
    saved_CPPFLAGS="$CPPFLAGS"
    saved_LDFLAGS="$LDFLAGS"
    
    if test -n "$szlib_inc"; then
      CPPFLAGS="$CPPFLAGS -I$szlib_inc"
    fi
    
    AC_CHECK_HEADERS([szlib.h],
                     [HAVE_SZLIB_H="yes"],
                     [CPPFLAGS="$saved_CPPFLAGS"])
    
    if test -n "$szlib_lib"; then
      LDFLAGS="$LDFLAGS -L$szlib_lib"
    fi
    
    AC_CHECK_LIB([sz], [SZ_BufftoBuffCompress],,
                 [LDFLAGS="$saved_LDFLAGS"; unset HAVE_SZLIB])
    
    if test -z "$HAVE_SZLIB" -a -n "$HDF5_CONFIG_ABORT"; then
      AC_MSG_ERROR([couldn't find szlib library, check if szip library is valid])
    fi
    ;;
esac


if test "X$HAVE_SZLIB" = "Xyes"; then
    dnl SZLIB library is available.  Check if it can encode

    dnl Given that user specifies h5cc, LDFLAGS in h5cc should be overriden; otherwise,
    dnl the encoding test will be performed on the SZIP library linked with HDF5, not
    dnl the SZIP library user specifies. To suppress the SZIP library linked with HDF5,
    dnl we prepend the user-specified SZIP library path to LDFLAGS in h5cc by using awk.

    AC_PROG_AWK

    AC_MSG_CHECKING([for h5cc])
    PURE_CC=""
    if ($CC -show &> /dev/null); then
	dnl Since CC can be "h5cc -Df2cFortran", arguments should be removed
	PURE_CC=`echo "$CC" | $AWK '{ split($1, array, " ") ; printf array[[1]] }'`
	AC_MSG_RESULT([$PURE_CC])
    else
	AC_MSG_RESULT([$CC])
	AC_MSG_ERROR([CC is not h5cc])
    fi

    SZIP_CC=szip_cc
    cat $PURE_CC | $AWK '{ if ( $0 ~ /^LDFLAGS=\"(.*)/ ) { print substr($0, 1, 9) " -L'$szlib_lib' " substr($0, 10) } else  { print } } ' > $SZIP_CC
    chmod 755 $SZIP_CC
    saved_CC="$CC"
    CC=./$SZIP_CC

    AC_MSG_CHECKING([for szlib encoder])

    AC_CACHE_VAL([he5_cv_szlib_functional],
        [AC_TRY_RUN([
	#include <stddef.h>
        #include <szlib.h>

        int main(void)
        {
            SZ_encoder_enabled();
            exit(0);
        }
        ], [he5_cv_szlib_functional=yes], [he5_cv_szlib_functional=no],)])

    AC_CACHE_VAL([he5_cv_szlib_can_encode],
        [AC_TRY_RUN([
	#include <stddef.h>
        #include <szlib.h>

        int main(void)
        {
            /* SZ_encoder_enabled returns 1 if encoder is present */
            if(SZ_encoder_enabled() == 1)
                exit(0);
            else
                exit(1);
        }
        ], [he5_cv_szlib_can_encode=yes], [he5_cv_szlib_can_encode=no],)])

    CC="$saved_CC"
    rm -f $SZIP_CC

    if test ${he5_cv_szlib_functional} = "no"; then
        he5_cv_szlib_can_encode=broken
    else
        AC_DEFINE(HAVE_FILTER_SZIP, 1,
                [Define if support for szip filter is enabled])
        USE_FILTER_SZIP="yes"
    fi

    if test ${he5_cv_szlib_can_encode} = "yes"; then
    	AC_DEFINE(HAVE_FILTER_SZIP_ENCODER, 1,
		[Define if support for szip encoder filter is enabled])
	USE_SZIP_ENCODER="yes"
        AC_MSG_RESULT([yes])
    fi
    if test ${he5_cv_szlib_can_encode} = "no"; then
        AC_MSG_RESULT([no])
    fi
    if test ${he5_cv_szlib_can_encode} = "broken"; then
        AC_MSG_RESULT([shared szlib doesn't work. disabling szip.])
    fi

    dnl Add "szip" to external filter list
    if test ${he5_cv_szlib_can_encode} = "yes"; then
        if test "X$EXTERNAL_FILTERS" != "X"; then
            EXTERNAL_FILTERS="${EXTERNAL_FILTERS},"
        fi
        EXTERNAL_FILTERS="${EXTERNAL_FILTERS}szip(encoder)"
    fi
    if test ${he5_cv_szlib_can_encode} = "no"; then
        if test "X$EXTERNAL_FILTERS" != "X"; then
            EXTERNAL_FILTERS="${EXTERNAL_FILTERS},"
        fi
        EXTERNAL_FILTERS="${EXTERNAL_FILTERS}szip(no encoder)"
    fi
fi

# Check for the HDF5 library using the --with argument
# Of course HDF5 is required, but the user may be using h5cc, in which case
# they don't need to specify --with-hdf5.  They can also use
# --with-hdf5=/path/to/hdf5 to give a specific path.
HAVE_HDF5="yes"
AC_ARG_WITH([hdf5],
            [AC_HELP_STRING([--with-hdf5=DIR],
                            [Specify path to HDF5 library to use while building
                            [default=yes]])],,
            withval=yes)

case $withval in
  yes)
    ;;
  no)
    AC_MSG_ERROR([HDF5 disabled in confugre, but is required to build HDF-EOS5.])
    ;;
  *)
    case "$withval" in
      *,*)
        hdf5_inc="`echo $withval |cut -f1 -d,`"
        hdf5_lib="`echo $withval |cut -f2 -d, -s`"
        ;;
      *)
        if test -n "$withval"; then
          hdf5_inc="$withval/include"
          hdf5_lib="$withval/lib"
        fi
        ;;
    esac

    dnl Trying to include -I/usr/include and -L/usr/lib is redundant and
    dnl can mess some compilers up.
    if test "X$hdf5_inc" = "X/usr/include"; then
      hdf5_inc=""
    fi
    if test "X$hdf5_lib" = "X/usr/lib"; then
      hdf5_lib=""
    fi

    if test -n "$hdf5_inc"; then
      CPPFLAGS="$CPPFLAGS -I$hdf5_inc"
      CFLAGS="$CFLAGS -I$hdf5_inc"
    fi

    if test -n "$hdf5_lib"; then
      LDFLAGS="$LDFLAGS -L$hdf5_lib"
    fi
    ;;
esac

dnl See if we have a valid linking path to the HDF5 library, either because
dnl it's in the user's path or because they provided the correct path using
dnl --with-hdf5
AC_CHECK_HEADERS([hdf5.h], , [HAVE_HDF5="no"])
AC_CHECK_LIB(hdf5, H5Fcreate,, [HAVE_HDF5="no"])

if test "X$HAVE_HDF5" = "Xno"; then
  AC_MSG_ERROR([can't link against HDF5 library])
fi


# Check whether HDF5 threadsafety is enabled
AC_MSG_CHECKING([if HDF5 threadsafe mode is enabled])
AC_TRY_RUN([
#include "hdf5.h"

int main(void) {
#ifdef H5_HAVE_THREADSAFE
  return 0;
#else
  return 1;
#endif
} ], 
  [ AC_MSG_RESULT([yes])
    THREADSAFE="yes"],
  [AC_MSG_RESULT([no])
    THREADSAFE="no"])

# Record threadsafe status in config.h and for Makefiles
if test "X$THREADSAFE" = "Xyes"; then
  AC_DEFINE([_HDFEOS5_THREADSAFE], [1],
            [Define if threadsafe HDF-EOS is enabled])
fi

AM_CONDITIONAL([THREADSAFE_CONDITIONAL], [test "X$THREADSAFE" = "Xyes"])


if test "x$HAVE_HDF5" = "xyes"; then
  dnl Check if HDF5 is linked with SZIP encoder

  AC_MSG_CHECKING([for hdf5 szip decoding filter])
  AC_CACHE_VAL([he5_cv_hdf5_szip_can_decode],
      [AC_TRY_RUN([
      #include <H5Ipublic.h>
      #include <H5Zpublic.h>
      
      int main(int argc, char **argv)
      {
              herr_t ret;
              unsigned int flags = 0;
              int decoder = 0;
      
              ret = H5Zget_filter_info(H5Z_FILTER_SZIP, &flags);
	      if (ret < 0) exit(1);
              decoder = flags & H5Z_FILTER_CONFIG_DECODE_ENABLED;
              if (decoder) exit(0);
              else exit(1);
      }
      ], [he5_cv_hdf5_szip_can_decode=yes], [he5_cv_hdf5_szip_can_decode=no],)])
  if test ${he5_cv_hdf5_szip_can_decode} = "yes"; then
    AC_DEFINE(HAVE_HDF5_SZIP_DECODER, 1,
	    [Define if HDF5 has szip decoder filter])
    AC_DEFINE(H5_HAVE_FILTER_SZIP, 1,
	    [Define if HDF5 has szip any type of filter])
    AC_MSG_RESULT([yes])
  else
    AC_MSG_RESULT([no])
  fi

  AC_MSG_CHECKING([for hdf5 szip encoding filter])
  AC_CACHE_VAL([he5_cv_hdf5_szip_can_encode],
      [AC_TRY_RUN([
      #include <H5Ipublic.h>
      #include <H5Zpublic.h>
      
      int main(int argc, char **argv)
      {
              herr_t ret;
              unsigned int flags = 0;
              int encoder = 0;
      
              ret = H5Zget_filter_info(H5Z_FILTER_SZIP, &flags);
	      if (ret < 0) exit(1);
              encoder = flags & H5Z_FILTER_CONFIG_ENCODE_ENABLED;
              if (encoder) exit(0);
              else exit(1);
      }
      ], [he5_cv_hdf5_szip_can_encode=yes], [he5_cv_hdf5_szip_can_encode=no],)])

  if test ${he5_cv_hdf5_szip_can_encode} = "yes"; then
    AC_DEFINE(HAVE_HDF5_SZIP_ENCODER, 1,
	    [Define if HDF5 has szip encoder filter])
    AC_MSG_RESULT([yes])
  else
    AC_MSG_RESULT([no])
  fi

  dnl Check if SZIP linked with HDF5 has the same configuration as SZIP given by --with-szlib option has
  if test ${he5_cv_hdf5_szip_can_decode} = "no"; then
    if test "X$HAVE_SZLIB" = "Xyes"; then
      AC_MSG_ERROR([HDF5 was linked without SZIP, but --with-szlib was given])
    fi
  else
    if test "X$HAVE_SZLIB" != "Xyes"; then
      AC_MSG_ERROR([HDF5 was linked with SZIP, but --with-szlib was not given])
    fi
    if test ${he5_cv_szlib_functional} = "no"; then
      AC_MSG_ERROR([SZIP specified in --with-szlib is not functional])
    fi
    if test ${he5_cv_hdf5_szip_can_encode} = "no"; then
      if test ${he5_cv_szlib_can_encode} = "yes"; then
	AC_MSG_ERROR([HDF5 was linked without SZIP encoder, but yours has SZIP encoder])
      fi
    else
      if test ${he5_cv_szlib_can_encode} = "no"; then
	AC_MSG_ERROR([HDF5 was linked with SZIP encoder, but yours does not have SZIP encoder])
      fi
    fi
  fi
fi

# Set CFLAGS to prevent AC_PROG_CC from setting it
CFLAGS=$CFLAGS

# Checks for programs.
AC_PROG_CC
AC_PROG_INSTALL
AC_PROG_LN_S
AC_PROG_MAKE_SET

# Checks for libraries.

# Checks for header files.
AC_HEADER_STDC
AC_CHECK_HEADERS([malloc.h stdlib.h string.h limits.h])

# Checks for typedefs, structures, and compiler characteristics.
AC_C_CONST
AC_TYPE_OFF_T
AC_TYPE_SIZE_T

# Checks for library functions.
AC_FUNC_MALLOC
AC_FUNC_MEMCMP
AC_FUNC_REALLOC
AC_FUNC_ERROR_AT_LINE
AC_CHECK_FUNCS([memchr memmove memset strchr strstr pow sqrt])

# Check whether testdrivers directory is present.  The user might have
# downloaded HDF-EOS5 but not the tests.
AC_MSG_CHECKING([for testdrivers directory])
if test -d "${srcdir}/testdrivers"; then
  TESTDRIVERS_DIR="yes"
  AC_MSG_RESULT([present])

  # If the testdrivers directory is present, see if it contains a file named
  # 'makefile'.  If so, rename the file so it doesn't cause confusion later
  # on.
  if test -e "testdrivers/makefile"; then
    mv testdrivers/makefile testdrivers/makefile_orig
  fi

else
  TESTDRIVERS_DIR="no"
  AC_MSG_RESULT([not found])
  AC_MSG_WARN([testdrivers directory is not present. Tests will not be run])
fi

AC_ARG_ENABLE([install-include],
              [AC_HELP_STRING([--enable-install-include],
                              [HDF-EOS5 normally only installs libraries,
                               assuming that users will use the headers in
                               the include directories.
                               Users who want the standard automake
                               behavior of installing both libraries and
                               header files should enable this option.])],
              [INSTALL_INCLUDE=$enableval])

AM_CONDITIONAL([TESTDRIVERS_CONDITIONAL], [test "X$TESTDRIVERS_DIR" = "Xyes"])
AM_CONDITIONAL([INSTALL_INCLUDE_CONDITIONAL], [test "X$INSTALL_INCLUDE" = "Xyes"])
AM_CONDITIONAL([F2CFORTRAN_CONDITIONAL], [test "X$F2CFORTRAN_MACRO" = "Xyes"])
AM_CONDITIONAL([F2CFORTRAN_90_CONDITIONAL], [test "X$F2CFORTRAN_90" = "Xyes"])
AM_CONDITIONAL([F2CFORTRAN_32PTR_CONDITIONAL], [test "X$F2CFORTRAN_32PTR" = "Xyes"])
AM_CONDITIONAL([SZIP_ENCODER_CONDITIONAL], [test "X$USE_SZIP_ENCODER" = "Xyes"])

AC_CONFIG_FILES([Makefile
                 include/Makefile
                 src/Makefile
                 samples/Makefile
		 hdf-eos5.pc])

if test "X$TESTDRIVERS_DIR" = "Xyes"; then
  AC_CONFIG_FILES([ testdrivers/Makefile
                 testdrivers/grid/Makefile
                 testdrivers/point/Makefile
                 testdrivers/swath/Makefile
                 testdrivers/threads/Makefile
                 testdrivers/za/Makefile])
fi

AC_OUTPUT