1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162
163
164
165
166
167
168
169
170
171
172
173
174
175
176
177
178
179
180
181
182
183
184
185
186
187
188
189
190
191
192
193
194
195
196
197
198
199
200
201
202
203
204
205
206
207
208
209
210
211
212
213
214
215
216
217
218
219
220
221
222
223
224
225
226
227
228
229
230
231
232
233
234
235
236
237
238
239
240
241
242
243
244
245
246
247
248
249
250
251
252
253
254
255
256
257
258
259
260
261
262
263
264
265
266
267
268
269
270
271
272
273
274
275
276
277
278
279
280
281
282
283
284
285
286
287
288
289
290
291
292
293
294
295
296
297
298
299
300
301
302
303
304
305
306
307
308
309
310
311
312
313
314
315
316
317
318
319
320
321
322
323
324
325
326
327
328
329
330
331
332
333
334
335
336
337
338
339
340
341
342
343
344
345
346
347
348
349
350
351
352
353
354
355
356
357
358
359
360
361
362
363
364
365
366
367
368
369
370
371
372
373
374
375
376
377
378
379
380
381
382
383
384
385
386
387
388
389
390
391
392
393
394
395
396
397
398
399
400
401
402
403
404
405
406
407
408
409
410
411
412
413
414
415
416
417
418
419
420
421
422
423
424
425
426
427
428
429
430
431
432
433
434
435
436
437
438
439
440
441
442
443
444
445
446
447
448
449
450
451
452
453
454
455
456
457
458
459
460
461
462
463
464
465
466
467
468
469
470
471
472
473
474
475
476
477
478
479
480
481
482
483
484
485
486
487
488
489
490
491
492
493
494
495
496
497
498
499
500
501
502
503
504
505
506
507
508
509
510
511
512
513
514
515
516
517
518
519
520
521
522
523
524
525
526
527
528
529
530
531
532
533
534
535
536
537
538
539
540
541
542
543
544
545
546
547
548
549
550
551
552
553
554
555
556
557
558
559
560
561
562
563
564
565
566
567
568
569
570
571
572
573
574
575
576
577
578
579
580
581
582
583
584
585
586
587
588
589
590
591
592
593
594
595
596
597
598
599
600
601
602
603
604
605
606
607
608
609
610
611
612
613
614
615
616
617
618
619
620
621
622
623
624
625
626
627
628
629
630
631
632
633
634
635
636
637
638
639
640
641
642
643
644
645
646
647
648
649
650
651
652
653
654
655
656
657
658
659
660
661
662
663
664
665
666
667
668
669
670
671
672
673
674
675
676
677
678
679
680
681
682
683
684
685
686
687
688
689
690
691
692
693
694
695
696
697
698
699
700
701
702
703
704
705
706
707
708
709
710
711
712
713
714
715
716
717
718
719
720
721
722
723
724
725
726
727
728
729
730
731
732
733
734
735
736
737
738
739
740
741
742
743
744
745
746
747
748
749
750
751
752
753
754
755
756
757
758
759
760
761
762
763
764
765
766
767
768
769
770
771
772
773
774
775
776
777
778
779
780
781
782
783
784
785
786
787
788
789
790
791
792
793
794
795
796
797
798
799
800
801
802
803
804
805
806
807
808
809
810
811
812
813
814
815
816
817
818
819
820
821
822
823
824
825
826
827
828
829
830
831
832
833
834
835
836
837
838
839
840
841
842
843
844
845
846
847
848
849
850
851
852
853
854
855
856
857
858
859
860
861
862
863
864
865
866
867
868
869
870
871
872
873
874
875
876
877
878
879
880
881
882
883
884
885
886
887
888
889
890
891
892
893
894
895
896
897
898
899
900
901
902
903
904
905
906
907
908
909
910
911
912
913
914
915
916
917
918
919
920
921
922
923
924
925
926
927
928
929
930
931
932
933
934
935
936
937
938
939
940
941
942
943
944
945
946
947
948
949
950
951
952
953
954
955
956
957
958
959
960
961
962
963
964
965
966
967
968
969
970
971
972
973
974
975
976
977
978
979
980
981
982
983
984
985
986
987
988
989
990
991
992
993
994
995
996
997
998
999
1000
1001
1002
1003
1004
1005
1006
1007
1008
1009
1010
1011
1012
1013
1014
1015
1016
1017
1018
1019
1020
1021
1022
1023
1024
1025
1026
1027
1028
1029
1030
1031
1032
1033
1034
1035
1036
1037
1038
1039
1040
1041
1042
1043
1044
1045
1046
1047
1048
1049
1050
1051
1052
1053
1054
1055
1056
1057
1058
1059
1060
1061
1062
1063
1064
1065
1066
1067
1068
1069
1070
1071
1072
1073
1074
1075
1076
1077
1078
1079
1080
1081
1082
1083
1084
1085
1086
1087
1088
1089
1090
1091
1092
1093
1094
1095
1096
1097
1098
1099
1100
1101
1102
1103
1104
1105
1106
1107
1108
1109
1110
1111
1112
1113
1114
1115
1116
1117
1118
1119
1120
1121
1122
1123
1124
1125
1126
1127
1128
1129
1130
1131
1132
1133
1134
1135
1136
1137
1138
1139
1140
1141
1142
1143
1144
1145
1146
1147
1148
1149
1150
1151
1152
1153
1154
1155
1156
1157
1158
1159
1160
1161
1162
1163
1164
1165
1166
1167
1168
1169
1170
1171
1172
1173
1174
1175
1176
1177
1178
1179
1180
1181
1182
1183
1184
1185
1186
1187
1188
1189
1190
1191
1192
1193
1194
1195
1196
1197
1198
1199
1200
1201
1202
1203
1204
1205
1206
1207
1208
1209
1210
1211
1212
1213
1214
1215
1216
1217
1218
1219
1220
1221
1222
1223
1224
1225
1226
1227
1228
1229
1230
1231
1232
1233
1234
1235
1236
1237
1238
1239
1240
1241
1242
1243
1244
1245
1246
1247
1248
1249
1250
1251
1252
1253
1254
1255
1256
1257
1258
1259
1260
1261
1262
1263
1264
1265
1266
1267
1268
1269
1270
1271
1272
1273
1274
1275
1276
1277
1278
1279
1280
1281
1282
1283
1284
1285
1286
1287
1288
1289
1290
1291
1292
1293
1294
1295
1296
1297
1298
1299
1300
1301
1302
1303
1304
1305
1306
1307
1308
1309
1310
1311
1312
1313
1314
1315
1316
1317
1318
1319
1320
1321
1322
1323
1324
1325
1326
1327
1328
1329
1330
1331
1332
1333
1334
1335
1336
1337
1338
1339
1340
1341
1342
1343
1344
1345
1346
1347
1348
1349
1350
1351
1352
1353
1354
1355
1356
1357
1358
1359
1360
1361
1362
1363
1364
1365
1366
1367
1368
1369
1370
1371
1372
1373
1374
1375
1376
1377
1378
1379
1380
1381
1382
1383
1384
1385
1386
1387
1388
1389
1390
1391
1392
1393
1394
1395
1396
1397
1398
1399
1400
1401
1402
1403
1404
1405
1406
1407
1408
1409
1410
1411
1412
1413
1414
1415
1416
1417
1418
1419
1420
1421
1422
1423
1424
1425
1426
1427
1428
1429
1430
1431
1432
1433
1434
1435
1436
1437
1438
1439
1440
1441
1442
1443
1444
1445
1446
1447
1448
1449
1450
1451
1452
1453
1454
1455
1456
1457
1458
1459
1460
1461
1462
1463
1464
1465
1466
1467
1468
1469
1470
1471
1472
1473
1474
1475
1476
1477
1478
1479
1480
1481
1482
1483
1484
1485
1486
1487
1488
1489
1490
1491
1492
1493
1494
1495
1496
1497
1498
1499
1500
1501
1502
1503
1504
1505
1506
1507
1508
1509
1510
1511
1512
1513
1514
1515
1516
1517
1518
1519
1520
1521
1522
1523
1524
1525
1526
1527
1528
1529
1530
1531
1532
1533
1534
1535
1536
1537
1538
1539
1540
1541
1542
1543
1544
1545
1546
1547
1548
1549
1550
1551
1552
1553
1554
1555
1556
1557
1558
1559
1560
1561
1562
1563
1564
1565
1566
1567
1568
1569
1570
1571
1572
1573
1574
1575
1576
1577
1578
1579
1580
1581
1582
1583
1584
1585
1586
1587
1588
1589
1590
1591
1592
1593
1594
1595
1596
1597
1598
1599
1600
1601
1602
1603
1604
1605
1606
1607
1608
1609
1610
1611
1612
1613
1614
1615
1616
1617
1618
1619
1620
1621
1622
1623
1624
1625
1626
1627
1628
1629
1630
1631
1632
1633
1634
1635
1636
1637
1638
1639
1640
1641
1642
1643
1644
1645
1646
1647
1648
1649
1650
1651
1652
1653
1654
1655
1656
1657
1658
1659
1660
1661
1662
1663
1664
1665
1666
1667
1668
1669
1670
1671
1672
1673
1674
1675
1676
1677
1678
1679
1680
1681
1682
1683
1684
1685
1686
1687
1688
1689
1690
1691
1692
1693
1694
1695
1696
1697
1698
1699
1700
1701
1702
1703
1704
1705
1706
1707
1708
1709
1710
1711
1712
1713
1714
1715
1716
1717
1718
1719
1720
1721
1722
1723
1724
1725
1726
1727
1728
1729
1730
1731
1732
1733
1734
1735
1736
1737
1738
1739
1740
1741
1742
1743
1744
1745
1746
1747
1748
1749
1750
1751
1752
1753
1754
1755
1756
1757
1758
1759
1760
1761
1762
1763
1764
1765
1766
1767
1768
1769
1770
1771
1772
1773
1774
1775
1776
1777
1778
1779
1780
1781
1782
1783
1784
1785
1786
1787
1788
1789
1790
1791
1792
1793
1794
1795
1796
1797
1798
1799
1800
1801
1802
1803
1804
1805
1806
1807
1808
1809
1810
1811
1812
1813
1814
1815
1816
1817
1818
1819
1820
1821
1822
1823
1824
1825
1826
1827
1828
1829
1830
1831
1832
1833
1834
1835
1836
1837
1838
1839
1840
1841
1842
1843
1844
1845
1846
1847
1848
1849
1850
1851
1852
1853
1854
1855
1856
1857
1858
1859
1860
1861
1862
1863
1864
1865
1866
1867
1868
1869
1870
1871
1872
1873
1874
1875
1876
1877
1878
1879
1880
1881
1882
1883
1884
1885
1886
1887
1888
1889
1890
1891
1892
1893
1894
1895
1896
1897
1898
1899
1900
1901
1902
1903
1904
1905
1906
1907
1908
1909
1910
1911
1912
1913
1914
1915
1916
1917
1918
1919
1920
1921
1922
1923
1924
1925
1926
1927
1928
1929
1930
1931
1932
1933
1934
1935
1936
1937
1938
1939
1940
1941
1942
1943
1944
1945
1946
1947
1948
1949
1950
1951
1952
1953
1954
1955
1956
1957
1958
1959
1960
1961
1962
1963
1964
1965
1966
1967
1968
1969
1970
1971
1972
1973
1974
1975
1976
1977
1978
1979
1980
1981
1982
1983
1984
1985
1986
1987
1988
1989
1990
1991
1992
1993
1994
1995
1996
1997
1998
1999
2000
2001
2002
2003
2004
2005
2006
2007
2008
2009
2010
2011
2012
2013
2014
2015
2016
2017
2018
2019
2020
2021
2022
2023
2024
2025
2026
2027
2028
2029
2030
2031
2032
2033
2034
2035
2036
2037
2038
2039
2040
2041
2042
2043
2044
2045
2046
2047
2048
2049
2050
2051
2052
2053
2054
2055
2056
2057
2058
2059
2060
2061
2062
2063
2064
2065
2066
2067
2068
2069
2070
2071
2072
2073
2074
2075
2076
2077
2078
2079
2080
2081
2082
2083
2084
2085
2086
2087
2088
2089
2090
2091
2092
2093
2094
2095
2096
2097
2098
2099
2100
2101
2102
2103
2104
2105
2106
2107
2108
2109
2110
2111
2112
2113
2114
2115
2116
2117
2118
2119
2120
2121
2122
2123
2124
2125
2126
2127
2128
2129
2130
2131
2132
2133
2134
2135
2136
2137
2138
2139
2140
2141
2142
2143
2144
2145
2146
2147
2148
2149
2150
2151
2152
2153
2154
2155
2156
2157
2158
2159
2160
2161
2162
2163
2164
2165
2166
2167
2168
2169
2170
2171
2172
2173
2174
2175
2176
2177
2178
2179
2180
2181
2182
2183
2184
2185
2186
2187
2188
2189
2190
2191
2192
2193
2194
2195
2196
2197
2198
2199
2200
2201
2202
2203
2204
2205
2206
2207
2208
2209
2210
2211
2212
2213
2214
2215
2216
2217
2218
2219
2220
2221
2222
2223
2224
2225
2226
2227
2228
2229
2230
2231
2232
2233
2234
2235
2236
2237
2238
2239
2240
2241
2242
2243
2244
2245
2246
2247
2248
2249
2250
2251
2252
2253
2254
2255
2256
2257
2258
2259
2260
2261
2262
2263
2264
2265
2266
2267
2268
2269
2270
2271
2272
2273
2274
2275
2276
2277
2278
2279
2280
2281
2282
2283
2284
2285
2286
2287
2288
2289
2290
2291
2292
2293
2294
2295
|
(* ========================================================================= *)
(* Analysis of solutions to Pell equation *)
(* ========================================================================= *)
needs "Library/analysis.ml";;
needs "Library/transc.ml";;
needs "Library/prime.ml";;
prioritize_real();;
let PELL_INDUCTION = prove
(`P 0 /\ P 1 /\ (!n. P n /\ P (n + 1) ==> P(n + 2)) ==> !n. P n`,
STRIP_TAC THEN
SUBGOAL_THEN `!n. P n /\ P(n + 1)` (fun th -> REWRITE_TAC[th]) THEN
INDUCT_TAC THEN ASM_REWRITE_TAC[ADD_CLAUSES] THEN
ASM_SIMP_TAC[ADD1; ARITH_RULE `SUC(n + 1) = n + 2`]);;
(* ------------------------------------------------------------------------- *)
(* Useful number-theoretic basics *)
(* ------------------------------------------------------------------------- *)
let ROOT_NONPOWER = prove
(`!p q d n. ~(q = 0) /\ (p EXP n = d * q EXP n) ==> ?a. d = a EXP n`,
REPEAT GEN_TAC THEN
ASM_CASES_TAC `n = 0` THEN ASM_SIMP_TAC[EXP; MULT_CLAUSES] THEN
STRIP_TAC THEN
MP_TAC(SPECL [`n:num`; `q:num`; `p:num`] DIVIDES_EXP2_REV) THEN
ASM_REWRITE_TAC[divides; LEFT_IMP_EXISTS_THM] THEN
DISCH_THEN(MP_TAC o SPEC `d:num`) THEN
REWRITE_TAC[EQT_INTRO(SPEC_ALL MULT_SYM)] THEN
ONCE_REWRITE_TAC[MULT_SYM] THEN
DISCH_THEN(X_CHOOSE_THEN `a:num` SUBST_ALL_TAC) THEN
EXISTS_TAC `a:num` THEN
UNDISCH_TAC `(a * q) EXP n = d * q EXP n` THEN
ASM_SIMP_TAC[MULT_EXP; EQ_MULT_RCANCEL; EXP_EQ_0]);;
let INTEGER_SUB_LEMMA = prove
(`!x y. ?n. (&x - &y) pow 2 = &n pow 2`,
REPEAT STRIP_TAC THEN
DISJ_CASES_THEN MP_TAC (SPECL [`&x`; `&y`] REAL_LE_TOTAL) THEN
REWRITE_TAC[REAL_OF_NUM_LE] THEN DISCH_TAC THENL
[EXISTS_TAC `y - x:num`; EXISTS_TAC `x - y:num`] THEN
ASM_SIMP_TAC[GSYM REAL_OF_NUM_SUB] THEN
REWRITE_TAC[REAL_POW_2] THEN REAL_ARITH_TAC);;
let SQRT_LINEAR_EQ = prove
(`!a u v x y.
2 <= a
==> ((&u + &v * sqrt(&a pow 2 - &1) = &x + &y * sqrt(&a pow 2 - &1)) <=>
(u = x) /\ (v = y))`,
REPEAT STRIP_TAC THEN EQ_TAC THEN SIMP_TAC[] THEN
REWRITE_TAC[REAL_ARITH `(a + b = c + d) <=> (a - c = d - b)`] THEN
REWRITE_TAC[GSYM REAL_SUB_RDISTRIB] THEN
DISCH_THEN(MP_TAC o C AP_THM `2` o AP_TERM `(pow)`) THEN
REWRITE_TAC[REAL_POW_MUL] THEN
ASM_SIMP_TAC[SQRT_POW_2; REAL_SUB_LE; REAL_POW_LE_1; REAL_OF_NUM_LE;
ARITH_RULE `2 <= a ==> 1 <= a`] THEN
X_CHOOSE_TAC `p:num` (SPECL [`u:num`; `x:num`] INTEGER_SUB_LEMMA) THEN
X_CHOOSE_TAC `q:num` (SPECL [`y:num`; `v:num`] INTEGER_SUB_LEMMA) THEN
ASM_REWRITE_TAC[] THEN
SUBGOAL_THEN `&a pow 2 - &1 = &(a EXP 2 - 1)` SUBST1_TAC THENL
[REWRITE_TAC[REAL_OF_NUM_POW] THEN MATCH_MP_TAC REAL_OF_NUM_SUB THEN
REWRITE_TAC[GSYM REAL_OF_NUM_LE; GSYM REAL_OF_NUM_POW] THEN
ASM_SIMP_TAC[REAL_POW_LE_1; REAL_OF_NUM_LE;
ARITH_RULE `2 <= a ==> 1 <= a`]; ALL_TAC] THEN
REWRITE_TAC[REAL_OF_NUM_POW; REAL_OF_NUM_MUL; REAL_OF_NUM_EQ] THEN
DISCH_TAC THEN
MP_TAC(SPECL [`p:num`; `q:num`; `a EXP 2 - 1`; `2`] ROOT_NONPOWER) THEN
ASM_REWRITE_TAC[EQT_INTRO(SPEC_ALL MULT_SYM)] THEN
MATCH_MP_TAC(TAUT `~b /\ (a ==> c) ==> ((~a ==> b) ==> c)`) THEN
CONJ_TAC THENL
[DISCH_THEN(X_CHOOSE_THEN `b:num` MP_TAC) THEN
DISCH_THEN(MP_TAC o MATCH_MP
(ARITH_RULE `(a - 1 = b) ==> 1 < a ==> (a - b = 1)`)) THEN
SUBST1_TAC(SYM(SPEC `a:num` (CONJUNCT1 EXP))) THEN
ASM_REWRITE_TAC[LT_EXP; ARITH_LE; ARITH_LT] THEN
REWRITE_TAC[EXP] THEN
DISCH_THEN(MP_TAC o MATCH_MP (ARITH_RULE
`(a - b = 1) ==> (a = b + 1)`)) THEN
REWRITE_TAC[GSYM REAL_OF_NUM_EQ; GSYM REAL_OF_NUM_ADD; GSYM
REAL_OF_NUM_POW] THEN
REWRITE_TAC[REAL_POW_2] THEN
DISCH_THEN(MP_TAC o MATCH_MP
(REAL_ARITH `(a * a = b * b + &1) ==> ((a + b) * (a - b) = &1)`)) THEN
DISCH_THEN(MP_TAC o C AP_THM `2` o AP_TERM `(pow)`) THEN
REWRITE_TAC[REAL_POW_MUL] THEN
X_CHOOSE_TAC `c:num` (SPECL [`a:num`; `b:num`] INTEGER_SUB_LEMMA) THEN
ASM_REWRITE_TAC[] THEN
REWRITE_TAC[GSYM REAL_POW_MUL] THEN
REWRITE_TAC[REAL_OF_NUM_POW; REAL_OF_NUM_MUL; REAL_OF_NUM_ADD] THEN
REWRITE_TAC[REAL_OF_NUM_EQ; EXP_ONE; EXP_EQ_1; MULT_EQ_1; ARITH_EQ] THEN
UNDISCH_TAC `2 <= a` THEN ARITH_TAC;
DISCH_THEN SUBST_ALL_TAC THEN
UNDISCH_TAC `p EXP 2 = 0 EXP 2 * (a EXP 2 - 1)` THEN
REWRITE_TAC[ARITH; MULT_CLAUSES; EXP_EQ_0] THEN
DISCH_THEN SUBST_ALL_TAC THEN
UNDISCH_TAC `(&u - &x) pow 2 = &0 pow 2` THEN
UNDISCH_TAC `(&y - &v) pow 2 = &0 pow 2` THEN
CONV_TAC REAL_RAT_REDUCE_CONV THEN
REWRITE_TAC[REAL_POW_EQ_0; ARITH_EQ; REAL_SUB_0] THEN
SIMP_TAC[REAL_OF_NUM_EQ]]);;
(* ------------------------------------------------------------------------- *)
(* Recurrence defining the solutions. *)
(* ------------------------------------------------------------------------- *)
let X_DEF =
let th = prove
(`!a. ?X. !n. X n = if n = 0 then 1
else if n = 1 then a
else 2 * a * X(n-1) - X(n-2)`,
GEN_TAC THEN MATCH_MP_TAC(MATCH_MP WF_REC WF_num) THEN
REPEAT STRIP_TAC THEN
REPEAT(COND_CASES_TAC THEN ASM_REWRITE_TAC[]) THEN
BINOP_TAC THEN
ASM_SIMP_TAC[ARITH_RULE `n - m < n <=> ~(m = 0) /\ ~(n = 0)`; ARITH_EQ]) in
new_specification ["X"] (REWRITE_RULE[SKOLEM_THM] th);;
let X_CLAUSES = prove
(`(!a. X a 0 = 1) /\
(!a. X a 1 = a) /\
(!a n. X a (n + 2) = 2 * a * X a (n + 1) - X a (n))`,
REPEAT STRIP_TAC THEN GEN_REWRITE_TAC LAND_CONV [X_DEF] THEN
REWRITE_TAC[ARITH_EQ; ADD_EQ_0; ARITH_RULE `~(n + 2 = 1)`] THEN
REWRITE_TAC[ARITH_RULE `((n + 2) - 2 = n) /\ ((n + 2) - 1 = n + 1)`]);;
let Y_DEF =
let th = prove
(`!a. ?Y. !n. Y n = if n = 0 then 0
else if n = 1 then 1
else 2 * a * Y(n-1) - Y(n-2)`,
GEN_TAC THEN MATCH_MP_TAC(MATCH_MP WF_REC WF_num) THEN
REPEAT STRIP_TAC THEN
REPEAT(COND_CASES_TAC THEN ASM_REWRITE_TAC[]) THEN
BINOP_TAC THEN
ASM_SIMP_TAC[ARITH_RULE `n - m < n <=> ~(m = 0) /\ ~(n = 0)`; ARITH_EQ]) in
new_specification ["Y"] (REWRITE_RULE[SKOLEM_THM] th);;
let Y_CLAUSES = prove
(`(!a. Y a 0 = 0) /\
(!a. Y a 1 = 1) /\
(!a n. Y a (n + 2) = 2 * a * Y a (n + 1) - Y a (n))`,
REPEAT STRIP_TAC THEN GEN_REWRITE_TAC LAND_CONV [Y_DEF] THEN
REWRITE_TAC[ARITH_EQ; ADD_EQ_0; ARITH_RULE `~(n + 2 = 1)`] THEN
REWRITE_TAC[ARITH_RULE `((n + 2) - 2 = n) /\ ((n + 2) - 1 = n + 1)`]);;
(* ------------------------------------------------------------------------- *)
(* An obvious but tiresome lemma: the Xs and Ys increase. *)
(* ------------------------------------------------------------------------- *)
let X_INCREASES = prove
(`!a n. ~(a = 0) ==> X a n <= X a (n + 1)`,
GEN_TAC THEN REWRITE_TAC[RIGHT_FORALL_IMP_THM] THEN DISCH_TAC THEN
MATCH_MP_TAC num_WF THEN REPEAT STRIP_TAC THEN
ASM_CASES_TAC `n = 0` THEN
ASM_REWRITE_TAC[X_CLAUSES; ADD_CLAUSES;
ARITH_RULE `1 <= a <=> ~(a = 0)`] THEN
GEN_REWRITE_TAC RAND_CONV [X_DEF] THEN
ASM_REWRITE_TAC[ADD_EQ_0; ARITH_EQ;
ARITH_RULE `(n + 1 = 1) <=> (n = 0)`] THEN
REWRITE_TAC[ADD_SUB] THEN
MATCH_MP_TAC(ARITH_RULE `a + b <= c ==> a <= c - b:num`) THEN
MATCH_MP_TAC LE_TRANS THEN EXISTS_TAC `2 * X a n` THEN CONJ_TAC THENL
[ALL_TAC;
REWRITE_TAC[LE_MULT_LCANCEL; ARITH_EQ] THEN
UNDISCH_TAC `~(a = 0)` THEN SPEC_TAC(`a:num`,`a:num`) THEN
INDUCT_TAC THEN REWRITE_TAC[ADD_CLAUSES; MULT_CLAUSES] THEN
REWRITE_TAC[ARITH_RULE `a <= b + a:num`]] THEN
MATCH_MP_TAC(ARITH_RULE `b <= a ==> a + b <= 2 * a`) THEN
SUBGOAL_THEN `n = (n - 1) + 1` SUBST1_TAC THENL
[UNDISCH_TAC `~(n = 0)` THEN ARITH_TAC; ALL_TAC] THEN
REWRITE_TAC[ARITH_RULE `((n + 1) + 1) - 2 = n`] THEN
FIRST_ASSUM MATCH_MP_TAC THEN
UNDISCH_TAC `~(n = 0)` THEN ARITH_TAC);;
let Y_INCREASES = prove
(`!a n. ~(a = 0) ==> Y a n <= Y a (n + 1)`,
GEN_TAC THEN REWRITE_TAC[RIGHT_FORALL_IMP_THM] THEN DISCH_TAC THEN
MATCH_MP_TAC num_WF THEN REPEAT STRIP_TAC THEN
ASM_CASES_TAC `n = 0` THEN
ASM_REWRITE_TAC[Y_CLAUSES; ADD_CLAUSES; LE_0] THEN
GEN_REWRITE_TAC RAND_CONV [Y_DEF] THEN
ASM_REWRITE_TAC[ADD_EQ_0; ARITH_EQ;
ARITH_RULE `(n + 1 = 1) <=> (n = 0)`] THEN
REWRITE_TAC[ADD_SUB] THEN
MATCH_MP_TAC(ARITH_RULE `a + b <= c ==> a <= c - b:num`) THEN
MATCH_MP_TAC LE_TRANS THEN EXISTS_TAC `2 * Y a n` THEN CONJ_TAC THENL
[ALL_TAC;
REWRITE_TAC[LE_MULT_LCANCEL; ARITH_EQ] THEN
UNDISCH_TAC `~(a = 0)` THEN SPEC_TAC(`a:num`,`a:num`) THEN
INDUCT_TAC THEN REWRITE_TAC[ADD_CLAUSES; MULT_CLAUSES] THEN
REWRITE_TAC[ARITH_RULE `a <= b + a:num`]] THEN
MATCH_MP_TAC(ARITH_RULE `b <= a ==> a + b <= 2 * a`) THEN
SUBGOAL_THEN `n = (n - 1) + 1` SUBST1_TAC THENL
[UNDISCH_TAC `~(n = 0)` THEN ARITH_TAC; ALL_TAC] THEN
REWRITE_TAC[ARITH_RULE `((n + 1) + 1) - 2 = n`] THEN
FIRST_ASSUM MATCH_MP_TAC THEN
UNDISCH_TAC `~(n = 0)` THEN ARITH_TAC);;
(* ------------------------------------------------------------------------- *)
(* Show that the expression is a power of the basis. *)
(* ------------------------------------------------------------------------- *)
let XY_POWER_POS = prove
(`!a n. ~(a = 0) ==> (&(X a n) + &(Y a n) * sqrt(&a pow 2 - &1) =
(&a + sqrt(&a pow 2 - &1)) pow n)`,
GEN_TAC THEN REWRITE_TAC[RIGHT_FORALL_IMP_THM] THEN DISCH_TAC THEN
MATCH_MP_TAC num_WF THEN GEN_TAC THEN DISCH_TAC THEN
ONCE_REWRITE_TAC[X_DEF; Y_DEF] THEN
COND_CASES_TAC THEN ASM_REWRITE_TAC[ARITH_EQ] THEN
REWRITE_TAC[REAL_MUL_LZERO; REAL_ADD_RID; real_pow] THEN
COND_CASES_TAC THEN ASM_REWRITE_TAC[REAL_POW_1; REAL_MUL_LID] THEN
REWRITE_TAC[REAL_OF_NUM_ADD] THEN
SUBGOAL_THEN
`(&(2 * a * X a (n - 1) - X a (n - 2)) =
&(2 * a * X a (n - 1)) - &(X a (n - 2))) /\
(&(2 * a * Y a (n - 1) - Y a (n - 2)) =
&(2 * a * Y a (n - 1)) - &(Y a (n - 2)))`
(CONJUNCTS_THEN SUBST1_TAC)
THENL
[CONJ_TAC THEN MATCH_MP_TAC(GSYM REAL_OF_NUM_SUB) THEN
MATCH_MP_TAC(ARITH_RULE
`x <= y /\ y <= 2 * a * y ==> x <= 2 * a * y`) THEN
ASM_SIMP_TAC[ARITH_RULE
`~(n = 0) /\ ~(n = 1) ==> (n - 1 = (n - 2) + 1)`] THEN
ASM_SIMP_TAC[X_INCREASES; Y_INCREASES] THEN
REWRITE_TAC[MULT_ASSOC] THEN
GEN_REWRITE_TAC LAND_CONV [ARITH_RULE `n = 1 * n`] THEN
REWRITE_TAC[LE_MULT_RCANCEL] THEN DISJ1_TAC THEN
UNDISCH_TAC `~(a = 0)` THEN ARITH_TAC; ALL_TAC] THEN
REWRITE_TAC[REAL_ARITH
`(x1 - x2) + (y1 - y2) * a = (x1 + y1 * a) - (x2 + y2 * a)`] THEN
REWRITE_TAC[GSYM REAL_OF_NUM_MUL] THEN
REWRITE_TAC[GSYM REAL_MUL_ASSOC; GSYM REAL_ADD_LDISTRIB] THEN
ASM_SIMP_TAC[ARITH_RULE
`~(n = 0) /\ ~(n = 1) ==> n - 2 < n /\ n - 1 < n`] THEN
ASM_SIMP_TAC[ARITH_RULE
`~(n = 0) /\ ~(n = 1) ==> (n - 1 = 1 + (n - 2))`] THEN
REWRITE_TAC[REAL_POW_ADD; REAL_MUL_ASSOC; REAL_POW_1] THEN
REWRITE_TAC[REAL_ARITH `a * b - b = (a - &1) * b`] THEN
SUBGOAL_THEN `n = 2 + (n - 2)`
(fun th -> GEN_REWRITE_TAC (RAND_CONV o RAND_CONV) [th])
THENL
[MAP_EVERY UNDISCH_TAC [`~(n = 0)`; `~(n = 1)`] THEN ARITH_TAC;
ALL_TAC] THEN
REWRITE_TAC[REAL_POW_ADD] THEN AP_THM_TAC THEN AP_TERM_TAC THEN
REWRITE_TAC[REAL_POW_2; REAL_ADD_LDISTRIB; REAL_ADD_RDISTRIB] THEN
REWRITE_TAC[GSYM REAL_POW_2] THEN
ASM_SIMP_TAC[GSYM REAL_POW_2; SQRT_POW_2; REAL_SUB_LE;
REAL_POW_LE_1; REAL_OF_NUM_LE;
ARITH_RULE `1 <= a <=> ~(a = 0)`] THEN
REWRITE_TAC[REAL_POW_2] THEN REAL_ARITH_TAC);;
let XY_POWER_NEG = prove
(`!a n. ~(a = 0) ==> (&(X a n) - &(Y a n) * sqrt(&a pow 2 - &1) =
(&a - sqrt(&a pow 2 - &1)) pow n)`,
GEN_TAC THEN REWRITE_TAC[RIGHT_FORALL_IMP_THM] THEN DISCH_TAC THEN
MATCH_MP_TAC num_WF THEN GEN_TAC THEN DISCH_TAC THEN
ONCE_REWRITE_TAC[X_DEF; Y_DEF] THEN
COND_CASES_TAC THEN ASM_REWRITE_TAC[ARITH_EQ] THEN
REWRITE_TAC[REAL_MUL_LZERO; REAL_SUB_RZERO; real_pow] THEN
COND_CASES_TAC THEN ASM_REWRITE_TAC[REAL_POW_1; REAL_MUL_LID] THEN
REWRITE_TAC[REAL_OF_NUM_ADD] THEN
SUBGOAL_THEN
`(&(2 * a * X a (n - 1) - X a (n - 2)) =
&(2 * a * X a (n - 1)) - &(X a (n - 2))) /\
(&(2 * a * Y a (n - 1) - Y a (n - 2)) =
&(2 * a * Y a (n - 1)) - &(Y a (n - 2)))`
(CONJUNCTS_THEN SUBST1_TAC)
THENL
[CONJ_TAC THEN MATCH_MP_TAC(GSYM REAL_OF_NUM_SUB) THEN
MATCH_MP_TAC(ARITH_RULE
`x <= y /\ y <= 2 * a * y ==> x <= 2 * a * y`) THEN
ASM_SIMP_TAC[ARITH_RULE
`~(n = 0) /\ ~(n = 1) ==> (n - 1 = (n - 2) + 1)`] THEN
ASM_SIMP_TAC[X_INCREASES; Y_INCREASES] THEN
REWRITE_TAC[MULT_ASSOC] THEN
GEN_REWRITE_TAC LAND_CONV [ARITH_RULE `n = 1 * n`] THEN
REWRITE_TAC[LE_MULT_RCANCEL] THEN DISJ1_TAC THEN
UNDISCH_TAC `~(a = 0)` THEN ARITH_TAC; ALL_TAC] THEN
REWRITE_TAC[REAL_ARITH
`(x1 - x2) - (y1 - y2) * a = (x1 - y1 * a) - (x2 - y2 * a)`] THEN
REWRITE_TAC[GSYM REAL_OF_NUM_MUL] THEN
REWRITE_TAC[GSYM REAL_MUL_ASSOC; GSYM REAL_SUB_LDISTRIB] THEN
ASM_SIMP_TAC[ARITH_RULE
`~(n = 0) /\ ~(n = 1) ==> n - 2 < n /\ n - 1 < n`] THEN
ASM_SIMP_TAC[ARITH_RULE
`~(n = 0) /\ ~(n = 1) ==> (n - 1 = 1 + (n - 2))`] THEN
REWRITE_TAC[REAL_POW_ADD; REAL_MUL_ASSOC; REAL_POW_1] THEN
REWRITE_TAC[REAL_ARITH `a * b - b = (a - &1) * b`] THEN
SUBGOAL_THEN `n = 2 + (n - 2)`
(fun th -> GEN_REWRITE_TAC (RAND_CONV o RAND_CONV) [th])
THENL
[MAP_EVERY UNDISCH_TAC [`~(n = 0)`; `~(n = 1)`] THEN ARITH_TAC;
ALL_TAC] THEN
REWRITE_TAC[REAL_POW_ADD] THEN AP_THM_TAC THEN AP_TERM_TAC THEN
REWRITE_TAC[REAL_POW_2; REAL_SUB_LDISTRIB; REAL_SUB_RDISTRIB] THEN
REWRITE_TAC[GSYM REAL_POW_2] THEN
ASM_SIMP_TAC[GSYM REAL_POW_2; SQRT_POW_2; REAL_SUB_LE;
REAL_POW_LE_1; REAL_OF_NUM_LE;
ARITH_RULE `1 <= a <=> ~(a = 0)`] THEN
REWRITE_TAC[REAL_POW_2] THEN REAL_ARITH_TAC);;
(* ------------------------------------------------------------------------- *)
(* Hence all members of recurrence relations are Pell solutions. *)
(* ------------------------------------------------------------------------- *)
let XY_ARE_SOLUTIONS = prove
(`!a n. ~(a = 0)
==> ((X a n) EXP 2 = (a EXP 2 - 1) * (Y a n) EXP 2 + 1)`,
REPEAT STRIP_TAC THEN
FIRST_ASSUM(MP_TAC o SPEC `n:num` o MATCH_MP XY_POWER_NEG) THEN
FIRST_ASSUM(MP_TAC o SPEC `n:num` o MATCH_MP XY_POWER_POS) THEN
REWRITE_TAC[IMP_IMP] THEN
DISCH_THEN(fun th ->
MP_TAC(MK_COMB(AP_TERM `( * )` (CONJUNCT1 th),CONJUNCT2 th))) THEN
REWRITE_TAC[GSYM REAL_POW_MUL] THEN
REWRITE_TAC[REAL_ARITH `(x + y) * (x - y) = x * x - y * y`] THEN
ONCE_REWRITE_TAC[AC REAL_MUL_AC
`(a * b) * (c * d) = (a * c) * (b * d)`] THEN
ASM_SIMP_TAC[GSYM REAL_POW_2; SQRT_POW_2; REAL_SUB_LE;
REAL_POW_LE_1; REAL_OF_NUM_LE;
ARITH_RULE `1 <= a <=> ~(a = 0)`] THEN
REWRITE_TAC[REAL_ARITH `a - (a - &1) = &1`; REAL_POW_ONE] THEN
REWRITE_TAC[REAL_EQ_SUB_RADD] THEN
SUBGOAL_THEN `&a pow 2 - &1 = &(a EXP 2 - 1)` SUBST1_TAC THENL
[REWRITE_TAC[REAL_OF_NUM_POW] THEN MATCH_MP_TAC REAL_OF_NUM_SUB THEN
REWRITE_TAC[GSYM REAL_OF_NUM_LE; GSYM REAL_OF_NUM_POW] THEN
ASM_SIMP_TAC[REAL_POW_LE_1; REAL_OF_NUM_LE;
ARITH_RULE `1 <= a <=> ~(a = 0)`];
REWRITE_TAC[REAL_OF_NUM_ADD; REAL_OF_NUM_MUL; REAL_OF_NUM_EQ;
REAL_OF_NUM_POW] THEN
REWRITE_TAC[MULT_AC; ADD_AC]]);;
(* ------------------------------------------------------------------------- *)
(* And they are all solutions. *)
(* ------------------------------------------------------------------------- *)
let X_DEGENERATE = prove
(`!n. X 1 n = 1`,
MATCH_MP_TAC PELL_INDUCTION THEN SIMP_TAC[X_CLAUSES; ARITH]);;
let Y_DEGENERATE = prove
(`!n. Y 1 n = n`,
MATCH_MP_TAC PELL_INDUCTION THEN SIMP_TAC[Y_CLAUSES] THEN
REPEAT STRIP_TAC THEN ARITH_TAC);;
let REAL_ARCH_POW = prove
(`!x y. &1 < x /\ &1 < y
==> ?n. x pow n <= y /\ y < x pow (SUC n)`,
REPEAT STRIP_TAC THEN
MP_TAC(SPEC `ln(x)` REAL_ARCH_LEAST) THEN ASM_SIMP_TAC[LN_POS_LT] THEN
DISCH_THEN(MP_TAC o SPEC `ln(y)`) THEN
ASM_SIMP_TAC[LN_POS_LT; REAL_LT_IMP_LE] THEN
ASM_SIMP_TAC[GSYM LN_POW; REAL_ARITH `&1 < x ==> &0 < x`;
REAL_POW_LT; LN_MONO_LT; LN_MONO_LE]);;
let SOLUTIONS_INDUCTION = prove
(`!a x y.
~(a = 0) /\ ~(a = 1) /\ ~(y = 0) /\
(x EXP 2 = (a EXP 2 - 1) * y EXP 2 + 1)
==> ?x' y'. x' < x /\ y' < y /\
(x' EXP 2 = (a EXP 2 - 1) * y' EXP 2 + 1) /\
(&x + &y * sqrt(&a pow 2 - &1) =
(&x' + &y' * sqrt(&a pow 2 - &1)) *
(&a + sqrt(&a pow 2 - &1)))`,
REPEAT STRIP_TAC THEN
EXISTS_TAC `a * x - (a EXP 2 - 1) * y` THEN
EXISTS_TAC `a * y - x:num` THEN
SUBGOAL_THEN `x <= a * y:num` ASSUME_TAC THENL
[ONCE_REWRITE_TAC[GSYM(SPECL [`x:num`; `y:num`; `1`] EXP_MONO_LE_SUC)] THEN
ASM_REWRITE_TAC[ARITH_SUC] THEN
REWRITE_TAC[GSYM ADD1; LE_SUC_LT] THEN
REWRITE_TAC[MULT_EXP; LT_MULT_RCANCEL] THEN
REWRITE_TAC[ARITH_RULE `a - 1 < a <=> ~(a = 0)`] THEN
ASM_REWRITE_TAC[EXP_EQ_0]; ALL_TAC] THEN
SUBGOAL_THEN `(a EXP 2 - 1) * y <= a * x:num` ASSUME_TAC THENL
[SUBGOAL_THEN `(a EXP 2 - 1) * y EXP 2 < a * x * y` MP_TAC THENL
[ALL_TAC;
ASM_SIMP_TAC[MULT_ASSOC; EXP_2; LT_MULT_RCANCEL; LT_IMP_LE]] THEN
REWRITE_TAC[GSYM LE_SUC_LT; ADD1] THEN
FIRST_ASSUM(fun th -> GEN_REWRITE_TAC LAND_CONV [SYM th]) THEN
GEN_REWRITE_TAC RAND_CONV [MULT_SYM] THEN
REWRITE_TAC[EXP_2; GSYM MULT_ASSOC; LE_MULT_LCANCEL] THEN
DISJ2_TAC THEN ONCE_REWRITE_TAC[MULT_SYM] THEN ASM_REWRITE_TAC[];
ALL_TAC] THEN
MATCH_MP_TAC(TAUT `d /\ (d ==> a /\ b /\ c)
==> a /\ b /\ c /\ d`) THEN
CONJ_TAC THENL
[MATCH_MP_TAC REAL_EQ_RCANCEL_IMP THEN
EXISTS_TAC `&a - sqrt(&a pow 2 - &1)` THEN CONJ_TAC THENL
[REWRITE_TAC[REAL_SUB_0] THEN
DISCH_THEN(MP_TAC o C AP_THM `2` o AP_TERM `(pow)`) THEN
ASM_SIMP_TAC[SQRT_POW_2; REAL_SUB_LE; REAL_POW_LE_1; REAL_OF_NUM_LE;
ARITH_RULE `~(a = 0) ==> 1 <= a`] THEN
REAL_ARITH_TAC; ALL_TAC] THEN
REWRITE_TAC[GSYM REAL_MUL_ASSOC] THEN
REWRITE_TAC[REAL_ARITH `(a + b) * (a - b) = a * a - b * b`] THEN
ASM_SIMP_TAC[GSYM REAL_POW_2; SQRT_POW_2; REAL_SUB_LE; REAL_POW_LE_1;
REAL_OF_NUM_LE; ARITH_RULE `~(a = 0) ==> 1 <= a`] THEN
REWRITE_TAC[REAL_ARITH `a - (a - b) = b`; REAL_MUL_RID] THEN
ASM_SIMP_TAC[GSYM REAL_OF_NUM_SUB] THEN
REWRITE_TAC[REAL_ARITH
`(x + y * s) * (a - s) = (a * x - (s * s) * y) + (a * y - x) * s`] THEN
ASM_SIMP_TAC[GSYM REAL_POW_2; SQRT_POW_2; REAL_SUB_LE; REAL_POW_LE_1;
REAL_OF_NUM_LE; ARITH_RULE `~(a = 0) ==> 1 <= a`] THEN
REWRITE_TAC[GSYM REAL_OF_NUM_MUL] THEN
AP_THM_TAC THEN AP_TERM_TAC THEN AP_TERM_TAC THEN
AP_THM_TAC THEN AP_TERM_TAC THEN
REWRITE_TAC[REAL_OF_NUM_POW] THEN MATCH_MP_TAC REAL_OF_NUM_SUB THEN
REWRITE_TAC[GSYM REAL_OF_NUM_LE; GSYM REAL_OF_NUM_POW] THEN
ASM_SIMP_TAC[REAL_POW_LE_1; REAL_OF_NUM_LE;
ARITH_RULE `~(a = 0) ==> 1 <= a`]; ALL_TAC] THEN
DISCH_THEN(fun th -> ASSUME_TAC th THEN MP_TAC th) THEN
SUBGOAL_THEN
`(&x - &y * sqrt(&a pow 2 - &1)) =
(&(a * x - (a EXP 2 - 1) * y) - &(a * y - x) * sqrt (&a pow 2 - &1)) *
(&a - sqrt(&a pow 2 - &1))`
MP_TAC THENL
[MATCH_MP_TAC REAL_EQ_RCANCEL_IMP THEN
EXISTS_TAC `&a + sqrt(&a pow 2 - &1)` THEN CONJ_TAC THENL
[MATCH_MP_TAC(REAL_ARITH `~(a = --b) ==> ~(a + b = &0)`) THEN
DISCH_THEN(MP_TAC o C AP_THM `2` o AP_TERM `(pow)`) THEN
REWRITE_TAC[REAL_POW_NEG; ARITH] THEN
ASM_SIMP_TAC[SQRT_POW_2; REAL_SUB_LE; REAL_POW_LE_1; REAL_OF_NUM_LE;
ARITH_RULE `~(a = 0) ==> 1 <= a`] THEN
REAL_ARITH_TAC; ALL_TAC] THEN
REWRITE_TAC[GSYM REAL_MUL_ASSOC] THEN
REWRITE_TAC[REAL_ARITH `(a - b) * (a + b) = a * a - b * b`] THEN
ASM_SIMP_TAC[GSYM REAL_POW_2; SQRT_POW_2; REAL_SUB_LE; REAL_POW_LE_1;
REAL_OF_NUM_LE; ARITH_RULE `~(a = 0) ==> 1 <= a`] THEN
REWRITE_TAC[REAL_ARITH `a - (a - b) = b`; REAL_MUL_RID] THEN
ASM_SIMP_TAC[GSYM REAL_OF_NUM_SUB] THEN
REWRITE_TAC[REAL_ARITH
`(x - y * s) * (a + s) = (a * x - (s * s) * y) - (a * y - x) * s`] THEN
ASM_SIMP_TAC[GSYM REAL_POW_2; SQRT_POW_2; REAL_SUB_LE; REAL_POW_LE_1;
REAL_OF_NUM_LE; ARITH_RULE `~(a = 0) ==> 1 <= a`] THEN
REWRITE_TAC[GSYM REAL_OF_NUM_MUL] THEN
AP_THM_TAC THEN AP_TERM_TAC THEN AP_TERM_TAC THEN
AP_THM_TAC THEN AP_TERM_TAC THEN
REWRITE_TAC[REAL_OF_NUM_POW] THEN MATCH_MP_TAC REAL_OF_NUM_SUB THEN
REWRITE_TAC[GSYM REAL_OF_NUM_LE; GSYM REAL_OF_NUM_POW] THEN
ASM_SIMP_TAC[REAL_POW_LE_1; REAL_OF_NUM_LE;
ARITH_RULE `~(a = 0) ==> 1 <= a`]; ALL_TAC] THEN
DISCH_THEN(fun th1 -> DISCH_THEN (fun th2 ->
MP_TAC(MK_COMB(AP_TERM `( * )` th1,th2)))) THEN
ONCE_REWRITE_TAC[AC REAL_MUL_AC
`(a * b) * (c * d) = (c * a) * (d * b)`] THEN
REWRITE_TAC[REAL_ARITH `(a + b) * (a - b) = a * a - b * b`] THEN
REWRITE_TAC[REAL_ARITH `(a - b) * (a + b) = a * a - b * b`] THEN
ONCE_REWRITE_TAC[AC REAL_MUL_AC
`(a * b) * (c * b) = (c * a) * (b * b)`] THEN
ASM_SIMP_TAC[GSYM REAL_POW_2; SQRT_POW_2; REAL_SUB_LE; REAL_POW_LE_1;
REAL_OF_NUM_LE; ARITH_RULE `~(a = 0) ==> 1 <= a`] THEN
REWRITE_TAC[REAL_ARITH `a - (a - b) = b`; REAL_MUL_RID] THEN
ASM_REWRITE_TAC[REAL_OF_NUM_POW] THEN
REWRITE_TAC[GSYM REAL_OF_NUM_POW; GSYM REAL_OF_NUM_ADD;
GSYM REAL_OF_NUM_MUL] THEN
SUBGOAL_THEN `&a pow 2 - &1 = &(a EXP 2 - 1)` (SUBST1_TAC o SYM) THENL
[REWRITE_TAC[REAL_OF_NUM_POW] THEN MATCH_MP_TAC REAL_OF_NUM_SUB THEN
REWRITE_TAC[GSYM REAL_OF_NUM_LE; GSYM REAL_OF_NUM_POW] THEN
ASM_SIMP_TAC[REAL_POW_LE_1; REAL_OF_NUM_LE;
ARITH_RULE `~(a = 0) ==> 1 <= a`]; ALL_TAC] THEN
DISCH_THEN(MP_TAC o MATCH_MP (REAL_ARITH
`((a * b + &1) - b * a = x - y) ==> (x = y + &1)`)) THEN
SUBGOAL_THEN `&a pow 2 - &1 = &(a EXP 2 - 1)` SUBST1_TAC THENL
[REWRITE_TAC[REAL_OF_NUM_POW] THEN MATCH_MP_TAC REAL_OF_NUM_SUB THEN
REWRITE_TAC[GSYM REAL_OF_NUM_LE; GSYM REAL_OF_NUM_POW] THEN
ASM_SIMP_TAC[REAL_POW_LE_1; REAL_OF_NUM_LE;
ARITH_RULE `~(a = 0) ==> 1 <= a`]; ALL_TAC] THEN
ASM_SIMP_TAC[REAL_OF_NUM_SUB; REAL_OF_NUM_ADD; REAL_OF_NUM_EQ;
REAL_OF_NUM_POW; REAL_OF_NUM_MUL] THEN
ABBREV_TAC `u = a * x - (a EXP 2 - 1) * y` THEN
ABBREV_TAC `v = a * y - x:num` THEN
DISCH_THEN(ASSUME_TAC o ONCE_REWRITE_RULE[MULT_SYM]) THEN
REWRITE_TAC[MULT_AC] THEN
MATCH_MP_TAC(TAUT `(a <=> b) /\ (~a /\ ~b ==> F) ==> a /\ b`) THEN
CONJ_TAC THENL
[GEN_REWRITE_TAC LAND_CONV [GSYM(SPEC `1` EXP_MONO_LT_SUC)] THEN
ASM_REWRITE_TAC[ARITH_SUC] THEN
REWRITE_TAC[LT_ADD_RCANCEL; LT_MULT_LCANCEL] THEN
REWRITE_TAC[num_CONV `2`; EXP_MONO_LT_SUC] THEN
MATCH_MP_TAC(TAUT `a ==> (a /\ b <=> b)`) THEN
REWRITE_TAC[SUB_EQ_0; ARITH_SUC; NOT_LE] THEN
SUBST1_TAC(SYM(SPEC `a:num` (CONJUNCT1 EXP))) THEN
REWRITE_TAC[LT_EXP] THEN REWRITE_TAC[ARITH] THEN
MATCH_MP_TAC(ARITH_RULE `~(a = 0) /\ ~(a = 1) ==> 2 <= a`) THEN
ASM_REWRITE_TAC[]; ALL_TAC] THEN
REWRITE_TAC[NOT_LT] THEN STRIP_TAC THEN
UNDISCH_TAC
`&x + &y * sqrt (&a pow 2 - &1) =
(&u + &v * sqrt (&a pow 2 - &1)) * (&a + sqrt (&a pow 2 - &1))` THEN
REWRITE_TAC[] THEN
MATCH_MP_TAC(REAL_ARITH `a < b ==> ~(a = b)`) THEN
MATCH_MP_TAC REAL_LET_TRANS THEN
EXISTS_TAC `(&u + &v * sqrt (&a pow 2 - &1)) * &1` THEN CONJ_TAC THENL
[REWRITE_TAC[REAL_MUL_RID] THEN MATCH_MP_TAC REAL_LE_ADD2 THEN
ASM_REWRITE_TAC[REAL_OF_NUM_LE] THEN
MATCH_MP_TAC REAL_LE_RMUL THEN
ASM_SIMP_TAC[REAL_OF_NUM_LE; SQRT_POS_LE; REAL_POW_LE_1;
REAL_SUB_LE; ARITH_RULE `~(a = 0) ==> 1 <= a`];
ALL_TAC] THEN
MATCH_MP_TAC REAL_LT_LMUL THEN CONJ_TAC THENL
[MATCH_MP_TAC REAL_LTE_ADD THEN CONJ_TAC THENL
[REWRITE_TAC[REAL_OF_NUM_LT; LT_NZ] THEN DISCH_THEN SUBST_ALL_TAC THEN
UNDISCH_TAC `0 EXP 2 = (a EXP 2 - 1) * v EXP 2 + 1` THEN
DISCH_THEN(MP_TAC o SYM) THEN CONV_TAC NUM_REDUCE_CONV THEN
REWRITE_TAC[ADD_EQ_0; ARITH_EQ]; ALL_TAC] THEN
MATCH_MP_TAC REAL_LE_MUL THEN REWRITE_TAC[REAL_POS] THEN
ASM_SIMP_TAC[REAL_OF_NUM_LE; SQRT_POS_LE; REAL_POW_LE_1;
REAL_SUB_LE; ARITH_RULE `~(a = 0) ==> 1 <= a`];
ALL_TAC] THEN
MATCH_MP_TAC(REAL_ARITH `&1 < x /\ &0 <= y ==> &1 < x + y`) THEN
ASM_SIMP_TAC[REAL_OF_NUM_LE; SQRT_POS_LE; REAL_POW_LE_1;
REAL_SUB_LE; ARITH_RULE `~(a = 0) ==> 1 <= a`] THEN
REWRITE_TAC[REAL_OF_NUM_LT] THEN
MATCH_MP_TAC(ARITH_RULE `~(a = 0) /\ ~(a = 1) ==> 1 < a`) THEN
ASM_REWRITE_TAC[]);;
let SOLUTIONS_ARE_XY = prove
(`!a x y.
~(a = 0) /\
(x EXP 2 = (a EXP 2 - 1) * y EXP 2 + 1)
==> ?n. (x = X a n) /\ (y = Y a n)`,
REPEAT GEN_TAC THEN ASM_CASES_TAC `a = 1` THENL
[ASM_REWRITE_TAC[ARITH; MULT_CLAUSES; ADD_CLAUSES; EXP_2] THEN
SIMP_TAC[MULT_EQ_1; X_DEGENERATE; Y_DEGENERATE; GSYM EXISTS_REFL];
ALL_TAC] THEN
STRIP_TAC THEN
SUBGOAL_THEN `?n. &x + &y * sqrt(&a pow 2 - &1) =
(&a + sqrt(&a pow 2 - &1)) pow n`
MP_TAC THENL
[UNDISCH_TAC `x EXP 2 = (a EXP 2 - 1) * y EXP 2 + 1` THEN
SPEC_TAC(`x:num`,`x:num`) THEN SPEC_TAC(`y:num`,`y:num`) THEN
MATCH_MP_TAC num_WF THEN X_GEN_TAC `y0:num` THEN DISCH_TAC THEN
X_GEN_TAC `x0:num` THEN
ASM_CASES_TAC `y0 = 0` THENL
[ASM_REWRITE_TAC[EXP_2; MULT_CLAUSES; ADD_CLAUSES; MULT_EQ_1] THEN
DISCH_THEN SUBST1_TAC THEN EXISTS_TAC `0` THEN
REWRITE_TAC[REAL_MUL_LZERO; REAL_ADD_RID; real_pow]; ALL_TAC] THEN
DISCH_TAC THEN
MP_TAC(SPECL [`a:num`; `x0:num`; `y0:num`] SOLUTIONS_INDUCTION) THEN
ASM_REWRITE_TAC[] THEN
DISCH_THEN(X_CHOOSE_THEN `x1:num` (X_CHOOSE_THEN `y1:num`
STRIP_ASSUME_TAC)) THEN
FIRST_X_ASSUM(MP_TAC o SPEC `y1:num`) THEN ASM_REWRITE_TAC[] THEN
DISCH_THEN(MP_TAC o SPEC `x1:num`) THEN ASM_REWRITE_TAC[] THEN
DISCH_THEN(X_CHOOSE_THEN `n:num` SUBST1_TAC) THEN
EXISTS_TAC `SUC n` THEN REWRITE_TAC[real_pow; REAL_MUL_AC]; ALL_TAC] THEN
ASM_SIMP_TAC[GSYM XY_POWER_POS] THEN MATCH_MP_TAC MONO_EXISTS THEN
X_GEN_TAC `n:num` THEN
ASM_SIMP_TAC[SQRT_LINEAR_EQ;
ARITH_RULE `~(a = 0) /\ ~(a = 1) ==> 2 <= a`]);;
(* ------------------------------------------------------------------------- *)
(* Addition formulas. *)
(* ------------------------------------------------------------------------- *)
let ADDITION_FORMULA_POS = prove
(`!a m n.
~(a = 0)
==> ((X a (m + n) = X a m * X a n + (a EXP 2 - 1) * Y a m * Y a n) /\
(Y a (m + n) = X a m * Y a n + X a n * Y a m))`,
REPEAT GEN_TAC THEN DISCH_TAC THEN ASM_CASES_TAC `a = 1` THENL
[ASM_REWRITE_TAC[X_DEGENERATE; Y_DEGENERATE] THEN
REWRITE_TAC[ARITH; MULT_CLAUSES] THEN REWRITE_TAC[ADD_AC]; ALL_TAC] THEN
MP_TAC(SPECL [`a:num`; `m + n:num`] XY_POWER_POS) THEN
MP_TAC(SPECL [`a:num`; `m:num`] XY_POWER_POS) THEN
MP_TAC(SPECL [`a:num`; `n:num`] XY_POWER_POS) THEN
ASM_REWRITE_TAC[] THEN
REWRITE_TAC[REAL_POW_ADD] THEN
DISCH_THEN(SUBST1_TAC o SYM) THEN DISCH_THEN(SUBST1_TAC o SYM) THEN
REWRITE_TAC[REAL_ARITH
`(a + b * s) * (c + d * s) = (a * c + (s * s) * b * d) +
(a * d + b * c) * s`] THEN
ASM_SIMP_TAC[GSYM REAL_POW_2; SQRT_POW_2; REAL_SUB_LE; REAL_POW_LE_1;
REAL_OF_NUM_LE; ARITH_RULE `~(a = 0) ==> 1 <= a`] THEN
SUBGOAL_THEN `&a pow 2 - &1 = &(a EXP 2 - 1)` SUBST1_TAC THENL
[REWRITE_TAC[REAL_OF_NUM_POW] THEN MATCH_MP_TAC REAL_OF_NUM_SUB THEN
REWRITE_TAC[GSYM REAL_OF_NUM_LE; GSYM REAL_OF_NUM_POW] THEN
ASM_SIMP_TAC[REAL_POW_LE_1; REAL_OF_NUM_LE;
ARITH_RULE `~(a = 0) ==> 1 <= a`]; ALL_TAC] THEN
REWRITE_TAC[REAL_OF_NUM_MUL; REAL_OF_NUM_ADD] THEN
SUBGOAL_THEN `&a pow 2 - &1 = &(a EXP 2 - 1)` (SUBST1_TAC o SYM) THENL
[REWRITE_TAC[REAL_OF_NUM_POW] THEN MATCH_MP_TAC REAL_OF_NUM_SUB THEN
REWRITE_TAC[GSYM REAL_OF_NUM_LE; GSYM REAL_OF_NUM_POW] THEN
ASM_SIMP_TAC[REAL_POW_LE_1; REAL_OF_NUM_LE;
ARITH_RULE `~(a = 0) ==> 1 <= a`]; ALL_TAC] THEN
ASM_SIMP_TAC[SQRT_LINEAR_EQ;
ARITH_RULE `~(a = 0) /\ ~(a = 1) ==> 2 <= a`] THEN
REWRITE_TAC[MULT_AC]);;
let ADDITION_FORMULA_NEG = prove
(`!a m n.
~(a = 0) /\ m <= n
==> ((X a (n - m) = X a m * X a n - (a EXP 2 - 1) * Y a m * Y a n) /\
(Y a (n - m) = X a m * Y a n - X a n * Y a m))`,
REPEAT GEN_TAC THEN STRIP_TAC THEN ASM_CASES_TAC `a = 1` THENL
[ASM_REWRITE_TAC[X_DEGENERATE; Y_DEGENERATE] THEN
REWRITE_TAC[ARITH; MULT_CLAUSES]; ALL_TAC] THEN
MP_TAC(SPECL [`a:num`; `n - m:num`] XY_POWER_POS) THEN
ASM_REWRITE_TAC[] THEN
DISCH_THEN(MP_TAC o AP_TERM
`( * ) (((&a - sqrt (&a pow 2 - &1)) *
(&a + sqrt (&a pow 2 - &1))) pow m)`) THEN
GEN_REWRITE_TAC (LAND_CONV o LAND_CONV o ONCE_DEPTH_CONV)
[REAL_ARITH `(x - y) * (x + y) = x * x - y * y`] THEN
ASM_SIMP_TAC[GSYM REAL_POW_2; SQRT_POW_2; REAL_SUB_LE;
REAL_POW_LE_1; REAL_OF_NUM_LE;
ARITH_RULE `~(a = 0) ==> 1 <= a`] THEN
REWRITE_TAC[REAL_ARITH `x - (x - &1) = &1`] THEN
REWRITE_TAC[REAL_POW_MUL; REAL_POW_ONE; REAL_MUL_LID] THEN
REWRITE_TAC[GSYM REAL_MUL_ASSOC] THEN
REWRITE_TAC[GSYM REAL_POW_ADD] THEN
ASM_SIMP_TAC[ARITH_RULE `m <= n ==> (m + (n - m) = n:num)`] THEN
MP_TAC(SPECL [`a:num`; `m:num`] XY_POWER_NEG) THEN
MP_TAC(SPECL [`a:num`; `n:num`] XY_POWER_POS) THEN
ASM_REWRITE_TAC[] THEN
DISCH_THEN(SUBST1_TAC o SYM) THEN DISCH_THEN(SUBST1_TAC o SYM) THEN
REWRITE_TAC[REAL_ARITH
`(a - b * s) * (c + d * s) = (a * c - (s * s) * b * d) +
(a * d - b * c) * s`] THEN
ASM_SIMP_TAC[GSYM REAL_POW_2; SQRT_POW_2; REAL_SUB_LE; REAL_POW_LE_1;
REAL_OF_NUM_LE; ARITH_RULE `~(a = 0) ==> 1 <= a`] THEN
ONCE_REWRITE_TAC[REAL_ARITH
`(a + b * s = (x1 - x2) + (y1 - y2) * s) =
((a + x2) + (b + y2) * s = x1 + y1 * s)`] THEN
SUBGOAL_THEN `&a pow 2 - &1 = &(a EXP 2 - 1)` SUBST1_TAC THENL
[REWRITE_TAC[REAL_OF_NUM_POW] THEN MATCH_MP_TAC REAL_OF_NUM_SUB THEN
REWRITE_TAC[GSYM REAL_OF_NUM_LE; GSYM REAL_OF_NUM_POW] THEN
ASM_SIMP_TAC[REAL_POW_LE_1; REAL_OF_NUM_LE;
ARITH_RULE `~(a = 0) ==> 1 <= a`]; ALL_TAC] THEN
REWRITE_TAC[REAL_OF_NUM_MUL; REAL_OF_NUM_ADD] THEN
SUBGOAL_THEN `&a pow 2 - &1 = &(a EXP 2 - 1)` (SUBST1_TAC o SYM) THENL
[REWRITE_TAC[REAL_OF_NUM_POW] THEN MATCH_MP_TAC REAL_OF_NUM_SUB THEN
REWRITE_TAC[GSYM REAL_OF_NUM_LE; GSYM REAL_OF_NUM_POW] THEN
ASM_SIMP_TAC[REAL_POW_LE_1; REAL_OF_NUM_LE;
ARITH_RULE `~(a = 0) ==> 1 <= a`]; ALL_TAC] THEN
ASM_SIMP_TAC[SQRT_LINEAR_EQ;
ARITH_RULE `~(a = 0) /\ ~(a = 1) ==> 2 <= a`] THEN
DISCH_THEN(CONJUNCTS_THEN(SUBST1_TAC o SYM)) THEN
REWRITE_TAC[MULT_AC] THEN REWRITE_TAC[ADD_SUB]);;
(* ------------------------------------------------------------------------- *)
(* Some stronger monotonicity theorems for Y. *)
(* ------------------------------------------------------------------------- *)
let Y_INCREASES_SUC = prove
(`!a n. ~(a = 0) ==> Y a n < Y a (SUC n)`,
REPEAT STRIP_TAC THEN ASM_SIMP_TAC[ADD1; ADDITION_FORMULA_POS] THEN
REWRITE_TAC[X_CLAUSES; Y_CLAUSES] THEN
MATCH_MP_TAC(ARITH_RULE `1 * y <= ay /\ ~(x = 0) ==> y < x * 1 + ay`) THEN
ASM_SIMP_TAC[LE_MULT_RCANCEL; ARITH_RULE `1 <= a <=> ~(a = 0)`] THEN
MATCH_MP_TAC(ARITH_RULE
`!n. (n = 1) /\ n <= m ==> ~(m = 0)`) THEN
EXISTS_TAC `X a 0` THEN CONJ_TAC THENL
[REWRITE_TAC[X_CLAUSES]; ALL_TAC] THEN
SPEC_TAC(`n:num`,`n:num`) THEN
INDUCT_TAC THEN REWRITE_TAC[ADD_CLAUSES; LE_REFL] THEN
REWRITE_TAC[ADD1] THEN ASM_MESON_TAC[LE_TRANS; X_INCREASES]);;
let Y_INCREASES_LT = prove
(`!a m n. ~(a = 0) /\ m < n ==> Y a m < Y a n`,
REPEAT GEN_TAC THEN DISCH_THEN(CONJUNCTS_THEN2 ASSUME_TAC MP_TAC) THEN
GEN_REWRITE_TAC LAND_CONV [LT_EXISTS] THEN
SIMP_TAC[LEFT_IMP_EXISTS_THM] THEN X_GEN_TAC `d:num` THEN DISCH_TAC THEN
MATCH_MP_TAC LTE_TRANS THEN EXISTS_TAC `Y a (SUC m)` THEN
ASM_SIMP_TAC[Y_INCREASES_SUC] THEN
REWRITE_TAC[ARITH_RULE `m + SUC d = SUC m + d`] THEN
SPEC_TAC(`d:num`,`d:num`) THEN
INDUCT_TAC THEN REWRITE_TAC[ADD_CLAUSES; LE_REFL] THEN
RULE_ASSUM_TAC(REWRITE_RULE[ADD_CLAUSES]) THEN
ASM_MESON_TAC[ADD1; LE_TRANS; Y_INCREASES]);;
let Y_INCREASES_LE = prove
(`!a m n. ~(a = 0) /\ m <= n ==> Y a m <= Y a n`,
REWRITE_TAC[LE_LT] THEN MESON_TAC[LE_REFL; Y_INCREASES_LT]);;
let Y_INJ = prove
(`!a m n. ~(a = 0) ==> ((Y a m = Y a n) <=> (m = n))`,
REPEAT STRIP_TAC THEN EQ_TAC THEN SIMP_TAC[] THEN
MP_TAC(SPEC `a:num` Y_INCREASES_LT) THEN ASM_REWRITE_TAC[] THEN
MESON_TAC[LT_CASES; LT_REFL]);;
(* ------------------------------------------------------------------------- *)
(* One for X (to get the same as Y, need a /= 1). *)
(* ------------------------------------------------------------------------- *)
let X_INCREASES_LE = prove
(`!a m n. ~(a = 0) /\ m <= n ==> X a m <= X a n`,
REPEAT GEN_TAC THEN DISCH_THEN(CONJUNCTS_THEN2 ASSUME_TAC MP_TAC) THEN
GEN_REWRITE_TAC LAND_CONV [LE_EXISTS] THEN
SIMP_TAC[LEFT_IMP_EXISTS_THM] THEN X_GEN_TAC `d:num` THEN
DISCH_THEN(K ALL_TAC) THEN SPEC_TAC(`d:num`,`d:num`) THEN
INDUCT_TAC THEN REWRITE_TAC[ADD_CLAUSES; LE_REFL] THEN
REWRITE_TAC[ADD1] THEN ASM_MESON_TAC[LE_TRANS; X_INCREASES]);;
let X_INCREASES_LT = prove
(`!a m n. ~(a = 0) /\ ~(a = 1) /\ m < n ==> X a m < X a n`,
REPEAT GEN_TAC THEN
GEN_REWRITE_TAC (LAND_CONV o ONCE_DEPTH_CONV) [GSYM LE_SUC_LT] THEN
STRIP_TAC THEN
MATCH_MP_TAC LTE_TRANS THEN EXISTS_TAC `X a (SUC m)` THEN
ASM_SIMP_TAC[X_INCREASES_LE] THEN
SPEC_TAC(`m:num`,`p:num`) THEN
INDUCT_TAC THEN ASM_SIMP_TAC[ARITH; X_CLAUSES; ARITH_RULE
`~(a = 0) /\ ~(a = 1) ==> 1 < a`] THEN
REWRITE_TAC[ARITH_RULE `SUC(SUC p) = p + 2`] THEN
REWRITE_TAC[X_CLAUSES; ADD1] THEN
MATCH_MP_TAC(ARITH_RULE `a <= b /\ c < b ==> a < 2 * b - c`) THEN
CONJ_TAC THENL
[ALL_TAC;
MATCH_MP_TAC LTE_TRANS THEN EXISTS_TAC `X a (SUC p)` THEN
ASM_REWRITE_TAC[]] THEN
GEN_REWRITE_TAC LAND_CONV [ARITH_RULE `a = 1 * a`] THEN
REWRITE_TAC[LE_MULT_RCANCEL; ADD1] THEN DISJ1_TAC THEN
MAP_EVERY UNDISCH_TAC [`~(a = 0)`; `~(a = 1)`] THEN ARITH_TAC);;
let X_INCREASES_SUC = prove
(`!a n. ~(a = 0) /\ ~(a = 1) ==> X a n < X a (SUC n)`,
SIMP_TAC[X_INCREASES_LT; LT]);;
let X_INJ = prove
(`!a m n. ~(a = 0) /\ ~(a = 1) ==> ((X a m = X a n) <=> (m = n))`,
REPEAT STRIP_TAC THEN EQ_TAC THEN SIMP_TAC[] THEN
MP_TAC(SPEC `a:num` X_INCREASES_LT) THEN ASM_REWRITE_TAC[] THEN
MESON_TAC[LT_CASES; LT_REFL]);;
(* ------------------------------------------------------------------------- *)
(* Coprimality of "X a n" and "Y a n". *)
(* ------------------------------------------------------------------------- *)
let XY_COPRIME = prove
(`!a n. ~(a = 0) ==> coprime(X a n,Y a n)`,
REPEAT GEN_TAC THEN
DISCH_THEN(MP_TAC o SPEC `n:num` o MATCH_MP XY_ARE_SOLUTIONS) THEN
ONCE_REWRITE_TAC[TAUT `a ==> b <=> ~b ==> ~a`] THEN
REWRITE_TAC[coprime; NOT_FORALL_THM; LEFT_IMP_EXISTS_THM] THEN
X_GEN_TAC `d:num` THEN REWRITE_TAC[NOT_IMP] THEN
REWRITE_TAC[divides] THEN STRIP_TAC THEN ASM_REWRITE_TAC[EXP_2] THEN
REWRITE_TAC[GSYM MULT_ASSOC] THEN
GEN_REWRITE_TAC (funpow 2 RAND_CONV o LAND_CONV)
[AC MULT_AC `a * d * x * d * x = d * d * a * x * x:num`] THEN
DISCH_THEN(MP_TAC o MATCH_MP (ARITH_RULE
`(a = b + 1) ==> (a - b = 1)`)) THEN
ASM_REWRITE_TAC[GSYM LEFT_SUB_DISTRIB; MULT_EQ_1]);;
(* ------------------------------------------------------------------------- *)
(* Divisibility properties. *)
(* ------------------------------------------------------------------------- *)
let Y_DIVIDES_LEMMA = prove
(`!a k n. ~(a = 0) ==> (Y a n) divides (Y a (n * k))`,
REWRITE_TAC[RIGHT_FORALL_IMP_THM] THEN GEN_TAC THEN DISCH_TAC THEN
ONCE_REWRITE_TAC[SWAP_FORALL_THM] THEN GEN_TAC THEN
INDUCT_TAC THEN REWRITE_TAC[MULT_CLAUSES] THEN
REWRITE_TAC[Y_CLAUSES; DIVIDES_0] THEN
ASM_SIMP_TAC[ADDITION_FORMULA_POS] THEN
UNDISCH_TAC `Y a n divides Y a (n * k)` THEN
SIMP_TAC[divides; LEFT_IMP_EXISTS_THM] THEN
X_GEN_TAC `d:num` THEN DISCH_TAC THEN
EXISTS_TAC `X a n * d + X a (n * k)` THEN
REWRITE_TAC[LEFT_ADD_DISTRIB] THEN REWRITE_TAC[MULT_AC; ADD_AC]);;
let Y_DIVIDES = prove
(`!a m n. ~(a = 0) ==> ((Y a m) divides (Y a n) <=> m divides n)`,
REPEAT STRIP_TAC THEN EQ_TAC THENL
[ALL_TAC;
GEN_REWRITE_TAC LAND_CONV [divides] THEN
ASM_SIMP_TAC[LEFT_IMP_EXISTS_THM; Y_DIVIDES_LEMMA]] THEN
ONCE_REWRITE_TAC[TAUT `a ==> b <=> ~b ==> ~a`] THEN
ASM_CASES_TAC `n = 0` THEN ASM_REWRITE_TAC[DIVIDES_0] THEN
ASM_CASES_TAC `m = 0` THENL
[ASM_REWRITE_TAC[Y_CLAUSES; DIVIDES_ZERO] THEN
MATCH_MP_TAC(ARITH_RULE
`!n. (n = 1) /\ n <= m ==> ~(m = 0)`) THEN
EXISTS_TAC `Y a 1` THEN CONJ_TAC THENL
[REWRITE_TAC[Y_CLAUSES]; ALL_TAC] THEN
ASM_SIMP_TAC[Y_INCREASES_LE; ARITH_RULE `1 <= n <=> ~(n = 0)`];
ALL_TAC] THEN
MP_TAC(SPECL [`n:num`; `m:num`] DIVISION) THEN
ASM_REWRITE_TAC[] THEN
ABBREV_TAC `q = n DIV m` THEN ABBREV_TAC `r = n MOD m` THEN
STRIP_TAC THEN ASM_REWRITE_TAC[] THEN
ASM_CASES_TAC `r = 0` THEN
ASM_SIMP_TAC[ADD_CLAUSES; DIVIDES_LMUL; DIVIDES_REFL] THEN
DISCH_TAC THEN
ASM_SIMP_TAC[ADDITION_FORMULA_POS] THEN
SUBGOAL_THEN `~((Y a m) divides (X a (q * m) * Y a r))` MP_TAC THENL
[ALL_TAC;
REWRITE_TAC[TAUT `~a ==> ~b <=> b ==> a`] THEN DISCH_TAC THEN
MATCH_MP_TAC DIVIDES_ADD_REVL THEN
EXISTS_TAC `X a r * Y a (q * m)` THEN
ASM_REWRITE_TAC[] THEN
GEN_REWRITE_TAC (funpow 3 RAND_CONV) [MULT_SYM] THEN
ASM_SIMP_TAC[DIVIDES_LMUL; Y_DIVIDES_LEMMA]] THEN
DISCH_THEN(MP_TAC o MATCH_MP
(REWRITE_RULE[IMP_CONJ] COPRIME_DIVPROD)) THEN
REWRITE_TAC[NOT_IMP] THEN CONJ_TAC THENL
[MP_TAC(SPECL [`a:num`; `q * m:num`] XY_COPRIME) THEN ASM_REWRITE_TAC[] THEN
ONCE_REWRITE_TAC[TAUT `a ==> b <=> ~b ==> ~a`] THEN
REWRITE_TAC[coprime; NOT_FORALL_THM; NOT_IMP] THEN
MATCH_MP_TAC MONO_EXISTS THEN X_GEN_TAC `d:num` THEN
STRIP_TAC THEN ASM_REWRITE_TAC[] THEN ONCE_REWRITE_TAC[MULT_SYM] THEN
ASM_MESON_TAC[DIVIDES_TRANS; Y_DIVIDES_LEMMA]; ALL_TAC] THEN
DISCH_THEN(MP_TAC o MATCH_MP DIVIDES_LE) THEN
ASM_SIMP_TAC[DE_MORGAN_THM; NOT_LE; Y_INCREASES_LT] THEN
ONCE_REWRITE_TAC[GSYM(CONJUNCT1 Y_CLAUSES)] THEN ASM_SIMP_TAC[Y_INJ]);;
(* ------------------------------------------------------------------------- *)
(* This lemma would be trivial from binomial theorem. *)
(* ------------------------------------------------------------------------- *)
let BINOMIAL_TRIVIALITY = prove
(`!x y d n. ?p q.
(&x + &y * sqrt(&d)) pow (n + 2) =
&x pow (n + 2) +
&(n + 2) * &x pow (n + 1) * &y * sqrt(&d) +
&(((n + 1) * (n + 2)) DIV 2) * &x pow n * &y pow 2 * &d +
&p * &y pow 3 + &q * &y pow 3 * sqrt(&d)`,
GEN_TAC THEN GEN_TAC THEN GEN_TAC THEN INDUCT_TAC THENL
[REPEAT(EXISTS_TAC `0`) THEN CONV_TAC NUM_REDUCE_CONV THEN
REWRITE_TAC[REAL_POW_1; real_pow; REAL_MUL_LZERO; REAL_ADD_RID] THEN
REWRITE_TAC[REAL_MUL_LID] THEN REWRITE_TAC[REAL_POW_2] THEN
REWRITE_TAC[REAL_ARITH
`(x + y) * (x + y) = x * x + &2 * x * y + y * y`] THEN
AP_TERM_TAC THEN AP_TERM_TAC THEN
ONCE_REWRITE_TAC[AC REAL_MUL_AC `(a * b) * (a * b) = (a * a) * b * b`] THEN
SIMP_TAC[GSYM REAL_POW_2; SQRT_POW_2; REAL_POS]; ALL_TAC] THEN
GEN_REWRITE_TAC (funpow 2 BINDER_CONV o LAND_CONV o TOP_DEPTH_CONV)
[ADD_CLAUSES; real_pow] THEN
FIRST_ASSUM(X_CHOOSE_THEN `p:num` (X_CHOOSE_THEN `q:num` SUBST1_TAC)) THEN
REWRITE_TAC[REAL_ARITH
`(x + y) * (xn + xn1 + xn2 + p + q) =
(x * xn) + (x * xn1 + y * xn) + (x * xn2 + y * xn1) +
(y * xn2 + p * x + q * y) + (p * y + q * x)`] THEN
ONCE_REWRITE_TAC[REAL_ARITH
`x * n2 * xn1 * y * d + (y * d) * xn2 = (n2 * x * xn1 + xn2) * y * d`] THEN
REWRITE_TAC[GSYM(CONJUNCT2 real_pow)] THEN
REWRITE_TAC[ARITH_RULE `SUC(n + m) = n + SUC m`] THEN
REWRITE_TAC[ARITH_RULE `SUC n + m = n + SUC m`] THEN
CONV_TAC NUM_REDUCE_CONV THEN
REWRITE_TAC[REAL_ARITH `&n * x + x = (&n + &1) * x`] THEN
REWRITE_TAC[REAL_OF_NUM_ADD; ARITH_RULE `(n + 2) + 1 = n + 3`] THEN
REWRITE_TAC[GSYM REAL_ADD_ASSOC; GSYM REAL_MUL_ASSOC; REAL_EQ_LADD] THEN
ONCE_REWRITE_TAC[REAL_ARITH
`x * n12 * xn * y2 * d + y * s * n2 * xn1 * y * s + a =
(n12 * (x * xn) * y2 * d + n2 * xn1 * (y * y) * (s * s)) + a`] THEN
REWRITE_TAC[GSYM REAL_POW_2; GSYM(CONJUNCT2 real_pow)] THEN
SIMP_TAC[SQRT_POW_2; REAL_POS] THEN
REWRITE_TAC[ADD1; REAL_MUL_ASSOC; GSYM REAL_ADD_RDISTRIB] THEN
SUBGOAL_THEN `&(((n + 1) * (n + 2)) DIV 2) + &(n + 2) =
&(((n + 2) * (n + 3)) DIV 2)`
SUBST1_TAC THENL
[REWRITE_TAC[REAL_OF_NUM_ADD; REAL_OF_NUM_EQ] THEN
CONV_TAC SYM_CONV THEN MATCH_MP_TAC DIV_UNIQ THEN
EXISTS_TAC `0` THEN REWRITE_TAC[ARITH; ADD_CLAUSES] THEN
REWRITE_TAC[ARITH_RULE `(n + 2) * (n + 3) = n * n + 5 * n + 6`] THEN
REWRITE_TAC[ARITH_RULE
`(x + 5 * n + 6 = (y + n + 2) * 2) <=> (x + 3 * n + 2 = 2 * y)`] THEN
REWRITE_TAC[ARITH_RULE `n * n + 3 * n + 2 = (n + 1) * (n + 2)`] THEN
SUBGOAL_THEN `EVEN((n + 1) * (n + 2))` MP_TAC THENL
[REWRITE_TAC[EVEN_MULT; EVEN_ADD; ARITH_EVEN] THEN
CONV_TAC(EQT_INTRO o TAUT); ALL_TAC] THEN
SIMP_TAC[EVEN_EXISTS; LEFT_IMP_EXISTS_THM] THEN
SIMP_TAC[DIV_MULT; ARITH_EQ]; ALL_TAC] THEN
REWRITE_TAC[REAL_EQ_LADD] THEN REWRITE_TAC[GSYM REAL_MUL_ASSOC] THEN
ONCE_REWRITE_TAC[REAL_ARITH `q * y3 * s * y * s = q * y * y3 * s * s`] THEN
SIMP_TAC[GSYM REAL_POW_2; SQRT_POW_2; REAL_POS] THEN
ONCE_REWRITE_TAC[REAL_ARITH
`y * s * nn * xn * y2 * d = nn * d * xn * (y * y2) * s`] THEN
REWRITE_TAC[GSYM(CONJUNCT2 real_pow)] THEN
EXISTS_TAC `p * x + q * y * d:num` THEN REWRITE_TAC[ARITH_SUC] THEN
EXISTS_TAC `((n + 1) * (n + 2)) DIV 2 * d * x EXP n +
p * y + q * x` THEN
REWRITE_TAC[GSYM REAL_OF_NUM_MUL; GSYM REAL_OF_NUM_ADD;
GSYM REAL_OF_NUM_POW] THEN
REWRITE_TAC[REAL_ADD_LDISTRIB; REAL_ADD_RDISTRIB] THEN
REWRITE_TAC[REAL_MUL_AC] THEN REWRITE_TAC[REAL_ADD_AC]);;
(* ------------------------------------------------------------------------- *)
(* A lower bound theorem. *)
(* ------------------------------------------------------------------------- *)
let Y_LOWERBOUND = prove
(`!a n. (2 * a - 1) EXP n <= Y a (n + 1)`,
GEN_TAC THEN INDUCT_TAC THEN REWRITE_TAC[EXP; ARITH; Y_CLAUSES] THEN
ASM_CASES_TAC `a = 0` THEN ASM_REWRITE_TAC[ARITH; MULT_CLAUSES; LE_0] THEN
REWRITE_TAC[ARITH_RULE `SUC n + 1 = n + 2`; Y_CLAUSES] THEN
MATCH_MP_TAC LE_TRANS THEN
EXISTS_TAC `(2 * a - 1) * Y a (n + 1)` THEN
ASM_REWRITE_TAC[LE_MULT_LCANCEL] THEN
REWRITE_TAC[RIGHT_SUB_DISTRIB; MULT_CLAUSES; GSYM MULT_ASSOC] THEN
MATCH_MP_TAC(ARITH_RULE `a <= b ==> c - b <= c - a:num`) THEN
ASM_SIMP_TAC[Y_INCREASES]);;
let Y_UPPERBOUND = prove
(`!a n. Y a (n + 1) <= (2 * a) EXP n`,
GEN_TAC THEN INDUCT_TAC THEN
REWRITE_TAC[EXP; ADD_CLAUSES; Y_CLAUSES; LE_REFL] THEN
REWRITE_TAC[ARITH_RULE `SUC(n + 1) = n + 2`; Y_CLAUSES] THEN
MATCH_MP_TAC(ARITH_RULE `a <= b ==> a - c <= b:num`) THEN
ASM_REWRITE_TAC[MULT_ASSOC; LE_MULT_LCANCEL]);;
(* ------------------------------------------------------------------------- *)
(* Now a key congruence. *)
(* ------------------------------------------------------------------------- *)
let XY_Y3_CONGRUENCE = prove
(`!a n k. ~(a = 0)
==> ?q. Y a (n * k) =
k * (X a n) EXP (k - 1) * Y a n + q * (Y a n) EXP 3`,
REPEAT STRIP_TAC THEN ASM_CASES_TAC `k = 0` THENL
[EXISTS_TAC `0` THEN
ASM_REWRITE_TAC[Y_CLAUSES; MULT_CLAUSES; ADD_CLAUSES; SUB_0]; ALL_TAC] THEN
ASM_CASES_TAC `a = 1` THENL
[ASM_REWRITE_TAC[X_DEGENERATE; Y_DEGENERATE; EXP_ONE] THEN
EXISTS_TAC `0` THEN REWRITE_TAC[ADD_CLAUSES; MULT_CLAUSES] THEN
REWRITE_TAC[MULT_AC]; ALL_TAC] THEN
ASM_CASES_TAC `k = 1` THENL
[ASM_REWRITE_TAC[MULT_CLAUSES; SUB_REFL; EXP] THEN
EXISTS_TAC `0` THEN REWRITE_TAC[MULT_CLAUSES; ADD_CLAUSES]; ALL_TAC] THEN
MP_TAC(SPECL [`a:num`; `n * k:num`] XY_POWER_POS) THEN ASM_REWRITE_TAC[] THEN
REWRITE_TAC[GSYM REAL_POW_POW] THEN
MP_TAC(SPECL [`a:num`; `n:num`] XY_POWER_POS) THEN ASM_REWRITE_TAC[] THEN
REWRITE_TAC[GSYM REAL_POW_POW] THEN DISCH_THEN(SUBST1_TAC o SYM) THEN
SUBGOAL_THEN `2 <= k` MP_TAC THENL
[MAP_EVERY UNDISCH_TAC [`~(k = 0)`; `~(k = 1)`] THEN ARITH_TAC;
ALL_TAC] THEN
GEN_REWRITE_TAC LAND_CONV [LE_EXISTS] THEN
DISCH_THEN(X_CHOOSE_THEN `d:num`
(SUBST1_TAC o ONCE_REWRITE_RULE[ADD_SYM])) THEN
MP_TAC(SPECL [`X a n`; `Y a n`; `a EXP 2 - 1`; `d:num`]
BINOMIAL_TRIVIALITY) THEN
SUBGOAL_THEN `&a pow 2 - &1 = &(a EXP 2 - 1)` (SUBST1_TAC o SYM) THENL
[REWRITE_TAC[REAL_OF_NUM_POW] THEN MATCH_MP_TAC REAL_OF_NUM_SUB THEN
REWRITE_TAC[GSYM REAL_OF_NUM_LE; GSYM REAL_OF_NUM_POW] THEN
ASM_SIMP_TAC[REAL_POW_LE_1; REAL_OF_NUM_LE;
ARITH_RULE `~(a = 0) ==> 1 <= a`]; ALL_TAC] THEN
DISCH_THEN(X_CHOOSE_THEN `p:num` (X_CHOOSE_THEN `q:num` SUBST1_TAC)) THEN
ONCE_REWRITE_TAC[REAL_ARITH
`x1 + y1 + x2 + x3 + y2 = (x1 + x2 + x3) + (y1 + y2)`] THEN
REWRITE_TAC[REAL_MUL_ASSOC; GSYM REAL_ADD_RDISTRIB] THEN
SUBGOAL_THEN `&a pow 2 - &1 = &(a EXP 2 - 1)` SUBST1_TAC THENL
[REWRITE_TAC[REAL_OF_NUM_POW] THEN MATCH_MP_TAC REAL_OF_NUM_SUB THEN
REWRITE_TAC[GSYM REAL_OF_NUM_LE; GSYM REAL_OF_NUM_POW] THEN
ASM_SIMP_TAC[REAL_POW_LE_1; REAL_OF_NUM_LE;
ARITH_RULE `~(a = 0) ==> 1 <= a`]; ALL_TAC] THEN
REWRITE_TAC[REAL_OF_NUM_POW; REAL_OF_NUM_MUL; REAL_OF_NUM_ADD] THEN
SUBGOAL_THEN `&a pow 2 - &1 = &(a EXP 2 - 1)` (SUBST1_TAC o SYM) THENL
[REWRITE_TAC[REAL_OF_NUM_POW] THEN MATCH_MP_TAC REAL_OF_NUM_SUB THEN
REWRITE_TAC[GSYM REAL_OF_NUM_LE; GSYM REAL_OF_NUM_POW] THEN
ASM_SIMP_TAC[REAL_POW_LE_1; REAL_OF_NUM_LE;
ARITH_RULE `~(a = 0) ==> 1 <= a`]; ALL_TAC] THEN
ASM_SIMP_TAC[SQRT_LINEAR_EQ;
ARITH_RULE `~(p = 0) /\ ~(p = 1) ==> 2 <= p`] THEN
DISCH_THEN(K ALL_TAC) THEN
REWRITE_TAC[ARITH_RULE `(d + 2) - 1 = d + 1`] THEN
EXISTS_TAC `q:num` THEN REWRITE_TAC[GSYM MULT_ASSOC]);;
(* ------------------------------------------------------------------------- *)
(* The other key divisibility result. *)
(* ------------------------------------------------------------------------- *)
let Y2_DIVIDES = prove
(`!a m n. ~(a = 0)
==> (((Y a m) EXP 2) divides (Y a n) <=> (m * Y a m) divides n)`,
REPEAT STRIP_TAC THEN ASM_CASES_TAC `m = 0` THENL
[ASM_REWRITE_TAC[Y_CLAUSES; MULT_CLAUSES; DIVIDES_ZERO; EXP_2] THEN
GEN_REWRITE_TAC (LAND_CONV o RAND_CONV) [GSYM(CONJUNCT1 Y_CLAUSES)] THEN
ASM_SIMP_TAC[Y_INJ]; ALL_TAC] THEN
SUBGOAL_THEN `~(Y a m = 0)` ASSUME_TAC THENL
[GEN_REWRITE_TAC (RAND_CONV o RAND_CONV) [GSYM(CONJUNCT1 Y_CLAUSES)] THEN
ASM_SIMP_TAC[Y_INJ]; ALL_TAC] THEN
MATCH_MP_TAC(TAUT
`!c. (a ==> c) /\ (b ==> c) /\ (c ==> (a <=> b)) ==> (a <=> b)`) THEN
EXISTS_TAC `m divides n` THEN REPEAT CONJ_TAC THENL
[DISCH_TAC THEN
SUBGOAL_THEN `(Y a m) divides (Y a n)` MP_TAC THENL
[ALL_TAC; ASM_SIMP_TAC[Y_DIVIDES]] THEN
UNDISCH_TAC `((Y a m) EXP 2) divides (Y a n)` THEN
REWRITE_TAC[divides; EXP_2; GSYM MULT_ASSOC] THEN MESON_TAC[];
REWRITE_TAC[divides; GSYM MULT_ASSOC] THEN MESON_TAC[];
ALL_TAC] THEN
GEN_REWRITE_TAC LAND_CONV [divides] THEN
DISCH_THEN(X_CHOOSE_THEN `k:num` SUBST1_TAC) THEN
MP_TAC(SPECL [`a:num`; `m:num`; `k:num`] XY_Y3_CONGRUENCE) THEN
ASM_REWRITE_TAC[] THEN
DISCH_THEN(X_CHOOSE_THEN `q:num` SUBST1_TAC) THEN
MATCH_MP_TAC EQ_TRANS THEN
EXISTS_TAC `((Y a m) EXP 2) divides (k * (X a m) EXP (k - 1) * Y a m)` THEN
CONJ_TAC THENL
[REWRITE_TAC[num_CONV `3`; EXP] THEN
MESON_TAC[DIVIDES_ADD; DIVIDES_ADD_REVL; DIVIDES_LMUL; DIVIDES_REFL];
ALL_TAC] THEN
REWRITE_TAC[MULT_ASSOC] THEN
GEN_REWRITE_TAC (LAND_CONV o RAND_CONV) [MULT_SYM] THEN
REWRITE_TAC[EXP_2; GSYM MULT_ASSOC] THEN
ASM_SIMP_TAC[DIVIDES_LMUL2_EQ] THEN
EQ_TAC THEN SIMP_TAC[DIVIDES_RMUL] THEN
DISCH_TAC THEN MATCH_MP_TAC COPRIME_DIVPROD THEN
EXISTS_TAC `X a m EXP (k - 1)` THEN
ONCE_REWRITE_TAC[MULT_SYM] THEN ASM_REWRITE_TAC[] THEN
MATCH_MP_TAC COPRIME_EXP THEN
ONCE_REWRITE_TAC[COPRIME_SYM] THEN ASM_SIMP_TAC[XY_COPRIME]);;
(* ------------------------------------------------------------------------- *)
(* Some more congruences. *)
(* ------------------------------------------------------------------------- *)
let Y_N_MOD2 = prove
(`!a n. ~(a = 0) ==> ?q. Y a n = 2 * q + n`,
GEN_TAC THEN REWRITE_TAC[RIGHT_FORALL_IMP_THM] THEN DISCH_TAC THEN
MATCH_MP_TAC PELL_INDUCTION THEN REWRITE_TAC[Y_CLAUSES] THEN
REPEAT CONJ_TAC THENL
[EXISTS_TAC `0` THEN REWRITE_TAC[MULT_CLAUSES; ADD_CLAUSES];
EXISTS_TAC `0` THEN REWRITE_TAC[MULT_CLAUSES; ADD_CLAUSES];
ALL_TAC] THEN
REWRITE_TAC[RIGHT_AND_EXISTS_THM; LEFT_AND_EXISTS_THM;
LEFT_IMP_EXISTS_THM] THEN
MAP_EVERY X_GEN_TAC [`n:num`; `q1:num`; `q2:num`] THEN STRIP_TAC THEN
FIRST_ASSUM(MP_TAC o SPEC `n:num` o MATCH_MP Y_INCREASES) THEN
ASM_REWRITE_TAC[] THEN
REWRITE_TAC[ARITH_RULE `2 * q1 + n <= 2 * q2 + n + 1 <=> q1 <= q2`] THEN
DISCH_TAC THEN
EXISTS_TAC `(2 * a * q2 - q1) + (a - 1) * (n + 1)` THEN
MATCH_MP_TAC(ARITH_RULE
`v <= u /\ y <= x /\ (2 * (x + z) + w + v = 2 * y + u)
==> (u - v = 2 * ((x - y) + z) + w)`) THEN
REPEAT CONJ_TAC THENL
[REWRITE_TAC[LEFT_ADD_DISTRIB] THEN
MATCH_MP_TAC(ARITH_RULE
`x <= u /\ y <= v ==> 2 * x + y <= 2 * u + v + w`) THEN
REWRITE_TAC[MULT_ASSOC] THEN CONJ_TAC THEN
GEN_REWRITE_TAC LAND_CONV [ARITH_RULE `n = 1 * n`] THENL
[MATCH_MP_TAC LE_MULT2 THEN ASM_REWRITE_TAC[];
REWRITE_TAC[LE_MULT_RCANCEL] THEN DISJ1_TAC] THEN
UNDISCH_TAC `~(a = 0)` THEN ARITH_TAC;
REWRITE_TAC[MULT_ASSOC] THEN
GEN_REWRITE_TAC LAND_CONV [ARITH_RULE `n = 1 * n`] THEN
MATCH_MP_TAC LE_MULT2 THEN ASM_REWRITE_TAC[] THEN
UNDISCH_TAC `~(a = 0)` THEN ARITH_TAC;
UNDISCH_TAC `~(a = 0)` THEN SPEC_TAC(`a:num`,`a:num`) THEN
INDUCT_TAC THEN REWRITE_TAC[NOT_SUC] THEN
REWRITE_TAC[ARITH_RULE `SUC a - 1 = a`] THEN
REWRITE_TAC[MULT_CLAUSES; ADD_CLAUSES] THEN
ARITH_TAC]);;
let Y_N_MODA1 = prove
(`!a n. ~(a = 0) ==> ?q. Y a n = q * (a - 1) + n`,
GEN_TAC THEN REWRITE_TAC[RIGHT_FORALL_IMP_THM] THEN DISCH_TAC THEN
ASM_CASES_TAC `a = 1` THENL
[ASM_REWRITE_TAC[SUB_REFL; Y_DEGENERATE; MULT_CLAUSES; ADD_CLAUSES];
ALL_TAC] THEN
MATCH_MP_TAC PELL_INDUCTION THEN REWRITE_TAC[Y_CLAUSES] THEN
REPEAT CONJ_TAC THENL
[EXISTS_TAC `0` THEN REWRITE_TAC[MULT_CLAUSES; ADD_CLAUSES];
EXISTS_TAC `0` THEN REWRITE_TAC[MULT_CLAUSES; ADD_CLAUSES];
ALL_TAC] THEN
REWRITE_TAC[RIGHT_AND_EXISTS_THM; LEFT_AND_EXISTS_THM;
LEFT_IMP_EXISTS_THM] THEN
MAP_EVERY X_GEN_TAC [`n:num`; `q1:num`; `q2:num`] THEN
STRIP_TAC THEN
FIRST_ASSUM(MP_TAC o SPEC `n:num` o MATCH_MP Y_INCREASES) THEN
ASM_REWRITE_TAC[] THEN
REWRITE_TAC[ARITH_RULE `q1 + n <= q2 + n + 1 <=> q1 <= q2 + 1`] THEN
ASM_CASES_TAC `q2 = 0` THENL
[ASM_REWRITE_TAC[MULT_CLAUSES; ADD_CLAUSES] THEN
REWRITE_TAC[ARITH_RULE `a <= 1 <=> (a = 0) \/ (a = 1)`] THEN
ASM_REWRITE_TAC[MULT_EQ_0; MULT_EQ_1] THEN
ASM_REWRITE_TAC[ARITH_RULE `(a - 1 = 0) <=> (a = 0) \/ (a = 1)`] THEN
SIMP_TAC[ARITH_RULE `(a - 1 = 1) <=> (a = 2)`] THEN
STRIP_TAC THEN ASM_REWRITE_TAC[MULT_CLAUSES; ADD_CLAUSES] THENL
[EXISTS_TAC `2 * (n + 1)` THEN
UNDISCH_TAC `~(a = 0)` THEN SPEC_TAC(`a:num`,`b:num`) THEN
INDUCT_TAC THEN REWRITE_TAC[NOT_SUC] THEN
REWRITE_TAC[ARITH_RULE `SUC n - 1 = n`] THEN
REWRITE_TAC[MULT_CLAUSES; ADD_CLAUSES] THEN
MATCH_MP_TAC(ARITH_RULE `(a + c = b) ==> (b - a = c:num)`) THEN
ARITH_TAC;
REWRITE_TAC[MULT_ASSOC; ARITH] THEN
REWRITE_TAC[ARITH_RULE `4 * (n + 1) - (1 + n) = 3 * (n + 1)`] THEN
EXISTS_TAC `2 * n + 1` THEN ARITH_TAC];
ALL_TAC] THEN
DISCH_THEN(fun th ->
EXISTS_TAC `2 * (n + 1) + 2 * a * q2 - q1` THEN MP_TAC th) THEN
UNDISCH_TAC `~(a = 1)` THEN
UNDISCH_TAC `~(a = 0)` THEN SPEC_TAC(`a:num`,`b:num`) THEN
INDUCT_TAC THEN REWRITE_TAC[NOT_SUC] THEN
REWRITE_TAC[ARITH_RULE `(SUC n = 1) <=> (n = 0)`] THEN DISCH_TAC THEN
REWRITE_TAC[ARITH_RULE `SUC n - 1 = n`] THEN DISCH_TAC THEN
REWRITE_TAC[RIGHT_ADD_DISTRIB; RIGHT_SUB_DISTRIB] THEN
MATCH_MP_TAC(ARITH_RULE
`v <= u /\ y <= x /\ (u + y = z + x + w + v)
==> (u - v = (z + (x - y)) + w:num)`) THEN
REPEAT CONJ_TAC THENL
[GEN_REWRITE_TAC LAND_CONV [ARITH_RULE `a = 1 * a`] THEN
REWRITE_TAC[MULT_ASSOC] THEN MATCH_MP_TAC LE_MULT2 THEN
ASM_REWRITE_TAC[ARITH_RULE `q1 + n <= q2 + n + 1 <=> q1 <= q2 + 1`] THEN
REWRITE_TAC[MULT_CLAUSES] THEN ARITH_TAC;
MATCH_MP_TAC LE_TRANS THEN EXISTS_TAC `q2 * b + 1` THEN
ASM_REWRITE_TAC[] THEN
REWRITE_TAC[ARITH_RULE `a + 1 <= b <=> a < b`] THEN
ASM_SIMP_TAC[LT_MULT_RCANCEL] THEN
GEN_REWRITE_TAC LAND_CONV [ARITH_RULE `a = 1 * a`] THEN
REWRITE_TAC[MULT_ASSOC] THEN
ASM_SIMP_TAC[LT_MULT_RCANCEL] THEN
REWRITE_TAC[MULT_CLAUSES; ADD_CLAUSES] THEN ARITH_TAC;
REWRITE_TAC[MULT_CLAUSES; ADD_CLAUSES] THEN ARITH_TAC]);;
let X_CONGRUENT = prove
(`!a b c n. ~(a = 0) ==> ?q. X (a + b * c) n = X a n + q * c`,
GEN_TAC THEN GEN_TAC THEN GEN_TAC THEN
REWRITE_TAC[RIGHT_FORALL_IMP_THM] THEN DISCH_TAC THEN
ASM_CASES_TAC `b * c = 0` THENL
[GEN_TAC THEN EXISTS_TAC `0` THEN
ASM_REWRITE_TAC[MULT_CLAUSES; ADD_CLAUSES]; ALL_TAC] THEN
UNDISCH_TAC `~(b * c = 0)` THEN
REWRITE_TAC[MULT_EQ_0; DE_MORGAN_THM] THEN STRIP_TAC THEN
MATCH_MP_TAC PELL_INDUCTION THEN REWRITE_TAC[X_CLAUSES] THEN
REPEAT CONJ_TAC THENL
[EXISTS_TAC `0` THEN REWRITE_TAC[MULT_CLAUSES; ADD_CLAUSES];
EXISTS_TAC `b:num` THEN REWRITE_TAC[MULT_CLAUSES; ADD_CLAUSES];
ALL_TAC] THEN
REWRITE_TAC[RIGHT_AND_EXISTS_THM; LEFT_AND_EXISTS_THM;
LEFT_IMP_EXISTS_THM] THEN
MAP_EVERY X_GEN_TAC [`n:num`; `q1:num`; `q2:num`] THEN
STRIP_TAC THEN ASM_REWRITE_TAC[] THEN
REWRITE_TAC[ARITH_RULE
`2 * (x + y) * (u + v) = 2 * x * u + 2 * u * y + 2 * (x + y) * v`] THEN
EXISTS_TAC `(2 * X a (n + 1) * b + 2 * (a + b * c) * q2) - q1` THEN
MATCH_MP_TAC(ARITH_RULE
`a <= x /\ b <= y + z:num /\ ((x - a) + ((y + z) - b) = u)
==> ((x + y + z) - (a + b) = u)`) THEN
REWRITE_TAC[RIGHT_SUB_DISTRIB; RIGHT_ADD_DISTRIB; GSYM MULT_ASSOC] THEN
CONJ_TAC THENL
[MATCH_MP_TAC LE_TRANS THEN EXISTS_TAC `1 * X a (n + 1)` THEN CONJ_TAC THENL
[ASM_SIMP_TAC[MULT_CLAUSES; X_INCREASES]; ALL_TAC] THEN
REWRITE_TAC[MULT_ASSOC; LE_MULT_RCANCEL] THEN DISJ1_TAC THEN
UNDISCH_TAC `~(a = 0)` THEN ARITH_TAC; ALL_TAC] THEN
MATCH_MP_TAC LE_TRANS THEN EXISTS_TAC `X (a + b * c) n` THEN CONJ_TAC THENL
[ASM_REWRITE_TAC[ONCE_REWRITE_RULE[ADD_SYM] LE_ADD]; ALL_TAC] THEN
MATCH_MP_TAC LE_TRANS THEN EXISTS_TAC `X (a + b * c) (n + 1)` THEN
CONJ_TAC THENL [ASM_SIMP_TAC[X_INCREASES; ADD_EQ_0]; ALL_TAC] THEN
ASM_REWRITE_TAC[] THEN MATCH_MP_TAC LE_ADD2 THEN CONJ_TAC THENL
[GEN_REWRITE_TAC RAND_CONV [MULT_SYM] THEN
GEN_REWRITE_TAC LAND_CONV [ARITH_RULE `a = a * 1`] THEN
REWRITE_TAC[GSYM MULT_ASSOC; LE_MULT_LCANCEL] THEN
ASM_REWRITE_TAC[ARITH_RULE `1 <= x <=> ~(x = 0)`; MULT_EQ_0; ARITH_EQ];
MATCH_MP_TAC(ARITH_RULE `a <= y ==> a <= 2 * (x + y)`) THEN
ONCE_REWRITE_TAC[AC MULT_AC `a * b * c * d = (a * b) * (c * d:num)`] THEN
GEN_REWRITE_TAC LAND_CONV [ARITH_RULE `a = 1 * a`] THEN
REWRITE_TAC[LE_MULT_RCANCEL] THEN
ASM_REWRITE_TAC[ARITH_RULE `1 <= x <=> ~(x = 0)`; MULT_EQ_0; ARITH_EQ]]);;
let Y_CONGRUENT = prove
(`!a b c n. ~(a = 0) ==> ?q. Y (a + b * c) n = Y a n + q * c`,
GEN_TAC THEN GEN_TAC THEN GEN_TAC THEN
REWRITE_TAC[RIGHT_FORALL_IMP_THM] THEN DISCH_TAC THEN
ASM_CASES_TAC `b * c = 0` THENL
[GEN_TAC THEN EXISTS_TAC `0` THEN
ASM_REWRITE_TAC[MULT_CLAUSES; ADD_CLAUSES]; ALL_TAC] THEN
UNDISCH_TAC `~(b * c = 0)` THEN
REWRITE_TAC[MULT_EQ_0; DE_MORGAN_THM] THEN STRIP_TAC THEN
MATCH_MP_TAC PELL_INDUCTION THEN REWRITE_TAC[Y_CLAUSES] THEN
REPEAT CONJ_TAC THENL
[EXISTS_TAC `0` THEN REWRITE_TAC[MULT_CLAUSES; ADD_CLAUSES];
EXISTS_TAC `0` THEN REWRITE_TAC[MULT_CLAUSES; ADD_CLAUSES];
ALL_TAC] THEN
REWRITE_TAC[RIGHT_AND_EXISTS_THM; LEFT_AND_EXISTS_THM;
LEFT_IMP_EXISTS_THM] THEN
MAP_EVERY X_GEN_TAC [`n:num`; `q1:num`; `q2:num`] THEN
STRIP_TAC THEN ASM_REWRITE_TAC[] THEN
REWRITE_TAC[ARITH_RULE
`2 * (x + y) * (u + v) = 2 * x * u + 2 * u * y + 2 * (x + y) * v`] THEN
EXISTS_TAC `(2 * Y a (n + 1) * b + 2 * (a + b * c) * q2) - q1` THEN
MATCH_MP_TAC(ARITH_RULE
`a <= x /\ b <= y + z:num /\ ((x - a) + ((y + z) - b) = u)
==> ((x + y + z) - (a + b) = u)`) THEN
REWRITE_TAC[RIGHT_SUB_DISTRIB; RIGHT_ADD_DISTRIB; GSYM MULT_ASSOC] THEN
CONJ_TAC THENL
[MATCH_MP_TAC LE_TRANS THEN EXISTS_TAC `1 * Y a (n + 1)` THEN CONJ_TAC THENL
[ASM_SIMP_TAC[MULT_CLAUSES; Y_INCREASES]; ALL_TAC] THEN
REWRITE_TAC[MULT_ASSOC; LE_MULT_RCANCEL] THEN DISJ1_TAC THEN
UNDISCH_TAC `~(a = 0)` THEN ARITH_TAC; ALL_TAC] THEN
MATCH_MP_TAC LE_TRANS THEN EXISTS_TAC `Y (a + b * c) n` THEN CONJ_TAC THENL
[ASM_REWRITE_TAC[ONCE_REWRITE_RULE[ADD_SYM] LE_ADD]; ALL_TAC] THEN
MATCH_MP_TAC LE_TRANS THEN EXISTS_TAC `Y (a + b * c) (n + 1)` THEN
CONJ_TAC THENL [ASM_SIMP_TAC[Y_INCREASES; ADD_EQ_0]; ALL_TAC] THEN
ASM_REWRITE_TAC[] THEN MATCH_MP_TAC LE_ADD2 THEN CONJ_TAC THENL
[GEN_REWRITE_TAC RAND_CONV [MULT_SYM] THEN
GEN_REWRITE_TAC LAND_CONV [ARITH_RULE `a = a * 1`] THEN
REWRITE_TAC[GSYM MULT_ASSOC; LE_MULT_LCANCEL] THEN
ASM_REWRITE_TAC[ARITH_RULE `1 <= x <=> ~(x = 0)`; MULT_EQ_0; ARITH_EQ];
MATCH_MP_TAC(ARITH_RULE `a <= y ==> a <= 2 * (x + y)`) THEN
ONCE_REWRITE_TAC[AC MULT_AC `a * b * c * d = (a * b) * (c * d:num)`] THEN
GEN_REWRITE_TAC LAND_CONV [ARITH_RULE `a = 1 * a`] THEN
REWRITE_TAC[LE_MULT_RCANCEL] THEN
ASM_REWRITE_TAC[ARITH_RULE `1 <= x <=> ~(x = 0)`; MULT_EQ_0; ARITH_EQ]]);;
(* ------------------------------------------------------------------------- *)
(* A more important congruence. *)
(* ------------------------------------------------------------------------- *)
let X_CONGRUENT_2NJ_POS = prove
(`!a n j. ~(a = 0) ==> ?q. X a (2 * n + j) + X a j = q * X a n`,
REPEAT STRIP_TAC THEN
MP_TAC(SPECL [`a:num`; `n:num`; `n + j:num`] ADDITION_FORMULA_POS) THEN
ASM_REWRITE_TAC[ARITH_RULE `n + n + j = 2 * n + j`] THEN
DISCH_THEN(SUBST1_TAC o CONJUNCT1) THEN
MP_TAC(SPECL [`a:num`; `n:num`; `j:num`] ADDITION_FORMULA_POS) THEN
ASM_REWRITE_TAC[] THEN DISCH_THEN(SUBST1_TAC o CONJUNCT2) THEN
ONCE_REWRITE_TAC[ARITH_RULE
`(xn * a + d * yn * (xn * yj + xj * yn)) + xj =
xn * (a + d * yn * yj) + xj * (d * yn * yn + 1)`] THEN
ASM_SIMP_TAC[GSYM XY_ARE_SOLUTIONS; GSYM EXP_2] THEN
REWRITE_TAC[EXP_2; ARITH_RULE
`xn * a + xj * xn * xn = (a + xj * xn) * xn:num`] THEN
MESON_TAC[]);;
let X_CONGRUENT_4NJ_POS = prove
(`!a n j. ~(a = 0) ==> ?q. X a (4 * n + j) = q * X a n + X a j`,
REPEAT STRIP_TAC THEN
MP_TAC(SPECL [`a:num`; `n:num`; `2 * n + j`] X_CONGRUENT_2NJ_POS) THEN
ASM_REWRITE_TAC[ARITH_RULE `2 * n + 2 * n + j = 4 * n + j`] THEN
DISCH_THEN(X_CHOOSE_THEN `q1:num` MP_TAC) THEN
DISCH_THEN(MP_TAC o C AP_THM `X a j` o AP_TERM `(+):num->num->num`) THEN
REWRITE_TAC[GSYM ADD_ASSOC] THEN
MP_TAC(SPECL [`a:num`; `n:num`; `j:num`] X_CONGRUENT_2NJ_POS) THEN
ASM_REWRITE_TAC[] THEN DISCH_THEN(X_CHOOSE_THEN `q2:num` MP_TAC) THEN
DISCH_THEN SUBST1_TAC THEN
DISCH_THEN(MP_TAC o MATCH_MP (ARITH_RULE
`(y + q2 = q1 + x) ==> x <= y ==> (y = (q1 - q2) + x:num)`)) THEN
ASM_SIMP_TAC[X_INCREASES_LE; ARITH_RULE `j <= 4 * n + j`] THEN
DISCH_THEN(K ALL_TAC) THEN REWRITE_TAC[GSYM RIGHT_SUB_DISTRIB] THEN
MESON_TAC[]);;
let X_CONGRUENT_4MNJ_POS = prove
(`!a m n j. ~(a = 0) ==> ?q. X a (4 * m * n + j) = q * X a n + X a j`,
GEN_TAC THEN REWRITE_TAC[RIGHT_FORALL_IMP_THM] THEN
DISCH_TAC THEN INDUCT_TAC THEN REWRITE_TAC[MULT_CLAUSES; ADD_CLAUSES] THENL
[REPEAT GEN_TAC THEN EXISTS_TAC `0` THEN
REWRITE_TAC[MULT_CLAUSES; ADD_CLAUSES]; ALL_TAC] THEN
UNDISCH_TAC `!n j. ?q. X a (4 * m * n + j) = q * X a n + X a j` THEN
REPEAT(MATCH_MP_TAC MONO_FORALL THEN GEN_TAC) THEN
DISCH_THEN(X_CHOOSE_THEN `q1:num` ASSUME_TAC) THEN
MP_TAC(SPECL [`a:num`; `n:num`; `4 * m * n + j`] X_CONGRUENT_4NJ_POS) THEN
ASM_REWRITE_TAC[ARITH_RULE
`4 * (m * n + n) + j = 4 * n + 4 * m * n + j`] THEN
DISCH_THEN(X_CHOOSE_THEN `q2:num` SUBST1_TAC) THEN
EXISTS_TAC `q2 + q1:num` THEN ARITH_TAC);;
let X_CONGRUENT_2NJ_NEG_LEMMA = prove
(`!a n j. ~(a = 0) /\ j <= n ==> ?q. X a (2 * n - j) + X a j = q * X a n`,
REPEAT STRIP_TAC THEN ASM_CASES_TAC `j = n:num` THENL
[EXISTS_TAC `2` THEN ASM_REWRITE_TAC[MULT_2; ADD_SUB]; ALL_TAC] THEN
MP_TAC(SPECL [`a:num`; `n:num`; `n - j:num`] ADDITION_FORMULA_POS) THEN
ASM_SIMP_TAC[ARITH_RULE `j <= n ==> (n + n - j = 2 * n - j)`] THEN
STRIP_TAC THEN
MP_TAC(SPECL [`a:num`; `j:num`; `n:num`] ADDITION_FORMULA_NEG) THEN
ASM_REWRITE_TAC[] THEN STRIP_TAC THEN ASM_REWRITE_TAC[] THEN
EXISTS_TAC `(X a j * X a n - (a EXP 2 - 1) * Y a j * Y a n) +
(X a j * X a n - (a EXP 2 - 1) * Y a j * Y a n)` THEN
REWRITE_TAC[ARITH_RULE
`((xn * a + b) + c = (a + d) * xn) <=> (b + c = xn * d:num)`] THEN
REWRITE_TAC[LEFT_SUB_DISTRIB] THEN
MATCH_MP_TAC(ARITH_RULE
`b <= a /\ e <= d /\ (e + a + c = d + b)
==> ((a - b) + c = d - e:num)`) THEN
REPEAT CONJ_TAC THENL
[REWRITE_TAC[LE_MULT_LCANCEL] THEN REPEAT DISJ2_TAC THEN
FIRST_ASSUM(MATCH_MP_TAC o MATCH_MP (ARITH_RULE
`(c = a - b) ==> 1 <= c ==> b <= a`)) THEN
SUBST1_TAC(SYM(SPEC `a:num` (el 1 (CONJUNCTS Y_CLAUSES)))) THEN
MATCH_MP_TAC Y_INCREASES_LE THEN
ASM_SIMP_TAC[ARITH_RULE `j <= n ==> (1 <= n - j <=> ~(j = n))`];
REWRITE_TAC[LE_MULT_LCANCEL] THEN DISJ2_TAC THEN
FIRST_ASSUM(MATCH_MP_TAC o MATCH_MP (ARITH_RULE
`(c = a - b) ==> 1 <= c ==> b <= a`)) THEN
SUBST1_TAC(SYM(SPEC `a:num` (CONJUNCT1 X_CLAUSES))) THEN
MATCH_MP_TAC X_INCREASES_LE THEN ASM_REWRITE_TAC[LE_0];
REWRITE_TAC[ARITH_RULE
`xn * a * yj * yn + a * yn * xj * yn + xj =
xj * (a * yn * yn + 1) + a * yn * xn * yj`] THEN
ASM_SIMP_TAC[GSYM XY_ARE_SOLUTIONS; GSYM EXP_2] THEN
REWRITE_TAC[EXP_2; MULT_AC]]);;
let X_CONGRUENT_2NJ_NEG = prove
(`!a n j. ~(a = 0) /\ j <= 2 * n ==> ?q. X a (2 * n - j) + X a j = q * X a n`,
REPEAT STRIP_TAC THEN
ASM_CASES_TAC `j <= n:num` THEN ASM_SIMP_TAC[X_CONGRUENT_2NJ_NEG_LEMMA] THEN
MP_TAC(SPECL [`a:num`; `n:num`; `2 * n - j`] X_CONGRUENT_2NJ_NEG_LEMMA) THEN
ASM_SIMP_TAC[ARITH_RULE `~(j <= n) ==> 2 * n - j <= n`] THEN
ASM_SIMP_TAC[ARITH_RULE `y <= x ==> (x - (x - y) = y:num)`] THEN
SIMP_TAC[ADD_AC]);;
(* ------------------------------------------------------------------------- *)
(* The cute GCD fact given by Smorynski. *)
(* ------------------------------------------------------------------------- *)
let XY_GCD_LEMMA = prove
(`!a m n. ~(a = 0) /\ m < n
==> (gcd(Y a m,Y a n) = Y a (gcd(m,n)))`,
GEN_TAC THEN ASM_CASES_TAC `a = 0` THEN ASM_REWRITE_TAC[] THEN
ASM_CASES_TAC `a = 1` THEN ASM_REWRITE_TAC[Y_DEGENERATE] THEN
MATCH_MP_TAC num_WF THEN X_GEN_TAC `m:num` THEN DISCH_TAC THEN
X_GEN_TAC `n:num` THEN DISCH_TAC THEN
MP_TAC(SPECL [`n:num`; `m:num`] DIVISION) THEN
ASM_CASES_TAC `m = 0` THEN ASM_REWRITE_TAC[Y_CLAUSES; GCD_0] THEN
ABBREV_TAC `q = n DIV m` THEN ABBREV_TAC `r = n MOD m` THEN
DISCH_THEN(STRIP_ASSUME_TAC o GSYM) THEN
FIRST_X_ASSUM(MP_TAC o SPEC `r:num`) THEN ASM_REWRITE_TAC[] THEN
DISCH_THEN(MP_TAC o SPEC `m:num`) THEN ASM_REWRITE_TAC[] THEN
MATCH_MP_TAC EQ_IMP THEN BINOP_TAC THENL
[EXPAND_TAC "n" THEN ASM_SIMP_TAC[ADDITION_FORMULA_POS] THEN
GEN_REWRITE_TAC LAND_CONV [GCD_SYM] THEN MATCH_MP_TAC GCD_EQ THEN
X_GEN_TAC `d:num` THEN CONV_TAC SYM_CONV THEN MATCH_MP_TAC(TAUT
`(a ==> (b <=> c)) ==> (a /\ b <=> a /\ c)`) THEN
DISCH_TAC THEN MATCH_MP_TAC EQ_TRANS THEN
EXISTS_TAC `d divides (X a (q * m) * Y a r)` THEN CONJ_TAC THENL
[SUBGOAL_THEN `d divides (Y a (q * m))` MP_TAC THENL
[ASM_MESON_TAC[Y_DIVIDES; DIVIDES_TRANS; DIVIDES_LMUL; DIVIDES_REFL];
ALL_TAC] THEN
MESON_TAC[DIVIDES_ADD; DIVIDES_LMUL; DIVIDES_RMUL; DIVIDES_REFL;
DIVIDES_ADD_REVL];
ALL_TAC] THEN
EQ_TAC THEN SIMP_TAC[DIVIDES_LMUL] THEN
SUBGOAL_THEN `coprime(d,X a (q * m))`
(fun th -> MESON_TAC[COPRIME_DIVPROD; th]) THEN
SUBGOAL_THEN `d divides (Y a (q * m))` MP_TAC THENL
[ASM_MESON_TAC[Y_DIVIDES; DIVIDES_TRANS; DIVIDES_LMUL; DIVIDES_REFL];
ALL_TAC] THEN
MP_TAC(SPECL [`a:num`; `q * m:num`] XY_COPRIME) THEN ASM_REWRITE_TAC[] THEN
DISCH_TAC THEN DISCH_TAC THEN REWRITE_TAC[coprime] THEN
X_GEN_TAC `e:num` THEN STRIP_TAC THEN
UNDISCH_TAC `coprime (X a (q * m),Y a (q * m))` THEN
REWRITE_TAC[coprime] THEN DISCH_THEN(MP_TAC o SPEC `e:num`) THEN
DISCH_THEN MATCH_MP_TAC THEN ASM_MESON_TAC[DIVIDES_TRANS];
AP_TERM_TAC THEN EXPAND_TAC "n" THEN
GEN_REWRITE_TAC I [GSYM DIVIDES_ANTISYM] THEN
POP_ASSUM_LIST(K ALL_TAC) THEN NUMBER_TAC]);;
let XY_GCD = prove
(`!a m n. ~(a = 0) ==> (gcd(Y a m,Y a n) = Y a (gcd(m,n)))`,
REPEAT STRIP_TAC THEN
REPEAT_TCL DISJ_CASES_THEN ASSUME_TAC
(SPECL [`m:num`; `n:num`] LT_CASES)
THENL
[ASM_SIMP_TAC[XY_GCD_LEMMA];
ONCE_REWRITE_TAC[GCD_SYM] THEN ASM_SIMP_TAC[XY_GCD_LEMMA];
ASM_REWRITE_TAC[GCD_REFL]]);;
(* ------------------------------------------------------------------------- *)
(* The "step-down" lemma. *)
(* ------------------------------------------------------------------------- *)
let STEP_DOWN_LEMMA = prove
(`!a i j n q.
~(a = 0) /\ ~(a = 1) /\
i <= j /\ j <= 2 * n /\
(X a j = q * X a n + X a i)
==> (i = j) \/ ((a = 2) /\ (n = 1) /\ (i = 0) /\ (j = 2))`,
REPEAT STRIP_TAC THEN ASM_CASES_TAC `j <= n:num` THENL
[ASM_CASES_TAC `i = j:num` THEN ASM_REWRITE_TAC[] THEN
SUBGOAL_THEN `i < n:num` ASSUME_TAC THENL
[ASM_MESON_TAC[LTE_TRANS; LT_LE]; ALL_TAC] THEN
UNDISCH_TAC `X a j = q * X a n + X a i` THEN
ASM_CASES_TAC `q = 0` THEN
ASM_SIMP_TAC[ADD_CLAUSES; MULT_CLAUSES; X_INJ] THEN
DISCH_TAC THEN
MP_TAC(SPECL [`a:num`; `j:num`; `n:num`] X_INCREASES_LE) THEN
ASM_REWRITE_TAC[] THEN
MATCH_MP_TAC(TAUT `~a ==> a ==> b`) THEN
MATCH_MP_TAC(ARITH_RULE `1 <= b /\ 1 * x <= qx ==> ~(qx + b <= x)`) THEN
SIMP_TAC[LE_MULT_RCANCEL] THEN
ASM_SIMP_TAC[ARITH_RULE `~(x = 0) ==> 1 <= x`] THEN
ONCE_REWRITE_TAC[GSYM(CONJUNCT1 X_CLAUSES)] THEN
ASM_SIMP_TAC[X_INCREASES_LE; LE_0]; ALL_TAC] THEN
ASM_CASES_TAC `n = 0` THENL
[UNDISCH_TAC `i <= j:num` THEN UNDISCH_TAC `j <= 2 * n` THEN
ASM_SIMP_TAC[LE; MULT_CLAUSES]; ALL_TAC] THEN
ASM_CASES_TAC `i <= n:num` THENL
[MP_TAC(SPECL [`a:num`; `n:num`; `j:num`] X_CONGRUENT_2NJ_NEG) THEN
ASM_REWRITE_TAC[] THEN
DISCH_THEN(X_CHOOSE_THEN `q1:num` MP_TAC) THEN
UNDISCH_TAC `X a j = q * X a n + X a i` THEN
ASM_CASES_TAC `q = 0` THEN
ASM_SIMP_TAC[ADD_CLAUSES; MULT_CLAUSES; X_INJ] THEN DISCH_TAC THEN
DISCH_THEN(MP_TAC o MATCH_MP (ARITH_RULE
`(a + b + c = d:num) ==> (a + c = d - b)`)) THEN
REWRITE_TAC[GSYM RIGHT_SUB_DISTRIB] THEN
ASM_CASES_TAC `i = n:num` THENL
[ASM_REWRITE_TAC[] THEN
DISCH_THEN(MP_TAC o MATCH_MP (ARITH_RULE
`(x + n = q * n) ==> (x = q * n - 1 * n)`)) THEN
MATCH_MP_TAC(TAUT `~a ==> a ==> b`) THEN
REWRITE_TAC[GSYM RIGHT_SUB_DISTRIB] THEN
ASM_CASES_TAC `q1 - q - 1 = 0` THENL
[ASM_REWRITE_TAC[MULT_CLAUSES; ARITH_RULE `~(n = 0) <=> 1 <= n`] THEN
ONCE_REWRITE_TAC[GSYM(CONJUNCT1 X_CLAUSES)] THEN
ASM_SIMP_TAC[X_INCREASES_LE; LE_0]; ALL_TAC] THEN
MATCH_MP_TAC(ARITH_RULE
`j < n /\ 1 * n <= a * n ==> ~(j = a * n)`) THEN
ASM_SIMP_TAC[LE_MULT_RCANCEL; ARITH_RULE `~(x = 0) ==> 1 <= x`] THEN
MATCH_MP_TAC X_INCREASES_LT THEN ASM_REWRITE_TAC[] THEN
UNDISCH_TAC `~(j <= n:num)` THEN
UNDISCH_TAC `~(n = 0)` THEN ARITH_TAC; ALL_TAC] THEN
ASM_CASES_TAC `q1 - q = 0` THENL
[ASM_REWRITE_TAC[MULT_CLAUSES; ADD_EQ_0] THEN
MATCH_MP_TAC(TAUT `~c ==> a /\ c ==> b`) THEN
REWRITE_TAC[ARITH_RULE `~(n = 0) <=> 1 <= n`] THEN
ONCE_REWRITE_TAC[GSYM(CONJUNCT1 X_CLAUSES)] THEN
ASM_SIMP_TAC[X_INCREASES_LE; LE_0]; ALL_TAC] THEN
MATCH_MP_TAC(TAUT `(~b ==> a ==> c) ==> a ==> b \/ c`) THEN
DISCH_TAC THEN DISCH_TAC THEN
ASM_CASES_TAC `n = 1` THENL
[UNDISCH_TAC `j <= 2 * n` THEN ASM_REWRITE_TAC[MULT_CLAUSES] THEN
UNDISCH_TAC `~(j <= n:num)` THEN ASM_REWRITE_TAC[] THEN
REWRITE_TAC[IMP_IMP] THEN
DISCH_THEN(MP_TAC o MATCH_MP (ARITH_RULE
`~(j <= 1) /\ j <= 2 ==> (j = 2)`)) THEN
DISCH_THEN SUBST_ALL_TAC THEN REWRITE_TAC[] THEN
UNDISCH_THEN `n = 1` SUBST_ALL_TAC THEN
SUBGOAL_THEN `i = 0` SUBST_ALL_TAC THENL
[MAP_EVERY UNDISCH_TAC [`i <= 1`; `~(i = 1)`] THEN ARITH_TAC;
ALL_TAC] THEN
UNDISCH_TAC `X a (2 * 1 - 2) + X a 0 = (q1 - q) * X a 1` THEN
REWRITE_TAC[ARITH; X_CLAUSES] THEN DISCH_THEN(ASSUME_TAC o SYM) THEN
MATCH_MP_TAC(ARITH_RULE
`~(a = 0) /\ ~(a = 1) /\ a <= 2 ==> (a = 2)`) THEN
ASM_REWRITE_TAC[] THEN
UNDISCH_THEN `(q1 - q) * a = 2` (SUBST1_TAC o SYM) THEN
GEN_REWRITE_TAC LAND_CONV [ARITH_RULE `a = 1 * a`] THEN
REWRITE_TAC[LE_MULT_RCANCEL] THEN
ASM_SIMP_TAC[ARITH_RULE `~(q = 0) ==> 1 <= q`]; ALL_TAC] THEN
UNDISCH_TAC `X a (2 * n - j) + X a i = (q1 - q) * X a n` THEN
MATCH_MP_TAC(TAUT `~b ==> b ==> a`) THEN
MATCH_MP_TAC(ARITH_RULE
`s < x /\ x <= q * x ==> ~(s = q * x:num)`) THEN
CONJ_TAC THENL
[ALL_TAC;
GEN_REWRITE_TAC LAND_CONV [ARITH_RULE `a = 1 * a`] THEN
REWRITE_TAC[LE_MULT_RCANCEL] THEN
ASM_SIMP_TAC[ARITH_RULE `~(q = 0) ==> 1 <= q`]] THEN
MATCH_MP_TAC LET_TRANS THEN
EXISTS_TAC `2 * X a (n - 1)` THEN CONJ_TAC THENL
[MATCH_MP_TAC(ARITH_RULE `a <= c /\ b <= c ==> a + b <= 2 * c`) THEN
CONJ_TAC THEN MATCH_MP_TAC X_INCREASES_LE THEN ASM_REWRITE_TAC[] THENL
[UNDISCH_TAC `~(n = 0)` THEN UNDISCH_TAC `~(j <= n:num)` THEN ARITH_TAC;
UNDISCH_TAC `~(i = n:num)` THEN UNDISCH_TAC `i <= n:num` THEN
ARITH_TAC];
ALL_TAC] THEN
SUBGOAL_THEN `n - 1 = (n - 2) + 1` SUBST1_TAC THENL
[UNDISCH_TAC `~(n = 0)` THEN UNDISCH_TAC `~(n = 1)` THEN ARITH_TAC;
ALL_TAC] THEN
SUBGOAL_THEN `n = (n - 2) + 2`
(fun th -> GEN_REWRITE_TAC (RAND_CONV o ONCE_DEPTH_CONV) [th])
THENL
[UNDISCH_TAC `~(n = 0)` THEN UNDISCH_TAC `~(n = 1)` THEN ARITH_TAC;
ALL_TAC] THEN
REWRITE_TAC[X_CLAUSES] THEN
MATCH_MP_TAC(ARITH_RULE `z < x /\ 3 * x <= y ==> 2 * x < y - z`) THEN
ASM_SIMP_TAC[X_INCREASES_LT; ARITH_RULE `n < n + 1`] THEN
REWRITE_TAC[MULT_ASSOC; LE_MULT_RCANCEL] THEN DISJ1_TAC THEN
UNDISCH_TAC `~(a = 1)` THEN UNDISCH_TAC `~(a = 0)` THEN ARITH_TAC;
ALL_TAC] THEN
MP_TAC(SPECL [`a:num`; `n:num`; `j:num`] X_CONGRUENT_2NJ_NEG) THEN
ASM_REWRITE_TAC[] THEN
DISCH_THEN(X_CHOOSE_THEN `q1:num` MP_TAC) THEN
MP_TAC(SPECL [`a:num`; `n:num`; `i:num`] X_CONGRUENT_2NJ_NEG) THEN
ANTS_TAC THENL
[ASM_REWRITE_TAC[] THEN ASM_MESON_TAC[LE_TRANS]; ALL_TAC] THEN
DISCH_THEN(X_CHOOSE_THEN `q2:num` MP_TAC) THEN
ASM_REWRITE_TAC[] THEN
REWRITE_TAC[IMP_IMP] THEN
DISCH_THEN(MP_TAC o MATCH_MP (ARITH_RULE
`(a = b) /\ (c = d) ==> (a + d = b + c:num)`)) THEN
REWRITE_TAC[ARITH_RULE
`((x + i) + q1 = q2 + y + q3 + i) <=> (x + q1 = y + q2 + q3:num)`] THEN
DISCH_THEN(MP_TAC o MATCH_MP (ARITH_RULE
`(x + q1 = y + q2) ==> y <= x ==> (x = y + (q2 - q1:num))`)) THEN
ANTS_TAC THENL
[MATCH_MP_TAC X_INCREASES_LE THEN ASM_REWRITE_TAC[] THEN
UNDISCH_TAC `i <= j:num` THEN ARITH_TAC; ALL_TAC] THEN
REWRITE_TAC[GSYM RIGHT_ADD_DISTRIB; GSYM RIGHT_SUB_DISTRIB] THEN
ASM_CASES_TAC `(q2 + q) - q1 = 0` THENL
[ASM_SIMP_TAC[ADD_CLAUSES; MULT_CLAUSES; X_INJ] THEN
MATCH_MP_TAC(TAUT `(a ==> b) ==> (a ==> b \/ c)`) THEN
UNDISCH_TAC `j <= 2 * n` THEN UNDISCH_TAC `i <= j:num` THEN ARITH_TAC;
ALL_TAC] THEN
MATCH_MP_TAC(TAUT `~a ==> a ==> b`) THEN
MATCH_MP_TAC(ARITH_RULE
`1 * xi <= qxn /\ 1 <= xj ==> ~(xi = xj + qxn)`) THEN
CONJ_TAC THENL
[MATCH_MP_TAC LE_MULT2 THEN
ASM_REWRITE_TAC[ARITH_RULE `1 <= a <=> ~(a = 0)`] THEN
MATCH_MP_TAC X_INCREASES_LE THEN ASM_REWRITE_TAC[] THEN
UNDISCH_TAC `~(i <= n:num)` THEN ARITH_TAC; ALL_TAC] THEN
REWRITE_TAC[GSYM(CONJUNCT1 X_CLAUSES)] THEN
MATCH_MP_TAC X_INCREASES_LE THEN ASM_REWRITE_TAC[LE_0]);;
let STEP_DOWN_LEMMA_4_ASYM = prove
(`!a i j n q.
~(a = 0) /\ ~(a = 1) /\
0 < i /\ i <= n /\ j < 4 * n /\
(X a i + q * X a n = X a j)
==> (j = i) \/ (j = 4 * n - i)`,
REPEAT STRIP_TAC THEN ASM_CASES_TAC `j <= 2 * n` THENL
[MP_TAC(SPECL [`a:num`; `i:num`; `j:num`; `n:num`; `q:num`]
STEP_DOWN_LEMMA) THEN
ANTS_TAC THENL
[ASM_REWRITE_TAC[] THEN
UNDISCH_TAC `X a i + q * X a n = X a j` THEN
SIMP_TAC[ADD_AC; MULT_AC] THEN DISCH_THEN(ASSUME_TAC o SYM) THEN
SUBGOAL_THEN `X a i <= X a j` MP_TAC THENL
[ASM_REWRITE_TAC[ONCE_REWRITE_RULE[ADD_SYM] LE_ADD]; ALL_TAC] THEN
ONCE_REWRITE_TAC[TAUT `a ==> b <=> ~b ==> ~a`] THEN
ASM_SIMP_TAC[X_INCREASES_LT; NOT_LE]; ALL_TAC] THEN
ASM_SIMP_TAC[ARITH_RULE `0 < i ==> ~(i = 0)`]; ALL_TAC] THEN
DISJ_CASES_TAC(SPECL [`i:num`; `4 * n - j`] LE_CASES) THEN
(MP_TAC(SPECL [`a:num`; `n:num`; `2 * n - (4 * n - j)`]
X_CONGRUENT_2NJ_POS) THEN
MP_TAC(SPECL [`a:num`; `n:num`; `4 * n - j`] X_CONGRUENT_2NJ_NEG) THEN
ASM_SIMP_TAC[ARITH_RULE `~(j <= 2 * n) ==> 4 * n - j <= 2 * n`] THEN
ASM_SIMP_TAC[ARITH_RULE
`j < 4 * n /\ ~(j <= 2 * n)
==> (2 * n + 2 * n - (4 * n - j) = j)`] THEN
DISCH_THEN(X_CHOOSE_THEN `q1:num` ASSUME_TAC) THEN
DISCH_THEN(X_CHOOSE_THEN `q2:num` MP_TAC) THEN
SUBST1_TAC(SYM(ASSUME `X a i + q * X a n = X a j`)) THEN
UNDISCH_TAC
`X a (2 * n - (4 * n - j)) + X a (4 * n - j) = q1 * X a n` THEN
REWRITE_TAC[IMP_IMP] THEN
DISCH_THEN(MP_TAC o MATCH_MP (ARITH_RULE
`(a + b = c) /\ (d + a = e) ==> (b + e = c + d:num)`)))
THENL
[DISCH_THEN(MP_TAC o MATCH_MP (ARITH_RULE
`(x + q1 = q2 + y + q3)
==> y <= x ==> (x = ((q2 + q3) - q1) + y:num)`));
DISCH_THEN(MP_TAC o MATCH_MP (ARITH_RULE
`(x + q1 = q2 + y + q3)
==> x <= y ==> (y = (q1 - (q2 + q3)) + x:num)`))] THEN
REWRITE_TAC[GSYM RIGHT_SUB_DISTRIB; GSYM RIGHT_ADD_DISTRIB] THEN
ASM_SIMP_TAC[X_INCREASES_LE] THEN DISCH_TAC THENL
[MP_TAC(SPECL [`a:num`; `i:num`; `4 * n - j`; `n:num`; `(q1 + q) - q2:num`]
STEP_DOWN_LEMMA) THEN
ANTS_TAC THENL
[ASM_REWRITE_TAC[] THEN UNDISCH_TAC `~(j <= 2 * n)` THEN ARITH_TAC;
ALL_TAC] THEN
ASM_SIMP_TAC[ARITH_RULE `0 < i ==> ~(i = 0)`] THEN
DISCH_TAC THEN DISJ2_TAC THEN UNDISCH_TAC `j < 4 * n` THEN ARITH_TAC;
MP_TAC(SPECL [`a:num`; `4 * n - j`; `i:num`; `n:num`; `q2:num - (q1 + q)`]
STEP_DOWN_LEMMA) THEN
ANTS_TAC THENL
[ASM_REWRITE_TAC[] THEN UNDISCH_TAC `i <= n:num` THEN ARITH_TAC;
ALL_TAC] THEN
ASM_REWRITE_TAC[SUB_EQ_0; GSYM NOT_LT] THEN
DISCH_THEN(SUBST1_TAC o SYM) THEN
DISJ2_TAC THEN UNDISCH_TAC `j < 4 * n` THEN ARITH_TAC]);;
let STEP_DOWN_LEMMA_4 = prove
(`!a i j n q1 q2.
~(a = 0) /\ ~(a = 1) /\
0 < i /\ i <= n /\ j < 4 * n /\
(X a i + q1 * X a n = X a j + q2 * X a n)
==> (j = i) \/ (j = 4 * n - i)`,
REPEAT STRIP_TAC THEN ASM_CASES_TAC `j < i:num` THENL
[UNDISCH_TAC `X a i + q1 * X a n = X a j + q2 * X a n` THEN
DISCH_THEN(MP_TAC o MATCH_MP (ARITH_RULE
`(x + q1 = y + q2) ==> y < x ==> (x = y + (q2 - q1:num))`)) THEN
ASM_SIMP_TAC[X_INCREASES_LT; GSYM RIGHT_SUB_DISTRIB] THEN
ASM_CASES_TAC `q2 - q1 = 0` THENL
[ASM_SIMP_TAC[MULT_CLAUSES; ADD_CLAUSES; X_INJ]; ALL_TAC] THEN
MATCH_MP_TAC(TAUT `~a ==> a ==> b`) THEN
DISCH_THEN(MP_TAC o MATCH_MP (ARITH_RULE
`(i = j + q * n) ==> 1 <= j /\ 1 * n <= q * n ==> ~(i <= n)`)) THEN
ASM_SIMP_TAC[X_INCREASES_LE] THEN
ASM_SIMP_TAC[LE_MULT_RCANCEL;
ARITH_RULE `~(q2 - q1 = 0) ==> 1 <= q2 - q1`] THEN
ONCE_REWRITE_TAC[GSYM(CONJUNCT1 X_CLAUSES)] THEN
ASM_SIMP_TAC[X_INCREASES_LE; LE_0]; ALL_TAC] THEN
MP_TAC(SPECL [`a:num`; `i:num`; `j:num`; `n:num`; `q1 - q2:num`]
STEP_DOWN_LEMMA_4_ASYM) THEN
DISCH_THEN MATCH_MP_TAC THEN ASM_REWRITE_TAC[] THEN
REWRITE_TAC[RIGHT_SUB_DISTRIB] THEN
MATCH_MP_TAC(ARITH_RULE
`(i + q1 = j + q2) /\ ~(j < i) ==> (i + q1 - q2 = j:num)`) THEN
RULE_ASSUM_TAC(REWRITE_RULE[NOT_LT]) THEN
ASM_SIMP_TAC[NOT_LT; X_INCREASES_LE]);;
let STEP_DOWN_LEMMA_STRONG_ASYM = prove
(`!a i j n c.
~(a = 0) /\ ~(a = 1) /\
0 < i /\ i <= n /\
(X a i + c * X a n = X a j)
==> (?q. j = i + 4 * n * q) \/
(?q. j + i = 4 * n * q)`,
REPEAT STRIP_TAC THEN
MP_TAC(SPECL [`j:num`; `4 * n`] DIVISION) THEN
ABBREV_TAC `q = j DIV (4 * n)` THEN ABBREV_TAC `k = j MOD (4 * n)` THEN
ANTS_TAC THENL
[UNDISCH_TAC `0 < i` THEN UNDISCH_TAC `i <= n:num` THEN ARITH_TAC;
ALL_TAC] THEN
DISCH_THEN(STRIP_ASSUME_TAC o GSYM) THEN
MP_TAC(SPECL [`a:num`; `q:num`; `n:num`; `k:num`] X_CONGRUENT_4MNJ_POS) THEN
ASM_REWRITE_TAC[] THEN
DISCH_THEN(X_CHOOSE_THEN `q1:num` MP_TAC) THEN
SUBST1_TAC(ARITH_RULE `4 * q * n + k = q * 4 * n + k`) THEN
ASM_REWRITE_TAC[] THEN DISCH_THEN SUBST_ALL_TAC THEN
ASM_CASES_TAC `k < i:num` THENL
[UNDISCH_TAC `X a i + c * X a n = q1 * X a n + X a k` THEN
DISCH_THEN(MP_TAC o MATCH_MP (ARITH_RULE
`(a + q1 = q2 + b) ==> b < a ==> (a = (q2 - q1) + b:num)`)) THEN
ASM_SIMP_TAC[X_INCREASES_LT] THEN REWRITE_TAC[GSYM RIGHT_SUB_DISTRIB] THEN
ASM_CASES_TAC `q1 - c = 0` THENL
[ASM_SIMP_TAC[MULT_CLAUSES; ADD_CLAUSES; X_INJ] THEN
DISCH_TAC THEN DISJ1_TAC THEN EXISTS_TAC `q:num` THEN
FIRST_ASSUM(fun th -> GEN_REWRITE_TAC LAND_CONV [SYM th]) THEN
REWRITE_TAC[ADD_AC; MULT_AC];
MATCH_MP_TAC(TAUT `~a ==> a ==> b`) THEN
MATCH_MP_TAC(ARITH_RULE
`a <= b /\ 1 <= c ==> ~(a = b + c)`) THEN
CONJ_TAC THENL
[GEN_REWRITE_TAC LAND_CONV [ARITH_RULE `n = 1 * n`] THEN
MATCH_MP_TAC LE_MULT2 THEN
ASM_REWRITE_TAC[ARITH_RULE `1 <= n <=> ~(n = 0)`] THEN
ASM_SIMP_TAC[X_INCREASES_LE; LT_IMP_LE];
SUBST1_TAC(SYM(SPEC `a:num` (CONJUNCT1 X_CLAUSES))) THEN
ASM_SIMP_TAC[X_INCREASES_LE; LE_0]]];
MP_TAC(SPECL [`a:num`; `i:num`; `k:num`; `n:num`; `c - q1:num`]
STEP_DOWN_LEMMA_4_ASYM) THEN
ANTS_TAC THENL
[ASM_REWRITE_TAC[] THEN
UNDISCH_TAC `X a i + c * X a n = q1 * X a n + X a k` THEN
DISCH_THEN(MP_TAC o MATCH_MP (ARITH_RULE
`(a + q1 = q2 + b) ==> ~(b < a) ==> (a + (q1 - q2)= b:num)`)) THEN
REWRITE_TAC[GSYM RIGHT_SUB_DISTRIB] THEN
DISCH_THEN MATCH_MP_TAC THEN REWRITE_TAC[NOT_LT] THEN
MATCH_MP_TAC X_INCREASES_LE THEN ASM_REWRITE_TAC[GSYM NOT_LT];
ALL_TAC] THEN
DISCH_THEN DISJ_CASES_TAC THENL
[DISJ1_TAC THEN EXISTS_TAC `q:num` THEN
UNDISCH_THEN `q * 4 * n + k = j` (SUBST1_TAC o SYM) THEN
ASM_REWRITE_TAC[MULT_AC; ADD_AC];
DISJ2_TAC THEN EXISTS_TAC `q + 1` THEN
UNDISCH_THEN `q * 4 * n + k = j` (SUBST1_TAC o SYM) THEN
REWRITE_TAC[GSYM ADD_ASSOC; LEFT_ADD_DISTRIB; MULT_CLAUSES] THEN
ASM_REWRITE_TAC[] THEN
MATCH_MP_TAC(ARITH_RULE
`(a' = a) /\ i <= b ==> (a + (b - i) + i = a' + b:num)`) THEN
REWRITE_TAC[MULT_AC] THEN
UNDISCH_TAC `i <= n:num` THEN ARITH_TAC]]);;
let STEP_DOWN_LEMMA_STRONG = prove
(`!a i j n c1 c2.
~(a = 0) /\ ~(a = 1) /\ 0 < i /\ i <= n /\
(X a i + c1 * X a n = X a j + c2 * X a n)
==> (?q. j = i + 4 * n * q) \/
(?q. j + i = 4 * n * q)`,
REPEAT STRIP_TAC THEN ASM_CASES_TAC `j < i:num` THENL
[UNDISCH_TAC `X a i + c1 * X a n = X a j + c2 * X a n` THEN
DISCH_THEN(MP_TAC o MATCH_MP (ARITH_RULE
`(x + q1 = y + q2) ==> y < x ==> (x = y + (q2 - q1:num))`)) THEN
ASM_SIMP_TAC[X_INCREASES_LT; GSYM RIGHT_SUB_DISTRIB] THEN
ASM_CASES_TAC `c2 - c1 = 0` THENL
[ASM_SIMP_TAC[MULT_CLAUSES; ADD_CLAUSES; X_INJ] THEN
DISCH_THEN(K ALL_TAC) THEN DISJ1_TAC THEN
EXISTS_TAC `0` THEN REWRITE_TAC[MULT_CLAUSES; ADD_CLAUSES];
ALL_TAC] THEN
MATCH_MP_TAC(TAUT `~a ==> a ==> b`) THEN
DISCH_THEN(MP_TAC o MATCH_MP (ARITH_RULE
`(i = j + q * n) ==> 1 <= j /\ 1 * n <= q * n ==> ~(i <= n)`)) THEN
ASM_SIMP_TAC[X_INCREASES_LE] THEN
ASM_SIMP_TAC[LE_MULT_RCANCEL;
ARITH_RULE `~(q2 - q1 = 0) ==> 1 <= q2 - q1`] THEN
ONCE_REWRITE_TAC[GSYM(CONJUNCT1 X_CLAUSES)] THEN
ASM_SIMP_TAC[X_INCREASES_LE; LE_0]; ALL_TAC] THEN
MP_TAC(SPECL [`a:num`; `i:num`; `j:num`; `n:num`; `c1 - c2:num`]
STEP_DOWN_LEMMA_STRONG_ASYM) THEN
DISCH_THEN MATCH_MP_TAC THEN ASM_REWRITE_TAC[] THEN
REWRITE_TAC[RIGHT_SUB_DISTRIB] THEN
MATCH_MP_TAC(ARITH_RULE
`(i + q1 = j + q2) /\ ~(j < i) ==> (i + q1 - q2 = j:num)`) THEN
RULE_ASSUM_TAC(REWRITE_RULE[NOT_LT]) THEN
ASM_SIMP_TAC[NOT_LT; X_INCREASES_LE]);;
(* ------------------------------------------------------------------------- *)
(* Diophantine nature of the Y sequence. *)
(* ------------------------------------------------------------------------- *)
let Y_DIOPH = prove
(`~(a = 0) /\ ~(a = 1) /\ ~(y = 0)
==> ((y = Y a k) <=>
?x u v r b p q s t c d.
0 < r /\
(x EXP 2 = (a EXP 2 - 1) * y EXP 2 + 1) /\
(u EXP 2 = (a EXP 2 - 1) * v EXP 2 + 1) /\
(s EXP 2 = (b EXP 2 - 1) * t EXP 2 + 1) /\
(v = r * y EXP 2) /\
(b = 1 + 4 * p * y) /\
(b = a + q * u) /\
(s = x + c * u) /\
(t = k + 4 * d * y) /\
k <= y)`,
REPEAT STRIP_TAC THEN EQ_TAC THENL
[ALL_TAC;
DISCH_THEN(STRIP_ASSUME_TAC o GSYM) THEN
MP_TAC(SPECL [`a:num`; `x:num`; `y:num`] SOLUTIONS_ARE_XY) THEN
ASM_REWRITE_TAC[] THEN
DISCH_THEN(X_CHOOSE_THEN `i:num` (STRIP_ASSUME_TAC o GSYM)) THEN
MP_TAC(SPECL [`a:num`; `u:num`; `v:num`] SOLUTIONS_ARE_XY) THEN
ASM_REWRITE_TAC[] THEN
DISCH_THEN(X_CHOOSE_THEN `n:num` (STRIP_ASSUME_TAC o GSYM)) THEN
SUBGOAL_THEN `~(b = 0)` ASSUME_TAC THENL
[SUBST1_TAC(SYM(ASSUME `1 + 4 * p * y = b`)) THEN
REWRITE_TAC[ADD_EQ_0; ARITH_EQ]; ALL_TAC] THEN
MP_TAC(SPECL [`b:num`; `s:num`; `t:num`] SOLUTIONS_ARE_XY) THEN
ASM_REWRITE_TAC[] THEN
DISCH_THEN(X_CHOOSE_THEN `j:num` (STRIP_ASSUME_TAC o GSYM)) THEN
SUBGOAL_THEN `y <= v:num` ASSUME_TAC THENL
[SUBST1_TAC(SYM(ASSUME `r * y EXP 2 = v`)) THEN REWRITE_TAC[EXP_2] THEN
GEN_REWRITE_TAC LAND_CONV [ARITH_RULE `y = 1 * y`] THEN
REWRITE_TAC[MULT_ASSOC; LE_MULT_RCANCEL] THEN DISJ1_TAC THEN
ASM_REWRITE_TAC[ARITH_RULE `1 <= a <=> ~(a = 0)`; MULT_EQ_0] THEN
ASM_SIMP_TAC[ARITH_RULE `0 < r ==> ~(r = 0)`]; ALL_TAC] THEN
SUBGOAL_THEN `i <= n:num` ASSUME_TAC THENL
[UNDISCH_TAC `y <= v:num` THEN
SUBST1_TAC(SYM(ASSUME `Y a i = y`)) THEN
SUBST1_TAC(SYM(ASSUME `Y a n = v`)) THEN
ONCE_REWRITE_TAC[TAUT `a ==> b <=> ~b ==> ~a`] THEN
ASM_SIMP_TAC[NOT_LE; Y_INCREASES_LT]; ALL_TAC] THEN
MP_TAC(SPECL [`a:num`; `q:num`; `u:num`; `j:num`] X_CONGRUENT) THEN
REWRITE_TAC[ASSUME `~(a = 0)`; ASSUME `a + q * u = b:num`] THEN
DISCH_THEN(X_CHOOSE_THEN `q1:num` MP_TAC) THEN
SUBST1_TAC(ASSUME `X b j = s`) THEN
SUBST1_TAC(SYM(ASSUME `x + c * u = s:num`)) THEN
SUBST1_TAC(SYM(ASSUME `X a i = x`)) THEN
SUBST1_TAC(SYM(ASSUME `X a n = u`)) THEN DISCH_TAC THEN
SUBGOAL_THEN `~(i = 0)` ASSUME_TAC THENL
[UNDISCH_TAC `~(y = 0)` THEN
REWRITE_TAC[TAUT `~a ==> ~b <=> b ==> a`] THEN
EXPAND_TAC "y" THEN SIMP_TAC[Y_CLAUSES; ASSUME `~(a = 0)`];
ALL_TAC] THEN
SUBGOAL_THEN `(?q. j = i + 4 * n * q) \/ (?q. j + i = 4 * n * q)`
ASSUME_TAC THENL
[MATCH_MP_TAC STEP_DOWN_LEMMA_STRONG THEN
MAP_EVERY EXISTS_TAC [`a:num`; `c:num`; `q1:num`] THEN
ASM_SIMP_TAC[ARITH_RULE `~(i = 0) ==> 0 < i`]; ALL_TAC] THEN
MP_TAC(SPECL [`a:num`; `i:num`; `n:num`] Y2_DIVIDES) THEN
ASM_REWRITE_TAC[] THEN
DISCH_THEN(MP_TAC o fst o EQ_IMP_RULE) THEN
REWRITE_TAC[divides; LEFT_IMP_EXISTS_THM] THEN
DISCH_THEN(MP_TAC o SPEC `r:num`) THEN
SUBST1_TAC(SYM(ASSUME `r * y EXP 2 = v`)) THEN
REWRITE_TAC[EQT_INTRO(SPEC_ALL MULT_SYM)] THEN
DISCH_THEN(X_CHOOSE_THEN `d1:num` (ASSUME_TAC o SYM)) THEN
UNDISCH_TAC `(?q. j = i + 4 * n * q) \/ (?q. j + i = 4 * n * q:num)` THEN
UNDISCH_THEN `(i * y) * d1 = n:num` (SUBST1_TAC o SYM) THEN DISCH_TAC THEN
SUBGOAL_THEN `(?q. j = i + q * 4 * Y a i) \/
(?q. j + i = q * 4 * Y a i)`
MP_TAC THENL
[FIRST_ASSUM(UNDISCH_TAC o check is_disj o concl) THEN
REWRITE_TAC[OR_EXISTS_THM] THEN
DISCH_THEN(X_CHOOSE_THEN `d2:num`
(fun th -> EXISTS_TAC `i * d1 * d2:num` THEN MP_TAC th)) THEN
SUBST1_TAC(ASSUME `Y a i = y`) THEN REWRITE_TAC[MULT_AC];
FIRST_X_ASSUM(K ALL_TAC o check (is_disj o concl)) THEN
DISCH_TAC] THEN
MP_TAC(SPECL [`b:num`; `j:num`] Y_N_MODA1) THEN
ASM_REWRITE_TAC[] THEN
DISCH_THEN(X_CHOOSE_THEN `d3:num` MP_TAC) THEN
SUBST1_TAC(SYM(ASSUME `1 + 4 * p * y = b`)) THEN REWRITE_TAC[ADD_SUB2] THEN
SUBST1_TAC(SYM(ASSUME `k + 4 * d * y = t`)) THEN DISCH_TAC THEN
SUBST1_TAC(SYM(ASSUME `Y a i = y`)) THEN AP_TERM_TAC THEN
SUBGOAL_THEN `(?q1 q2. k + q1 * 4 * Y a i = i + q2 * 4 * Y a i) \/
(?q. i + k = q * 4 * Y a i)`
MP_TAC THENL
[UNDISCH_TAC `(?q. j = i + q * 4 * Y a i) \/
(?q. j + i = q * 4 * Y a i)` THEN
MATCH_MP_TAC(TAUT
`(a1 ==> b1) /\ (a2 ==> b2) ==> a1 \/ a2 ==> b1 \/ b2`) THEN
CONJ_TAC THEN DISCH_TAC THEN
UNDISCH_TAC `k + 4 * d * y = d3 * 4 * p * y + j` THENL
[FIRST_X_ASSUM(X_CHOOSE_THEN `d4:num` SUBST1_TAC) THEN
DISCH_THEN(fun th ->
EXISTS_TAC `d:num` THEN
EXISTS_TAC `d3 * p + d4:num` THEN MP_TAC th) THEN
SUBST1_TAC(SYM(ASSUME `Y a i = y`)) THEN
REWRITE_TAC[RIGHT_ADD_DISTRIB] THEN
REWRITE_TAC[MULT_AC] THEN REWRITE_TAC[ADD_AC];
DISCH_THEN(MP_TAC o C AP_THM `i:num` o
AP_TERM `(+):num->num->num`) THEN
REWRITE_TAC[GSYM ADD_ASSOC] THEN
FIRST_X_ASSUM(X_CHOOSE_THEN `d4:num` SUBST1_TAC) THEN
DISCH_THEN(MP_TAC o MATCH_MP (ARITH_RULE
`(k + q1 + i = q2) ==> (i + k = q2 - q1:num)`)) THEN
DISCH_THEN SUBST1_TAC THEN
SUBST1_TAC(SYM(ASSUME `Y a i = y`)) THEN
REWRITE_TAC[GSYM RIGHT_ADD_DISTRIB; MULT_ASSOC;
GSYM RIGHT_SUB_DISTRIB] THEN
REWRITE_TAC[GSYM MULT_ASSOC] THEN
REWRITE_TAC[ARITH_RULE
`(d3 * 4 * p + d4 * 4) - 4 * x =
((d3 * p + d4) - x) * 4`] THEN REWRITE_TAC[GSYM MULT_ASSOC] THEN
EXISTS_TAC `(d3 * p + d4) - d:num` THEN REFL_TAC];
ALL_TAC] THEN
SUBGOAL_THEN `k <= Y a i` ASSUME_TAC THENL
[ASM_REWRITE_TAC[]; ALL_TAC] THEN
SUBGOAL_THEN `i <= Y a i` ASSUME_TAC THENL
[MP_TAC(SPECL [`a:num`; `i:num`] Y_N_MODA1) THEN
ASM_SIMP_TAC[LEFT_IMP_EXISTS_THM] THEN
REWRITE_TAC[ONCE_REWRITE_RULE[ADD_SYM] LE_ADD]; ALL_TAC] THEN
DISCH_THEN(DISJ_CASES_THEN MP_TAC) THENL
[DISCH_THEN(X_CHOOSE_THEN `q4:num` (X_CHOOSE_THEN `q5:num` MP_TAC)) THEN
REPEAT_TCL DISJ_CASES_THEN ASSUME_TAC
(SPECL [`q4:num`; `q5:num`] LT_CASES)
THENL
[DISCH_THEN(MP_TAC o MATCH_MP (ARITH_RULE
`(k + q4 = i + q5) ==> q4 < q5:num ==> (k = i + (q5 - q4))`)) THEN
REWRITE_TAC[MULT_ASSOC; LT_MULT_RCANCEL; GSYM RIGHT_SUB_DISTRIB] THEN
ASM_REWRITE_TAC[MULT_EQ_0; ARITH_EQ] THEN
UNDISCH_TAC `k <= y:num` THEN
MATCH_MP_TAC(TAUT `(a ==> ~b) ==> b ==> a ==> c`) THEN
DISCH_THEN SUBST1_TAC THEN
MATCH_MP_TAC(ARITH_RULE `1 * y < k * y ==> ~(i + k * y <= y)`) THEN
ASM_REWRITE_TAC[LT_MULT_RCANCEL] THEN
UNDISCH_TAC `q4 < q5:num` THEN ARITH_TAC;
DISCH_THEN(MP_TAC o MATCH_MP (ARITH_RULE
`(k + q4 = i + q5) ==> q5 < q4:num ==> (i = k + (q4 - q5))`)) THEN
REWRITE_TAC[MULT_ASSOC; LT_MULT_RCANCEL; GSYM RIGHT_SUB_DISTRIB] THEN
ASM_REWRITE_TAC[MULT_EQ_0; ARITH_EQ] THEN
UNDISCH_TAC `i <= Y a i` THEN
MATCH_MP_TAC(TAUT `(a ==> ~b) ==> b ==> a ==> c`) THEN
ASM_REWRITE_TAC[] THEN
DISCH_THEN SUBST1_TAC THEN
MATCH_MP_TAC(ARITH_RULE `1 * y < k * y ==> ~(i + k * y <= y)`) THEN
ASM_REWRITE_TAC[LT_MULT_RCANCEL] THEN
UNDISCH_TAC `q5 < q4:num` THEN ARITH_TAC;
ASM_SIMP_TAC[EQ_ADD_RCANCEL]];
DISCH_THEN(X_CHOOSE_THEN `q6:num` MP_TAC) THEN
ASM_CASES_TAC `q6 = 0` THEN ASM_REWRITE_TAC[MULT_CLAUSES; ADD_EQ_0] THEN
UNDISCH_TAC `k <= Y a i` THEN UNDISCH_TAC `i <= Y a i` THEN
SUBST1_TAC(ASSUME `Y a i = y`) THEN
MATCH_MP_TAC(ARITH_RULE
`2 * y < ay ==> i <= y ==> k <= y ==> (i + k = ay) ==> (i = k)`) THEN
REWRITE_TAC[MULT_ASSOC; LT_MULT_RCANCEL] THEN ASM_REWRITE_TAC[] THEN
UNDISCH_TAC `~(q6 = 0)` THEN ARITH_TAC]] THEN
DISCH_THEN(ASSUME_TAC o SYM) THEN ABBREV_TAC `x = X a k` THEN
SUBGOAL_THEN `x EXP 2 = (a EXP 2 - 1) * y EXP 2 + 1` (ASSUME_TAC o SYM) THENL
[MAP_EVERY EXPAND_TAC ["x"; "y"] THEN
SIMP_TAC[XY_ARE_SOLUTIONS; ASSUME `~(a = 0)`]; ALL_TAC] THEN
EXISTS_TAC `x:num` THEN ASM_REWRITE_TAC[] THEN
ABBREV_TAC `m = 2 * k * Y a k` THEN
ABBREV_TAC `u = X a m` THEN ABBREV_TAC `v = Y a m` THEN
SUBGOAL_THEN `u EXP 2 = (a EXP 2 - 1) * v EXP 2 + 1` (ASSUME_TAC o SYM) THENL
[MAP_EVERY EXPAND_TAC ["u"; "v"] THEN
SIMP_TAC[XY_ARE_SOLUTIONS; ASSUME `~(a = 0)`]; ALL_TAC] THEN
EXISTS_TAC `u:num` THEN EXISTS_TAC `v:num` THEN ASM_REWRITE_TAC[] THEN
SUBGOAL_THEN `(y EXP 2) divides v` MP_TAC THENL
[SUBST1_TAC(SYM(ASSUME `Y a m = v`)) THEN
SUBST1_TAC(SYM(ASSUME `Y a k = y`)) THEN
SIMP_TAC[Y2_DIVIDES; ASSUME `~(a = 0)`] THEN
SUBST1_TAC(SYM(ASSUME `2 * k * Y a k = m`)) THEN
REWRITE_TAC[divides] THEN EXISTS_TAC `2` THEN
REWRITE_TAC[MULT_AC]; ALL_TAC] THEN
REWRITE_TAC[divides] THEN
DISCH_THEN(X_CHOOSE_THEN `r:num` (ASSUME_TAC o SYM)) THEN
EXISTS_TAC `r:num` THEN ASM_REWRITE_TAC[] THEN
ASM_CASES_TAC `r = 0` THENL
[UNDISCH_TAC `y EXP 2 * r = v` THEN ASM_REWRITE_TAC[MULT_CLAUSES] THEN
DISCH_THEN(ASSUME_TAC o SYM) THEN REWRITE_TAC[LT_REFL] THEN
UNDISCH_TAC `Y a m = v` THEN ASM_REWRITE_TAC[] THEN DISCH_TAC THEN
SUBGOAL_THEN `m = 0` ASSUME_TAC THENL
[UNDISCH_TAC `Y a m = 0` THEN
ONCE_REWRITE_TAC[GSYM(CONJUNCT1 Y_CLAUSES)] THEN
SIMP_TAC[Y_INJ; ASSUME `~(a = 0)`] THEN
REWRITE_TAC[Y_CLAUSES]; ALL_TAC] THEN
SUBGOAL_THEN `k = 0` ASSUME_TAC THENL
[UNDISCH_TAC `2 * k * Y a k = m` THEN
REWRITE_TAC[ASSUME `m = 0`; MULT_EQ_0; ARITH_EQ] THEN
ONCE_REWRITE_TAC[GSYM(CONJUNCT1 Y_CLAUSES)] THEN
SIMP_TAC[Y_INJ; ASSUME `~(a = 0)`] THEN
REWRITE_TAC[Y_CLAUSES; EQ_SYM]; ALL_TAC] THEN
UNDISCH_TAC `Y a k = y` THEN ASM_REWRITE_TAC[Y_CLAUSES];
ALL_TAC] THEN
ASM_SIMP_TAC[ARITH_RULE `~(r = 0) ==> 0 < r`] THEN
SUBGOAL_THEN `ODD(u)` ASSUME_TAC THENL
[UNDISCH_TAC `(a EXP 2 - 1) * v EXP 2 + 1 = u EXP 2` THEN
DISCH_THEN(MP_TAC o AP_TERM `EVEN`) THEN
REWRITE_TAC[EXP_2; EVEN_ADD; EVEN_MULT; ARITH_EVEN] THEN
SUBGOAL_THEN `EVEN v` (fun th -> REWRITE_TAC[GSYM NOT_EVEN; th]) THEN
SUBST1_TAC(SYM(ASSUME `Y a m = v`)) THEN
MP_TAC(SPECL [`a:num`; `m:num`] Y_N_MOD2) THEN
SIMP_TAC[ASSUME `~(a = 0)`; LEFT_IMP_EXISTS_THM] THEN
SUBST1_TAC(SYM(ASSUME `2 * k * Y a k = m`)) THEN
REWRITE_TAC[EVEN_ADD; EVEN_MULT; ARITH_EVEN]; ALL_TAC] THEN
SUBGOAL_THEN `?b0 q6 q7. (b0 = 1 + q6 * 4 * y) /\ (b0 = a + q7 * u)`
MP_TAC THENL
[MATCH_MP_TAC CHINESE_REMAINDER THEN
UNDISCH_TAC `ODD u` THEN
ASM_CASES_TAC `u = 0` THEN ASM_REWRITE_TAC[ARITH_ODD] THEN
DISCH_TAC THEN ASM_REWRITE_TAC[MULT_EQ_0; ARITH_EQ] THEN
ONCE_REWRITE_TAC[COPRIME_SYM] THEN MATCH_MP_TAC COPRIME_MUL THEN
CONJ_TAC THENL
[SUBST1_TAC(SYM(NUM_REDUCE_CONV `2 * 2`)) THEN
MATCH_MP_TAC COPRIME_MUL THEN REWRITE_TAC[] THEN
MP_TAC(SPECL [`u:num`; `2`] PRIME_COPRIME) THEN REWRITE_TAC[PRIME_2] THEN
MATCH_MP_TAC(TAUT `~b /\ (a ==> d) /\ (c ==> d)
==> a \/ b \/ c ==> d`) THEN
REPEAT CONJ_TAC THENL
[UNDISCH_TAC `ODD u` THEN
ONCE_REWRITE_TAC[TAUT `a ==> b <=> ~b ==> ~a`] THEN
SIMP_TAC[divides; LEFT_IMP_EXISTS_THM; ODD_MULT; ARITH_ODD];
ONCE_REWRITE_TAC[COPRIME_SYM] THEN SIMP_TAC[COPRIME_1];
REWRITE_TAC[COPRIME_SYM]];
MP_TAC(SPECL [`a:num`; `m:num`] XY_COPRIME) THEN ASM_REWRITE_TAC[] THEN
SUBST1_TAC(SYM(ASSUME `y EXP 2 * r = v`)) THEN
REWRITE_TAC[coprime; EXP_2] THEN
MESON_TAC[DIVIDES_RMUL; DIVIDES_LMUL]]; ALL_TAC] THEN
DISCH_THEN(X_CHOOSE_THEN `b:num` (X_CHOOSE_THEN `p:num`
(X_CHOOSE_THEN `q:num` (STRIP_ASSUME_TAC o GSYM)))) THEN
MAP_EVERY EXISTS_TAC [`b:num`; `p:num`; `q:num`] THEN
ONCE_REWRITE_TAC[ARITH_RULE `1 + 4 * p * y = 1 + p * 4 * y`] THEN
ASM_REWRITE_TAC[] THEN
ABBREV_TAC `s = X b k` THEN ABBREV_TAC `t = Y b k` THEN
EXISTS_TAC `s:num` THEN EXISTS_TAC `t:num` THEN
SUBST1_TAC(ARITH_RULE `r * y EXP 2 = y EXP 2 * r`) THEN
ASM_REWRITE_TAC[] THEN
SUBST1_TAC(SYM(ASSUME `X b k = s`)) THEN
SUBST1_TAC(SYM(ASSUME `Y b k = t`)) THEN
SUBGOAL_THEN `~(b = 0)` ASSUME_TAC THENL
[UNDISCH_THEN `1 + p * 4 * y = b` (SUBST1_TAC o SYM) THEN
ONCE_REWRITE_TAC[TAUT `~b ==> a ==> b ==> ~a`] THEN
REWRITE_TAC[ADD_EQ_0; ARITH_EQ]; ALL_TAC] THEN
SIMP_TAC[XY_ARE_SOLUTIONS; ASSUME `~(b = 0)`] THEN
MP_TAC(SPECL [`a:num`; `q:num`; `u:num`; `k:num`] X_CONGRUENT) THEN
ASM_REWRITE_TAC[] THEN
DISCH_THEN(X_CHOOSE_THEN `c:num` (ASSUME_TAC o SYM)) THEN
EXISTS_TAC `c:num` THEN ASM_REWRITE_TAC[] THEN
MP_TAC(SPECL [`b:num`; `k:num`] Y_N_MODA1) THEN
SUBST1_TAC(SYM(ASSUME `1 + p * 4 * y = b`)) THEN
REWRITE_TAC[ADD_EQ_0; ADD_SUB2; ARITH_EQ] THEN ASM_REWRITE_TAC[] THEN
DISCH_THEN(X_CHOOSE_THEN `q8:num` SUBST1_TAC) THEN
EXISTS_TAC `q8 * p:num` THEN REWRITE_TAC[MULT_AC; ADD_AC] THEN
MP_TAC(SPECL [`a:num`; `k:num`] Y_N_MODA1) THEN
ASM_SIMP_TAC[LEFT_IMP_EXISTS_THM] THEN
REWRITE_TAC[ONCE_REWRITE_RULE[ADD_SYM] LE_ADD]);;
(* ------------------------------------------------------------------------- *)
(* A ratio approaches a^n for large enough k. *)
(* ------------------------------------------------------------------------- *)
let BINOMIALISH_LEMMA = prove
(`!m n. m EXP n * (m - n) <= m * (m - 1) EXP n`,
GEN_TAC THEN INDUCT_TAC THEN
REWRITE_TAC[EXP; SUB_0; MULT_CLAUSES; LE_REFL] THEN
MATCH_MP_TAC LE_TRANS THEN
EXISTS_TAC `(m - 1) * m EXP n * (m - n)` THEN CONJ_TAC THENL
[REWRITE_TAC[GSYM MULT_ASSOC] THEN
ONCE_REWRITE_TAC[AC MULT_AC `a * b * c = b * a * c:num`] THEN
REWRITE_TAC[LE_MULT_LCANCEL] THEN DISJ2_TAC THEN
REWRITE_TAC[LEFT_SUB_DISTRIB; RIGHT_SUB_DISTRIB; MULT_CLAUSES] THEN
ONCE_REWRITE_TAC[ARITH_RULE `a - (b + c) = a - c - b:num`] THEN
MATCH_MP_TAC(ARITH_RULE `c <= b ==> a - b <= a - c:num`) THEN ARITH_TAC;
GEN_REWRITE_TAC RAND_CONV
[AC MULT_AC `m * (m - 1) * n = (m - 1) * m * n`] THEN
ASM_REWRITE_TAC[LE_MULT_LCANCEL]]);;
let XY_EXP_LEMMA = prove
(`!a k n.
~(a = 0) /\
2 * n * a EXP n < k
==> abs(&(Y (a * k) (n + 1)) / &(Y k (n + 1)) - &a pow n) < &1 / &2`,
REPEAT STRIP_TAC THEN
SUBGOAL_THEN `~(k = 0)` ASSUME_TAC THENL
[FIRST_ASSUM(ACCEPT_TAC o MATCH_MP (ARITH_RULE
`a < k ==> ~(k = 0)`)); ALL_TAC] THEN
SUBGOAL_THEN `0 < Y k (n + 1)` ASSUME_TAC THENL
[SUBST1_TAC(SYM(SPEC `k:num` (CONJUNCT1 Y_CLAUSES))) THEN
ASM_SIMP_TAC[Y_INCREASES_LT; ARITH_RULE `0 < n + 1`];
ALL_TAC] THEN
MATCH_MP_TAC REAL_LT_LCANCEL_IMP THEN
EXISTS_TAC `abs(&(Y k (n + 1)))` THEN
REWRITE_TAC[GSYM REAL_ABS_MUL; REAL_SUB_LDISTRIB] THEN
ASM_SIMP_TAC[REAL_ABS_NUM; REAL_LT_IMP_NZ;
REAL_OF_NUM_LT; REAL_DIV_LMUL] THEN
REWRITE_TAC[real_div; REAL_MUL_LID; REAL_MUL_ASSOC] THEN
SIMP_TAC[GSYM real_div; REAL_OF_NUM_LT; ARITH; REAL_LT_RDIV_EQ] THEN
MATCH_MP_TAC(REAL_ARITH
`!lx ly ux uy.
lx <= x /\ x <= ux /\ ly <= y /\ y <= uy /\
&2 * uy < &2 * lx + d /\ &2 * ux < &2 * ly + d
==> abs(x - y) * &2 < d`) THEN
MAP_EVERY EXISTS_TAC
[`&((2 * a * k - 1) EXP n)`; `&((2 * k - 1) EXP n) * &a pow n`;
`&((2 * a * k) EXP n)`; `&((2 * k) EXP n) * &a pow n`] THEN
ASM_SIMP_TAC[REAL_OF_NUM_LE; Y_LOWERBOUND; Y_UPPERBOUND;
REAL_LE_RMUL_EQ; REAL_POW_LT; REAL_OF_NUM_LT;
ARITH_RULE `~(a = 0) ==> 0 < a`] THEN
REWRITE_TAC[REAL_OF_NUM_ADD; REAL_OF_NUM_POW; REAL_OF_NUM_MUL] THEN
REWRITE_TAC[REAL_OF_NUM_LT] THEN
MATCH_MP_TAC(ARITH_RULE
`!x:num. x <= c /\ a < b + x /\ d < e + x ==> a < b + c /\ d < e + c`) THEN
EXISTS_TAC `(2 * k - 1) EXP n` THEN REWRITE_TAC[Y_LOWERBOUND] THEN
REWRITE_TAC[GSYM MULT_EXP; GSYM MULT_ASSOC] THEN
REWRITE_TAC[RIGHT_SUB_DISTRIB; GSYM MULT_ASSOC] THEN
SUBST1_TAC(AC MULT_AC `2 * k * a = 2 * a * k`) THEN
REWRITE_TAC[MULT_CLAUSES] THEN
MATCH_MP_TAC(ARITH_RULE
`b' <= b /\ a < b' + c ==> a < b + c /\ a < b' + c:num`) THEN
CONJ_TAC THENL
[REWRITE_TAC[LE_MULT_LCANCEL] THEN DISJ2_TAC THEN
SPEC_TAC(`n:num`,`m:num`) THEN
INDUCT_TAC THEN REWRITE_TAC[CONJUNCT1 EXP; LE_REFL] THEN
REWRITE_TAC[EXP_MONO_LE_SUC] THEN UNDISCH_TAC `~(a = 0)` THEN ARITH_TAC;
ALL_TAC] THEN
SUBST1_TAC(AC MULT_AC `2 * a * k = 2 * k * a`) THEN
GEN_REWRITE_TAC (RAND_CONV o LAND_CONV o RAND_CONV o LAND_CONV o RAND_CONV)
[ARITH_RULE `a = 1 * a`] THEN
REWRITE_TAC[MULT_ASSOC; GSYM RIGHT_SUB_DISTRIB] THEN
REWRITE_TAC[MULT_EXP] THEN
REWRITE_TAC[ARITH_RULE `2 * e * a + e = (2 * a + 1) * e`] THEN
REWRITE_TAC[GSYM MULT_EXP; GSYM MULT_ASSOC] THEN
SUBST1_TAC(AC MULT_AC `2 * k * a = a * 2 * k`) THEN
ONCE_REWRITE_TAC[MULT_EXP] THEN REWRITE_TAC[MULT_ASSOC] THEN
SUBGOAL_THEN `(2 * k) * (2 * a EXP n) * (2 * k) EXP n <
(2 * k) * (2 * a EXP n + 1) * (2 * k - 1) EXP n`
MP_TAC THENL
[ALL_TAC; ASM_SIMP_TAC[LT_MULT_LCANCEL; MULT_EQ_0; ARITH_EQ]] THEN
GEN_REWRITE_TAC RAND_CONV
[AC MULT_AC `(2 * k) * l * m = l * (2 * k) * m`] THEN
MATCH_MP_TAC LTE_TRANS THEN
EXISTS_TAC `(2 * a EXP n + 1) * (2 * k) EXP n * (2 * k - n)` THEN
CONJ_TAC THENL
[ALL_TAC; REWRITE_TAC[LE_MULT_LCANCEL; BINOMIALISH_LEMMA]] THEN
REWRITE_TAC[ARITH_RULE
`(2 * k) * (2 * an) * 2kn < a2na * 2kn * kmn <=>
2kn * 4 * k * an < 2kn * a2na * kmn`] THEN
ASM_SIMP_TAC[LT_MULT_LCANCEL; EXP_EQ_0; MULT_EQ_0; ARITH_EQ] THEN
REWRITE_TAC[LEFT_SUB_DISTRIB] THEN
MATCH_MP_TAC(ARITH_RULE `a + b < c ==> a < c - b:num`) THEN
REWRITE_TAC[LEFT_ADD_DISTRIB; RIGHT_ADD_DISTRIB; MULT_CLAUSES] THEN
REWRITE_TAC[GSYM MULT_ASSOC] THEN
REWRITE_TAC[ARITH_RULE `4 * k * an + x < 2 * an * 2 * k + y <=> x < y`] THEN
ONCE_REWRITE_TAC[AC MULT_AC `2 * a * n = 2 * n * a`] THEN
UNDISCH_TAC `2 * n * a EXP n < k` THEN
MATCH_MP_TAC(ARITH_RULE
`n * 1 <= x ==> 2 * x < k ==> 2 * x + n < 2 * k`) THEN
ASM_REWRITE_TAC[LE_MULT_LCANCEL; ARITH_RULE `1 <= n <=> ~(n = 0)`] THEN
ASM_REWRITE_TAC[EXP_EQ_0]);;
let ABS_LT_REPRESENTATION = prove
(`!x y z.
~(y = 0)
==> (abs(&x / &y - &z) < &1 / &2 <=>
4 * x EXP 2 + 4 * (y * z) EXP 2 < 8 * x * y * z + y EXP 2)`,
REPEAT STRIP_TAC THEN MATCH_MP_TAC EQ_TRANS THEN
EXISTS_TAC `&4 * (&x / &y - &z) pow 2 < &1` THEN CONJ_TAC THENL
[SIMP_TAC[REAL_LT_RDIV_EQ; REAL_OF_NUM_LT; ARITH] THEN
SUBST1_TAC(SYM(REAL_RAT_REDUCE_CONV `&2 * &2`)) THEN
REWRITE_TAC[GSYM REAL_POW_2; GSYM REAL_POW_MUL] THEN
ONCE_REWRITE_TAC[GSYM REAL_POW2_ABS] THEN
REWRITE_TAC[REAL_ABS_MUL; REAL_ABS_NUM] THEN EQ_TAC THENL
[GEN_REWRITE_TAC (RAND_CONV o RAND_CONV)
[SYM(REAL_RAT_REDUCE_CONV `&1 pow 2`)] THEN
GEN_REWRITE_TAC (LAND_CONV o LAND_CONV) [REAL_MUL_SYM] THEN
SIMP_TAC[ARITH_EQ; REAL_POW_LT2; REAL_LE_MUL; REAL_POS; REAL_ABS_POS];
ONCE_REWRITE_TAC[TAUT `a ==> b <=> ~b ==> ~a`] THEN
REWRITE_TAC[REAL_NOT_LT] THEN
GEN_REWRITE_TAC (RAND_CONV o LAND_CONV)
[SYM(REAL_RAT_REDUCE_CONV `&1 pow 2`)] THEN
GEN_REWRITE_TAC (LAND_CONV o RAND_CONV) [REAL_MUL_SYM] THEN
SIMP_TAC[ARITH_EQ; REAL_POW_LE2; REAL_LE_MUL; REAL_POS; REAL_ABS_POS]];
ALL_TAC] THEN
MATCH_MP_TAC EQ_TRANS THEN
EXISTS_TAC `&4 * (&x - &y * &z) pow 2 < &y pow 2` THEN CONJ_TAC THENL
[GEN_REWRITE_TAC (RAND_CONV o RAND_CONV) [GSYM REAL_POW2_ABS] THEN
REWRITE_TAC[GSYM REAL_ABS_POW] THEN
GEN_REWRITE_TAC (RAND_CONV o RAND_CONV) [GSYM REAL_MUL_LID] THEN
ASM_SIMP_TAC[GSYM REAL_LT_LDIV_EQ; GSYM REAL_ABS_NZ; REAL_POW_EQ_0;
ARITH_EQ; REAL_OF_NUM_EQ] THEN
REWRITE_TAC[REAL_ABS_POW; REAL_POW2_ABS] THEN
REWRITE_TAC[real_div; GSYM REAL_MUL_ASSOC] THEN
REWRITE_TAC[GSYM real_div; GSYM REAL_POW_DIV] THEN
AP_THM_TAC THEN AP_TERM_TAC THEN AP_TERM_TAC THEN
AP_THM_TAC THEN AP_TERM_TAC THEN
REWRITE_TAC[real_div; REAL_SUB_RDISTRIB; GSYM REAL_MUL_ASSOC] THEN
AP_TERM_TAC THEN
ASM_SIMP_TAC[GSYM real_div; REAL_DIV_LMUL; REAL_OF_NUM_EQ]; ALL_TAC] THEN
REWRITE_TAC[GSYM REAL_OF_NUM_LT; GSYM REAL_OF_NUM_ADD;
GSYM REAL_OF_NUM_MUL; GSYM REAL_OF_NUM_POW] THEN
REWRITE_TAC[REAL_POW_2] THEN REAL_ARITH_TAC);;
let Y_EQ_0 = prove
(`!a n. ~(a = 0) ==> ((Y a n = 0) <=> (n = 0))`,
REPEAT STRIP_TAC THEN
SUBST1_TAC(SYM(SPEC `a:num` (CONJUNCT1 Y_CLAUSES))) THEN
ASM_SIMP_TAC[Y_INJ] THEN REWRITE_TAC[Y_CLAUSES]);;
let XY_EXP = prove
(`~(a = 0)
==> ((a EXP n = p) <=>
?k x y z. (Y (a * k) (n + 1) = x) /\
(Y k (n + 1) = y) /\
(Y a (n + 1) = z) /\
2 * n * z < k /\
4 * x EXP 2 + 4 * (y * p) EXP 2 < 8 * x * y * p + y EXP 2)`,
let lemma1 = prove
(`(?x y z. (a = x) /\ (b = y) /\ (c = z) /\ P x y z) <=> P a b c`,
MESON_TAC[])
and lemma2 =
CONV_RULE(RAND_CONV(ONCE_DEPTH_CONV SYM_CONV))
(SPEC_ALL ABS_LT_REPRESENTATION) in
REPEAT STRIP_TAC THEN REWRITE_TAC[lemma1] THEN
GEN_REWRITE_TAC (RAND_CONV o BINDER_CONV o LAND_CONV)
[ARITH_RULE `n < k <=> n < k /\ ~(k = 0)`] THEN
ONCE_REWRITE_TAC[TAUT `a /\ b <=> ~(a ==> ~b)`] THEN
ASM_SIMP_TAC[lemma2; Y_EQ_0; ADD_EQ_0; ARITH_EQ] THEN
REWRITE_TAC[NOT_IMP] THEN
REWRITE_TAC[ARITH_RULE `n < k /\ ~(k = 0) <=> n < k`] THEN
EQ_TAC THENL
[DISCH_THEN(SUBST1_TAC o SYM) THEN
EXISTS_TAC `2 * n * Y a (n + 1) + 1` THEN
REWRITE_TAC[ARITH_RULE `c < c + 1`; GSYM REAL_OF_NUM_POW] THEN
MATCH_MP_TAC XY_EXP_LEMMA THEN ASM_REWRITE_TAC[] THEN
MATCH_MP_TAC(ARITH_RULE `a <= b ==> 2 * a < 2 * b + 1`) THEN
REWRITE_TAC[LE_MULT_LCANCEL] THEN DISJ2_TAC THEN
MATCH_MP_TAC LE_TRANS THEN EXISTS_TAC `(2 * a - 1) EXP n` THEN
REWRITE_TAC[Y_LOWERBOUND] THEN
SPEC_TAC(`n:num`,`n:num`) THEN INDUCT_TAC THEN
REWRITE_TAC[CONJUNCT1 EXP; LE_REFL; EXP_MONO_LE_SUC] THEN
UNDISCH_TAC `~(a = 0)` THEN ARITH_TAC; ALL_TAC] THEN
DISCH_THEN(X_CHOOSE_THEN `k:num` (CONJUNCTS_THEN2 ASSUME_TAC MP_TAC)) THEN
MP_TAC(SPECL [`a:num`; `k:num`; `n:num`] XY_EXP_LEMMA) THEN
ANTS_TAC THENL
[ASM_REWRITE_TAC[] THEN
FIRST_X_ASSUM(MATCH_MP_TAC o MATCH_MP (ARITH_RULE
`2 * a < k ==> b <= a ==> 2 * b < k`)) THEN
REWRITE_TAC[LE_MULT_LCANCEL] THEN DISJ2_TAC THEN
MATCH_MP_TAC LE_TRANS THEN EXISTS_TAC `(2 * a - 1) EXP n` THEN
REWRITE_TAC[Y_LOWERBOUND] THEN
SPEC_TAC(`n:num`,`n:num`) THEN INDUCT_TAC THEN
REWRITE_TAC[CONJUNCT1 EXP; LE_REFL; EXP_MONO_LE_SUC] THEN
UNDISCH_TAC `~(a = 0)` THEN ARITH_TAC; ALL_TAC] THEN
REWRITE_TAC[IMP_IMP] THEN
DISCH_THEN(MP_TAC o MATCH_MP (REAL_ARITH
`abs(x - a) < e1 /\ abs(x - b) < e2 ==> abs(a - b) < e1 + e2`)) THEN
CONV_TAC REAL_RAT_REDUCE_CONV THEN
DISCH_THEN(MP_TAC o MATCH_MP (REAL_ARITH
`abs(a - b) < &1
==> a + &1 <= b \/ (a = b) \/ b + &1 <= a ==> (a = b)`)) THEN
REWRITE_TAC[REAL_OF_NUM_POW; REAL_OF_NUM_ADD;
REAL_OF_NUM_EQ; REAL_OF_NUM_LE] THEN
DISCH_THEN MATCH_MP_TAC THEN ARITH_TAC);;
(* ------------------------------------------------------------------------- *)
(* Lemmas. *)
(* ------------------------------------------------------------------------- *)
let REAL_SUM_OF_SQUARES = prove
(`(x pow 2 + y pow 2 = &0) <=> (x = &0) /\ (y = &0)`,
REWRITE_TAC[REAL_POW_2] THEN EQ_TAC THEN
SIMP_TAC[REAL_MUL_LZERO; REAL_ADD_LID] THEN
DISCH_THEN(MP_TAC o MATCH_MP (REAL_ARITH
`(a + b = &0) ==> &0 <= a /\ &0 <= b ==> (a = &0) /\ (b = &0)`)) THEN
REWRITE_TAC[REAL_LE_SQUARE; REAL_ENTIRE]);;
(* ------------------------------------------------------------------------- *)
(* Combining theorems for conjunction and disjunction. *)
(* ------------------------------------------------------------------------- *)
let DIOPH_CONJ = prove
(`(x1 = x2) /\ (y1 = y2) <=>
(x1 * x1 + x2 * x2 + y1 * y1 + y2 * y2 = 2 * x1 * x2 + 2 * y1 * y2)`,
REWRITE_TAC[GSYM REAL_OF_NUM_EQ;
GSYM REAL_OF_NUM_ADD; GSYM REAL_OF_NUM_MUL] THEN
ONCE_REWRITE_TAC[GSYM REAL_SUB_0] THEN
REWRITE_TAC[GSYM REAL_SUM_OF_SQUARES] THEN
REWRITE_TAC[REAL_POW_2] THEN REAL_ARITH_TAC);;
let DIOPH_DISJ = prove
(`(x1 = x2) \/ (y1 = y2) <=>
(x1 * y1 + x2 * y2 = x1 * y2 + x2 * y1)`,
REWRITE_TAC[GSYM REAL_OF_NUM_EQ;
GSYM REAL_OF_NUM_ADD; GSYM REAL_OF_NUM_MUL] THEN
ONCE_REWRITE_TAC[GSYM REAL_SUB_0] THEN
REWRITE_TAC[GSYM REAL_ENTIRE] THEN REAL_ARITH_TAC);;
(* ------------------------------------------------------------------------- *)
(* Inequalities. *)
(* ------------------------------------------------------------------------- *)
let DIOPH_LE = prove
(`x <= y <=> ?d:num. x + d = y`,
REWRITE_TAC[LE_EXISTS] THEN
AP_TERM_TAC THEN ABS_TAC THEN
REWRITE_TAC[ADD_AC; EQ_SYM_EQ]);;
let DIOPH_LT = prove
(`x < y <=> ?d. x + d + 1 = y`,
REWRITE_TAC[LT_EXISTS] THEN
REWRITE_TAC[ADD1] THEN
AP_TERM_TAC THEN ABS_TAC THEN
REWRITE_TAC[ADD_AC; EQ_SYM_EQ]);;
let DIOPH_NE = prove
(`~(x = y) <=> x < y \/ y < x:num`,
ARITH_TAC);;
(* ------------------------------------------------------------------------- *)
(* Exponentiation (from the Pell stuff). *)
(* ------------------------------------------------------------------------- *)
let Y_0 = prove
(`!k. Y 0 k = if k = 1 then 1 else 0`,
INDUCT_TAC THEN REWRITE_TAC[Y_CLAUSES; ARITH_EQ] THEN
SPEC_TAC(`k:num`,`k:num`) THEN
INDUCT_TAC THEN REWRITE_TAC[Y_CLAUSES; ARITH] THEN
REWRITE_TAC[ARITH_RULE `SUC(SUC n) = n + 2`; Y_CLAUSES; ARITH] THEN
REWRITE_TAC[MULT_CLAUSES; SUB_0; ARITH_RULE `~(k + 2 = 1)`]);;
let Y_0_TRIV = prove
(`!k. (Y 0 k = 0) <=> ~(k = 1)`,
GEN_TAC THEN REWRITE_TAC[Y_0] THEN
COND_CASES_TAC THEN ASM_REWRITE_TAC[ARITH_EQ]);;
let DIOPH_Y = prove
(`(Y a k = y) <=>
(a = 0) /\ (k = 1) /\ (y = 1) \/
(a = 0) /\ ~(k = 1) /\ (y = 0) \/
(k = 0) /\ (y = 0) \/
(a = 1) /\ (y = k) \/
~(a = 0) /\ ~(k = 0) /\ ~(a = 1) /\ ~(y = 0) /\
?x u v r b p q s t c d.
0 < r /\
(x EXP 2 = (a EXP 2 - 1) * y EXP 2 + 1) /\
(u EXP 2 = (a EXP 2 - 1) * v EXP 2 + 1) /\
(s EXP 2 = (b EXP 2 - 1) * t EXP 2 + 1) /\
(v = r * y EXP 2) /\
(b = 1 + 4 * p * y) /\
(b = a + q * u) /\
(s = x + c * u) /\
(t = k + 4 * d * y) /\
k <= y`,
ASM_CASES_TAC `a = 0` THENL
[ASM_CASES_TAC `y = 0` THENL
[ASM_REWRITE_TAC[Y_0_TRIV; ARITH_EQ] THEN ARITH_TAC; ALL_TAC] THEN
ASM_CASES_TAC `k = 0` THEN ASM_REWRITE_TAC[Y_CLAUSES; ARITH_EQ] THEN
ASM_REWRITE_TAC[ARITH_EQ] THEN CONV_TAC NUM_REDUCE_CONV THEN
REWRITE_TAC[MULT_CLAUSES; ADD_CLAUSES] THEN
REWRITE_TAC[EXP_2; MULT_EQ_1] THEN
REWRITE_TAC[Y_0] THEN COND_CASES_TAC THEN ASM_REWRITE_TAC[] THEN
REWRITE_TAC[EQ_SYM_EQ]; ALL_TAC] THEN
ASM_REWRITE_TAC[ARITH_EQ] THEN
ASM_CASES_TAC `k = 0` THEN ASM_REWRITE_TAC[Y_CLAUSES] THENL
[REWRITE_TAC[EQ_SYM_EQ] THEN CONV_TAC(EQT_INTRO o TAUT); ALL_TAC] THEN
ASM_CASES_TAC `a = 1` THEN ASM_REWRITE_TAC[Y_DEGENERATE] THENL
[REWRITE_TAC[EQ_SYM_EQ]; ALL_TAC] THEN
ASM_CASES_TAC `y = 0` THEN ASM_SIMP_TAC[Y_EQ_0] THEN
GEN_REWRITE_TAC LAND_CONV [EQ_SYM_EQ] THEN ASM_SIMP_TAC[Y_DIOPH]);;
let DIOPH_EXP_LEMMA = prove
(`(m EXP n = p) <=>
(m = 0) /\ (n = 0) /\ (p = 1) \/
(m = 0) /\ ~(n = 0) /\ (p = 0) \/
~(m = 0) /\
?k x y z. (Y (m * k) (n + 1) = x) /\
(Y k (n + 1) = y) /\
(Y m (n + 1) = z) /\
2 * n * z < k /\
4 * x EXP 2 + 4 * (y * p) EXP 2 < 8 * x * y * p + y EXP 2`,
ASM_CASES_TAC `m = 0` THEN ASM_REWRITE_TAC[ARITH_EQ] THENL
[SPEC_TAC(`n:num`,`n:num`) THEN INDUCT_TAC THEN
REWRITE_TAC[EXP; MULT_CLAUSES; ADD_CLAUSES; NOT_SUC] THEN
REWRITE_TAC[EQ_SYM_EQ]; ALL_TAC] THEN
ASM_SIMP_TAC[XY_EXP]);;
let DIOPH_EXP =
let th1 = REWRITE_RULE[DIOPH_Y] DIOPH_EXP_LEMMA in
let th2 = REWRITE_RULE[EXP_2] th1 in
let th3 = REWRITE_RULE[DIOPH_NE; DIOPH_LT; DIOPH_LE] th2 in
let th4 = REWRITE_RULE[ADD_CLAUSES; ARITH_EQ; ADD_EQ_0;
ARITH_RULE `(n + 1 = 1) = (n = 0)`; ADD_ASSOC;
EQ_ADD_RCANCEL] th3 in
let th5 = REWRITE_RULE[GSYM ADD_ASSOC] th4 in
REWRITE_RULE
[OR_EXISTS_THM; LEFT_OR_EXISTS_THM; RIGHT_OR_EXISTS_THM;
LEFT_AND_EXISTS_THM; RIGHT_AND_EXISTS_THM] th5;;
(****** This takes about an hour to compute, and longer to print out!
let DIOPH_EXP_ONE_EQUATION =
REWRITE_RULE[DIOPH_CONJ; DIOPH_DISJ] DIOPH_EXP;;
*******)
|
