1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
|
(* An LL(1) grammar for function spec files in RDP syntax, see
http://www.cs.rhbnc.ac.uk/research/languages/projects/rdp.shtml *)
spec ::= [ requiredProperties ] { validProperty } { category }.
requiredProperties ::= ':required-props' { propertyName } ';'.
validProperty ::= ':' validPropertyName validPropertyValues ';'.
validPropertyName ::= 'param' | propertyName.
validPropertyValues ::= [ '*' | propertyValue { propertyValue } ] .
category ::= functionDeclaration
| newCategory { functionDeclaration } endCategory.
newCategory ::= ':newcategory' categoryName ';'.
endCategory ::= ':endcategory' ';'.
functionDeclaration ::= functionName parameters returnType [ ',' paramsAndProps ] ';' .
parameters ::= '(' [ parameterName { ',' parameterName } ] ')'.
returnType ::= 'return' typeName.
paramsAndProps ::= parameterDeclaration [ ',' paramsAndProps ]
| [ functionProperty { ',' functionProperty } ].
parameterDeclaration ::= 'param' parameterName parameterType [ lengthDescriptor ] { propertyValue }.
parameterType ::= typeName direction transferType.
direction ::= 'in' | 'out' | 'in/out'.
transferType ::= 'array' | 'reference' | 'value'.
lengthDescriptor ::= '[' indexExpression { ',' indexExpression } ']'.
indexExpression ::= term { addOp term }.
addOp ::= '+' | '-'.
term ::= factor { mulOp factor }.
mulOp ::= '*' | '/'.
factor ::= compsize | '(' indexExpression ')' | integer | parameterName.
compsize ::= 'COMPSIZE' '(' [ parameterName { '/' parameterName } ] ')'.
integer ::= digit { digit }.
functionProperty ::= propertyName { metaPropertyValue }.
metaPropertyValue ::= [ '!' ] ( 'all' | propertyValue ).
propertyValue ::= word.
propertyName ::= word.
categoryName ::= word.
functionName ::= word.
typeName ::= word.
parameterName ::= word.
(* Not totally correct, but with RDP one can't specify a lexer. We really mean:
A word is a non-empty sequence of characters which are not in the set
" \t\n\r\f\v\xa0()[]:,;+*/!". Integers are not words. *)
word ::= ( upper | lower ) wordChar.
wordChar ::= upper | lower | digit | special.
upper ::= 'A' | 'B' | 'C' | 'D' | 'E' | 'F' | 'G' | 'H' | 'I' | 'J'
| 'K' | 'L' | 'M' | 'N' | 'O' | 'P' | 'Q' | 'R' | 'S' | 'T'
| 'U' | 'V' | 'W' | 'X' | 'Y' | 'Z'.
lower ::= 'a' | 'b' | 'c' | 'd' | 'e' | 'f' | 'g' | 'h' | 'i' | 'j'
| 'k' | 'l' | 'm' | 'n' | 'o' | 'p' | 'q' | 'r' | 's' | 't'
| 'u' | 'v' | 'w' | 'x' | 'y' | 'z'.
digit ::= '0' | '1' | '2' | '3' | '4' | '5' | '6' | '7' | '8' | '9'.
special ::= '_' | '-' | '.'.
|
