1 2 3 4 5 6 7 8 9 10 11 12 13 14 15 16 17 18 19 20 21 22 23 24 25 26 27 28 29 30 31 32 33 34 35 36 37 38 39 40 41 42 43 44 45 46 47 48 49 50 51 52 53 54 55 56 57 58 59 60 61 62 63 64 65 66 67 68 69 70 71 72 73 74 75 76 77 78 79 80 81 82 83 84 85 86 87 88 89 90 91 92 93 94 95 96 97 98 99 100 101 102 103 104 105 106 107 108 109 110 111 112 113 114 115 116 117 118 119 120 121 122 123 124 125 126 127 128 129 130 131 132 133 134 135 136 137 138 139 140 141 142 143 144 145 146 147 148 149 150 151 152 153 154 155 156 157 158 159 160 161 162 163 164 165 166 167 168 169 170 171 172 173 174 175 176 177 178 179 180 181 182 183 184 185 186 187 188 189 190 191 192 193 194 195 196 197 198 199 200 201 202 203 204 205 206 207 208 209 210 211 212 213 214 215 216 217 218 219 220 221 222 223 224 225 226 227 228 229 230 231 232 233 234 235 236 237 238 239 240 241 242 243 244 245 246 247 248 249 250 251 252 253 254 255 256 257 258 259 260 261 262 263 264 265 266 267 268 269 270 271 272 273 274 275 276 277 278 279 280 281 282 283 284 285 286 287 288 289 290 291 292 293 294 295 296 297 298 299 300 301 302 303 304 305 306 307 308 309 310 311 312 313 314 315 316 317 318 319 320 321 322 323 324 325 326 327 328 329 330 331 332 333 334 335 336 337 338 339 340 341 342 343 344 345 346 347 348 349 350 351 352 353 354 355 356 357 358 359 360 361 362 363 364 365 366 367 368 369 370 371 372 373 374 375 376 377 378 379 380 381 382 383 384 385 386 387
|
dnl This file is part of the Zebra server.
dnl Copyright (C) Index Data. See LICENSE.zebra for details.
dnl
AC_PREREQ(2.60)
AC_INIT([idzebra],
m4_esyscmd([. ./IDMETA; echo $VERSION|tr -d '\n']),
[zebra-help@indexdata.dk])
AC_CONFIG_HEADERS([include/config.h])
AC_CONFIG_SRCDIR([configure.ac])
AC_CONFIG_AUX_DIR([config])
AM_INIT_AUTOMAKE([1.9])
PACKAGE_SUFFIX="-2.0"
AC_SUBST(PACKAGE_SUFFIX)
dnl http://www.gnu.org/software/libtool/manual.html#Versioning
ZEBRALIBS_VERSION_INFO=0:1:0
AC_SUBST([ZEBRALIBS_VERSION_INFO])
main_zebralib=index/libidzebra${PACKAGE_SUFFIX}.la
AC_SUBST(main_zebralib)
dnl ------ Substitutions
AC_SUBST([CRYPT_LIBS])
AC_SUBST([DL_LIBS])
AC_SUBST([BZIP2_LIBS])
AC_SUBST([ZLIB_LIBS])
AC_SUBST([TCL_INCLUDE])
AC_SUBST([TCL_LIB])
AC_SUBST([TCL_LIB_SPEC])
AC_SUBST([ZEBRA_CFLAGS])
dnl
dnl ------ Checking programs
AC_PROG_CC
AC_PROG_CPP
AM_PROG_LIBTOOL
dnl
dnl ------ headers
AC_CHECK_HEADERS([sys/resource.h sys/time.h sys/wait.h sys/utsname.h unistd.h])
dnl ------ crypt
old_LIBS="$LIBS"
AC_CHECK_LIB([crypt],[crypt])
if test "$ac_cv_lib_crypt_crypt" = "yes"; then
AC_CHECK_HEADERS([crypt.h])
fi
CRYPT_LIBS="$LIBS"
LIBS="$old_LIBS"
dnl
dnl ------ YAZ
YAZ_INIT([server icu],[3.0.47])
if test "$YAZVERSION" = "NONE"; then
AC_MSG_ERROR([YAZ development libraries required])
fi
YAZLALIB=-lyaz
YAZ_DOC
dnl ------ Look for Tcl
dnl See if user has specified location of tclConfig.sh; otherwise
dnl see if tclConfig.sh exists in same prefix lcoation as tclsh; otherwise
dnl disable Tcl.
TCL_LIB=""
TCL_INCLUDE=""
tclconfig=NONE
AC_ARG_WITH(tclconfig, [ --with-tclconfig=DIR tclConfig.sh in DIR], [tclconfig=$withval])
if test "x$tclconfig" = xNONE; then
saveprefix=${prefix}
AC_PREFIX_PROGRAM(tclsh)
tclconfig=${prefix}/lib
prefix=${saveprefix}
if test ! -r ${tclconfig}/tclConfig.sh; then
# Not found, try search for Tcl on Debian systems.
for d in /usr/lib/tcl*; do
if test -f $d/tclConfig.sh; then
tclconfig=$d
fi
done
fi
fi
AC_MSG_CHECKING(for Tcl)
if test -r ${tclconfig}/tclConfig.sh; then
. ${tclconfig}/tclConfig.sh
if test -r ${tclconfig}/../generic/tcl.h; then
TCL_INCLUDE=-I${tclconfig}/../generic
TCL_LIB="$TCL_BUILD_LIB_SPEC $TCL_LIBS"
elif test -d ${TCL_PREFIX}/include/tcl${TCL_VERSION}; then
TCL_INCLUDE=-I${TCL_PREFIX}/include/tcl${TCL_VERSION}
TCL_LIB="$TCL_LIB_SPEC $TCL_LIBS"
else
TCL_INCLUDE=-I${TCL_PREFIX}/include
TCL_LIB="$TCL_LIB_SPEC $TCL_LIBS"
fi
TCL_LIB=`echo $TCL_LIB|sed 's%-L/usr/lib%%g'`
SHLIB_CFLAGS=$TCL_SHLIB_CFLAGS
SHLIB_LD=$TCL_SHLIB_LD
SHLIB_SUFFIX=$TCL_SHLIB_SUFFIX
SHLIB_VERSION=$TCL_SHLIB_VERSION
AC_MSG_RESULT($TCL_VERSION)
old_CPPFLAGS=$CPPFLAGS
CPPFLAGS="${TCL_INCLUDE} $CPPFLAGS"
AC_CHECK_HEADERS(tcl.h)
CPPFLAGS=${old_CPPFLAGS}
# The Mac OSX -framework causes problems with Libtool
# and dependancy libs.. so apply Tcl libs everywhere bug #461
case $host in
*-*-darwin*)
LIBS="$LIBS $TCL_LIB";
;;
esac
else
AC_MSG_RESULT(Not found)
AC_DEFINE(HAVE_TCL_H,0)
fi
dnl
dnl ------ various functions
AC_CHECK_FUNCS(mkstemp atoll)
dnl
dnl ------ iconv
AC_ARG_WITH(iconv, [ --with-iconv[=DIR] iconv library in DIR])
if test "$with_iconv" != "no"; then
AC_MSG_CHECKING(for iconv)
oldLIBS="$LIBS"
oldCPPFLAGS="${CPPFLAGS}"
if test "$with_iconv" != "yes" -a "$with_iconv" != ""; then
LIBS="$LIBS -L${with_iconv}/lib"
CPPFLAGS="${CPPFLAGS} -I${with_iconv}/include"
fi
AC_TRY_LINK([
#include <iconv.h>
],[
iconv_t t = iconv_open("", "");
],[
AC_DEFINE([HAVE_ICONV_H],[1],[Whether iconv.h is defined])
AC_MSG_RESULT(yes)
],[
LIBS="$LIBS -liconv"
AC_TRY_LINK([
#include <iconv.h>
],[
iconv_t t = iconv_open("", "");
],[
AC_DEFINE([HAVE_ICONV_H],[1])
AC_MSG_RESULT(yes)
],[
LIBS="$oldLIBS"
CPPFLAGS="$oldCPPFLAGS"
AC_MSG_RESULT(no)
])
])
fi
dnl
dnl ------- BZIP2
old_LIBS="$LIBS"
AC_CHECK_LIB(bz2,bzCompressInit)
if test "$ac_cv_lib_bz2_bzCompressInit" = "yes"; then
AC_CHECK_HEADERS(bzlib.h)
else
AC_CHECK_LIB(bz2,BZ2_bzCompressInit)
if test "$ac_cv_lib_bz2_BZ2_bzCompressInit" = "yes"; then
AC_CHECK_HEADERS(bzlib.h)
fi
fi
BZIP2_LIBS="$LIBS"
LIBS="$old_LIBS"
dnl
dnl ------- zlib
old_LIBS="$LIBS"
AC_CHECK_LIB([z],[compress2])
if test "$ac_cv_lib_z_compress2" = "yes"; then
AC_CHECK_HEADERS([zlib.h])
fi
ZLIB_LIBS="$LIBS"
LIBS="$old_LIBS"
dnl ------ -ldl
old_LIBS="$LIBS"
AC_CHECK_LIB([dl], [dlopen])
DL_LIBS="$LIBS"
LIBS="$old_LIBS"
dnl
dnl ------ EXPAT
expat=yes
AC_SUBST([EXPAT_LIBS])
AC_ARG_WITH(expat, [ --with-expat[=DIR] EXPAT library in DIR],[expat=$withval])
if test "$expat" != "no"; then
xLIBS="$LIBS";
xCFLAGS="$CFLAGS";
if test "$expat" != "yes"; then
EXPAT_CFLAGS="-I$expat/include"
EXPAT_LIBS="-L$expat/lib"
CFLAGS="$EXPAT_CFLAGS $CFLAGS"
LIBS="$EXPAT_LIBS $LIBS"
fi
AC_CHECK_LIB(expat,XML_ParserCreate,[EXPAT_LIBS="$EXPAT_LIBS -lexpat"])
if test "$ac_cv_lib_expat_XML_ParserCreate" = "yes"; then
AC_CHECK_HEADERS(expat.h)
fi
LIBS="$xLIBS"
CFLAGS="$xCFLAGS"
fi
dnl
dnl ------- 64 bit files
AC_SYS_LARGEFILE
AC_CHECK_TYPES([long long])
if test "${ac_cv_type_long_long}" = "yes"; then
ZINT_VALUE=1
else
ZINT_VALUE=0
fi
ZEBRA_CFLAGS="-DZEBRA_ZINT=${ZINT_VALUE}"
AC_DEFINE_UNQUOTED([ZEBRA_ZINT],${ZINT_VALUE},[Whehter zint is long long])
dnl ------ Modules
AC_SUBST([SHARED_MODULE_LA])
SHARED_MODULE_LA=""
AC_SUBST([STATIC_MODULE_OBJ])
STATIC_MODULE_OBJ=""
AC_SUBST([STATIC_MODULE_LADD])
STATIC_MODULE_LADD=""
AC_DEFUN([ZEBRA_MODULE],[
AC_ARG_ENABLE(mod-$1,[$3],[myen=$enableval],[myen=$2])
AC_MSG_CHECKING([for module $1])
if test "$myen" = "yes"; then
myen="shared"
fi
if test "$enable_shared" != "yes"; then
if test "$myen" = "shared"; then
myen="static"
fi
fi
m=`echo $1|tr .- __`
if test "$myen" = "no" -o "$myen" = "disabled"; then
AC_MSG_RESULT([disabled])
elif test "$2" = "disabled"; then
AC_MSG_RESULT([disabled])
AC_MSG_ERROR([Cannot enable mod-$1 because of missing libs (XML, etc)])
elif test "$myen" = "shared"; then
AC_MSG_RESULT([shared])
SHARED_MODULE_LA="${SHARED_MODULE_LA} mod-$1.la"
elif test "$myen" = "static"; then
AC_MSG_RESULT([static])
STATIC_MODULE_OBJ="${STATIC_MODULE_OBJ} \$(mod_${m}_la_OBJECTS)"
STATIC_MODULE_LADD="${STATIC_MODULE_LADD} \$(mod_${m}_la_LADD)"
modcpp=`echo $1|tr abcdefghijklmnopqrstuvwxyz- ABCDEFGHIJKLMNOPQRSTUVWXYZ_`
AC_DEFINE_UNQUOTED([IDZEBRA_STATIC_$modcpp])
else
AC_MSG_RESULT([$myen])
AC_MSG_ERROR([invalid --enable-mod-$1 value. Use on,off,static or shared])
fi
])
AC_DEFINE([IDZEBRA_STATIC_GRS_SGML],[1],[Whether module grs.sgml is static])
AC_DEFINE([IDZEBRA_STATIC_TEXT],[0],[Whether module text is static])
ZEBRA_MODULE(text,shared, [ --enable-mod-text Text filter])
AC_DEFINE([IDZEBRA_STATIC_GRS_REGX],[0],[Whether module grs.regx is static])
ZEBRA_MODULE(grs-regx,shared,[ --enable-mod-grs-regx REGX/TCL filter])
AC_DEFINE([IDZEBRA_STATIC_GRS_MARC],[0],[Whether module grs.marc is static])
ZEBRA_MODULE(grs-marc,shared,[ --enable-mod-grs-marc MARC filter])
if test "$ac_cv_header_expat_h" = "yes"; then
def="shared"
else
def="disabled"
fi
AC_DEFINE([IDZEBRA_STATIC_GRS_XML],[0],[Whether module grs.xml is static])
ZEBRA_MODULE(grs-xml,[$def], [ --enable-mod-grs-xml XML filter (Expat based)])
oldCPPFLAGS="$CPPFLAGS"
CPPFLAGS="$CPPFLAGS $YAZINC"
AC_PREPROC_IFELSE(
[AC_LANG_PROGRAM([[
#if YAZ_HAVE_XML2
#include <libxml/xmlversion.h>
#include <libxml/parser.h>
#include <libxml/tree.h>
#include <libxml/xmlIO.h>
#include <libxslt/transform.h>
#include <libxslt/xsltutils.h>
#else
#error Libxml2 not available
#endif
]],[[
#if LIBXML_VERSION < 20615
#error Libxml2 version < 2.6.15. xmlreader not reliable/present
#endif
]])],
[def="shared"],
[def="disabled"])
CPPFLAGS=$oldCPPFLAGS
AC_DEFINE([IDZEBRA_STATIC_DOM],[0],[Whether module dom is static])
ZEBRA_MODULE(dom,[$def], [ --enable-mod-dom XML/XSLT filter (Requires libxslt)])
AC_DEFINE([IDZEBRA_STATIC_ALVIS],[0],[Whether module alvis is static])
ZEBRA_MODULE(alvis,[$def], [ --enable-mod-alvis ALVIS filter (Requires libxslt)])
AC_DEFINE([IDZEBRA_STATIC_SAFARI],[0],[Whether module safari is static])
ZEBRA_MODULE(safari,shared,[ --enable-mod-safari Safari filter (DBC)])
dnl ------ ANSI C Header files
AC_STDC_HEADERS
if test "$ac_cv_header_stdc" = "no"; then
AC_MSG_WARN([Your system does not seem to support ANSI C])
fi
AC_SUBST([IDZEBRA_SRC_ROOT])
AC_SUBST([IDZEBRA_BUILD_ROOT])
IDZEBRA_SRC_ROOT=`cd ${srcdir}; pwd`
IDZEBRA_BUILD_ROOT=`pwd`
dnl
dnl ------ versioning
dnl
WIN_FILEVERSION=`echo $PACKAGE_VERSION | $AWK 'BEGIN { FS = "."; } { m = $4; printf("%d,%d,%d,%d", $1, $2, $3 == "" ? "0" : $3, $4 == "" ? "1" : $4);}'`
AC_SUBST([WIN_FILEVERSION])
VERSION_HEX=`echo $PACKAGE_VERSION | $AWK 'BEGIN { FS = "."; } { printf("%x", ($1 * 256 + $2) * 256 + $3);}'`
AC_SUBST([VERSION_HEX])
if test -d ${srcdir}/.git; then
VERSION_SHA1=`git show --pretty=format:%H|head -1`
else
VERSION_SHA1=`head -1 ${srcdir}/ChangeLog|awk '{print $2}'`
fi
AC_SUBST([VERSION_SHA1])
dnl
dnl ------ Create Makefiles
dnl
AC_OUTPUT([
Makefile
util/Makefile
bfile/Makefile
dfa/Makefile
dict/Makefile
isamb/Makefile
isams/Makefile
isamc/Makefile
rset/Makefile
data1/Makefile
index/Makefile
include/Makefile include/idzebra/Makefile
tab/Makefile
doc/Makefile
doc/local0.ent
doc/common/Makefile
doc/common/print.dsl
test/Makefile test/gils/Makefile test/usmarc/Makefile test/api/Makefile
test/xslt/Makefile
test/xpath/Makefile
test/rusmarc/Makefile test/cddb/Makefile test/malxml/Makefile
test/mbox/Makefile
test/config/Makefile
test/dmoz/Makefile test/zsh/Makefile
test/marcxml/Makefile test/charmap/Makefile test/codec/Makefile
test/espec/Makefile
test/filters/Makefile
examples/Makefile
examples/gils/Makefile
examples/marc21/Makefile
examples/marcxml/Makefile
examples/oai-pmh/Makefile
examples/zthes/Makefile
idzebra-config-2.0
Doxyfile
win/version.nsi
include/idzebra/version.h
],[
sed s%echo_source=yes%echo_source=no%g < idzebra-config-2.0 > util/idzebra-config-2.0 && chmod +x idzebra-config-2.0 util/idzebra-config-2.0
diff doc/local.ent doc/local0.ent >/dev/null 2>/dev/null \
|| cp doc/local0.ent doc/local.ent
])
echo \
"------------------------------------------------------------------------
ZEBRA Package: ${PACKAGE}
ZEBRA Version: ${VERSION}
Source code location: ${srcdir}
C Preprocessor: ${CPP}
C Preprocessor flags: ${CPPFLAGS}
C Compiler: ${CC}
C Compiler flags: ${CFLAGS}
Linker flags: ${LDFLAGS}
Linked libs: ${LIBS}
Host System Type: ${host}
Install path: ${prefix}
Automake: ${AUTOMAKE}
Archiver: ${AR}
Ranlib: ${RANLIB}
YAZ Version: ${YAZVERSION}
YAZ Include: ${YAZINC}
YAZ La Lib: ${YAZLALIB}
YAZ Lib: ${YAZLIB}
Bugreport: ${PACKAGE_BUGREPORT}
------------------------------------------------------------------------"
dnl Local Variables:
dnl mode:shell-script
dnl sh-indentation:2
dnl sh-basic-offset: 4
dnl End:
|