File: acinclude.m4

package info (click to toggle)
jack-audio-connection-kit 1:0.125.0-3
  • links: PTS, VCS
  • area: main
  • in suites: bullseye, buster, sid
  • size: 3,368 kB
  • sloc: ansic: 40,493; cpp: 1,426; makefile: 678; python: 327; sh: 89
file content (41 lines) | stat: -rw-r--r-- 902 bytes parent folder | download | duplicates (5)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
dnl AS_AC_EXPAND(VAR, CONFIGURE_VAR)
dnl example
dnl AS_AC_EXPAND(SYSCONFDIR, $sysconfdir)
dnl will set SYSCONFDIR to /usr/local/etc

dnl written by thomas vander stichele

AC_DEFUN([AS_AC_EXPAND],
[
  EXP_VAR=[$1]
  FROM_VAR=[$2]

  dnl first expand prefix and exec_prefix if necessary
  prefix_save=$prefix
  if test "x$prefix" = "xNONE"; then
    prefix=/usr/local
  fi
  exec_prefix_save=$exec_prefix
  if test "x$exec_prefix" = "xNONE"; then
    if test "x$prefix_save" = "xNONE"; then
      exec_prefix=/usr/local
    else
      exec_prefix=$prefix
    fi
  fi

  full_var="$FROM_VAR"
  dnl loop until it doesn't change anymore
  while true; do
    new_full_var="`eval echo $full_var`"
    if test "x$new_full_var" = "x$full_var"; then break; fi
    full_var=$new_full_var
  done

  dnl clean up
  full_var=$new_full_var
  [$1]=$full_var
  prefix=$prefix_save
  exec_prefix=$exec_prefix_save
])