/** -*-C-*-ish
    Kaya standard library
    Copyright (C) 2004, 2005 Edwin Brady

    This file is distributed under the terms of the GNU Lesser General
    Public Licence. See COPYING for licence.
*/

module Webapp;

import Prelude;
import System;
import Strings;
import Crypto;
import Regex;
import IO;
import WebCommon;

type HTML = String;

globals {
    [HTML] pagecontent;
    [String] headers;
    Bool headersdone;

    [(String,String)] queryVars;
    [(String,String)] postVars;
    [(String,String)] cookies;
    [(Char,String)] esctable;
}

public Exception UnrecognisedVariable(String err) = Exception(err,520);
public Exception IllegalHandler = Exception("Illegal handler called",521);
public Exception UnexpectedType(String err) = Exception(err,522);
public Exception OutOfRange = Exception("Value out of range",523);

"Add a header."
public Void header(String h)
{
    push(headers, h);
}

"Add some content"
public Void content(HTML c)
{
    push(pagecontent, c);
}

"Initialise the web app. 
Automatically run if the program is declared to be a webapp."
public Void initWebApp()
{
    headers = [];
    pagecontent = [];
    headersdone = false;
    initVars();
}

String encodeChar(Char x) {
    if (x==' ') { return "+"; }
    if (Int(x)>127 || isPunctuation(x))
/*	(x `elem` ['!','&','$','+',',','/',':',';','=','?','@',
		  '"','<','>','#','%','{','}','|','\\','^',
		  '~','[',']','`']))*/
    {
	return "%"+stringBase(Int(x),16);
    }
    return String(x);
}


[(String,String)] parseVars(String vars, String delim)
{
    varlist = Regex::split(delim,vars);
    pairs = [];
    for v in varlist {
	// left = right, urldecode the thing
	def = Regex::split("=",v);
	push(pairs,(urlDecode(def[0]),urlDecode(def[1])));
    }
    return pairs;
}

"Return the value of a GET var"
public String httpGetVar(String x) {
    for v in queryVars {
	if (v.fst==x) return v.snd;
    }
    throw(UnrecognisedVariable(x+" is not a GET variable"));
}

"Return the value of a POST var"
public String httpPostVar(String x) {
    for v in postVars {
	if (v.fst==x) return v.snd;
    }
    throw(UnrecognisedVariable(x+" is not a POST variable"));
}

"Return the value of a GET/POST var.
 Returns POST vars as preference, if a variable is defined in both."
public String httpVar(String x) {
    for v in postVars {
	if (v.fst==x) return v.snd;
    }
    for v in queryVars {
	if (v.fst==x) return v.snd;
    }
    return "";
}

"Return the value of a cookie.
Checks that the cookie is set, and throws an Exception if not"
public String cookie(String x) {
    for v in cookies {
	if (v.fst==x) return v.snd;
    }
    throw(UnrecognisedVariable(x+" is not a cookie"));
}

Void initVars()
{
    query = getEnv("QUERY_STRING");
    cookie = getEnv("HTTP_COOKIE");
    len = Int(getEnv("CONTENT_LENGTH"));
    postvars = "";
    for x in [1..len] {
	postvars += getChar(stdin);
    }

    queryVars = parseVars(query,"&");
    postVars = parseVars(postvars,"&");
    cookies = parseVars(cookie,"; ");
}

"Output headers. 
Outputs a Content-type:text/html header if none has been given.
This only works once; after outputting the headers, only content can be added."
public Void flushHeaders()
{
    contenttype = false;
    if (!headersdone) {
	for h in headers {
	    putStrLn(h);
	    if (substr(h,0,12)=="Content-type") {
		contenttype=true;
	    }
	}
	// If we haven't had a Content-type header, output the default one.
	if (!contenttype) {
	    putStrLn("Content-type: text/html;charset=UTF-8");
	}
	putStrLn("");
	headersdone = true;
    }
//    print "Flushing headers";
}

"Output the content. 
This only makes sense with headers, so output them first."
public Void flushContent()
{
    flushHeaders();
//    print "Flushing content "+String(size(pagecontent));
    for c in pagecontent {
	putStrLn(c);
    }
    pagecontent = [];
}

"Replace a string in the current output.
Replaces <em>str</em> in <em>new</em> 
wherever it occurs in the headers/content."
public Void replaceContent(HTML str, HTML new)
{
    for h in headers {
	replace(str,new,h,[Global]);
    }
    newc = [];
    for c in pagecontent {
	replace(str,new,c,[Global]);
	push(newc,c);
    }
    pagecontent = newc;
}

"Output all headers and content. 
This need not be called by the user, as it is done automatically at the end of 
a webapp's execution. It may be useful for debugging purposes, however."
public Void flush()
{
    flushContent();
//    print "Flushing ";
}

"Set a cookie"
public Void setCookie(String name,String value)
{
    header("Set-Cookie: "+name+"="+urlEncode(value));
}

"Return the integer in a GET/POST variable.
Throws an exception if it's not a valid integer."
public Int httpInt(String v)
{
    x = httpVar(v);
    if (quickMatch("^[+-]?[0-9]*$", x)) {
	return Int(x);
    } else {
	throw(UnexpectedType(x+" is not an integer in http variable "+v));
    }
}

"Return the float in a GET/POST variable.
Throws an exception if it's not a valid float."
public Float httpFloat(String v)
{
    x = httpVar(v);
    // FIXME: This isn't quite right, but it'll do for now.
    if (quickMatch("[0-9]*\.?[0-9]*e?[+-][0-9]*", x)) {
	return Float(x);
    } else {
	throw(UnexpectedType(x+" is not a float in http variable "+v));
    }
}

"Create a submit button.
The String return is HTML to create the button. Typical usage is:<br>
<code>content(submit(\"Submit\")</code>"
public HTML submit(String text)
{
    submitname = "kaya_submit";
    return "<input type=\"submit\" value=\""+text+"\" name=\"" + 
	    submitname +"\">";
}

"Create a reset button.
The String return is HTML to create the button. Typical usage is:<br>
<code>content(reset(\"Reset\")</code>"
public HTML reset(String text) = "<input type=\"reset\" value=\""+text+"\">";

"
Returns the text on the submit button used to submit the form currently
being processed."
public String submitUsed = httpVar("kaya_submit");

String scriptName() {
    nms = Regex::split("\/",progName());
    return nms[size(nms)-1];
}

"Set up a form.
The <em>fn</em> is a function used to process the form. 
When processing the
form, <em>fn</em> is passed the value <em>dat</em>.
<em>prepost</em> determines whether <em>PreContent</em> and 
<em>PostContent</em> are called for this link. Default is to call them, but
it can be useful to turn it off if the content type of the link is not 
text/html."
public HTML formHandler(Void(a) fn, a dat, Bool prepost = true)
{
    str = "<form action=\""+ scriptName()+"\" method=\"POST\">\n";
    str += "<input type=\"hidden\" name=\"kaya_function\" value=\""+
	encode(marshal(fn,888))+"\">\n";
    str += "<input type=\"hidden\" name=\"kaya_arg\" value=\""+
	encode(marshal(dat,fnid(fn)))+"\">";
    if (!prepost) {
	str += "<input type=\"hidden\" name=\"kaya_prepost\" value=\""+
	    encode(marshal(prepost,0))+"\">";
    }
    return str;
}

"Set up a file upload form.
NOTE: Still in development. This doesn't work yet, and the interface
will probably change."
public HTML fileFormHandler(Void(a) fn, a dat, Int maxsize, 
			    Bool prepost = true)
{
    str = "<form enctype=\"multipart/form-data\" action=\""+ 
	scriptName()+"\" method=\"POST\">\n";
//    str += "<input type=\"hidden\" name=\"MAX_FILE_SIZE\" value=\""+maxsize+
//	"\">";
    str += "<input type=\"hidden\" name=\"kaya_function\" value=\""+
	encode(String(fnid(fn)))+"\">\n";
    str += "<input type=\"hidden\" name=\"kaya_arg\" value=\""+
	encode(marshal(dat,fnid(fn)))+"\">";
    if (!prepost) {
	str += "<input type=\"hidden\" name=\"kaya_prepost\" value=\""+
	    encode(marshal(prepost,0))+"\">";
    }
    return str;
}

public HTML uploadButton(String name) 
  = "<input name=\""+name+"\" type=\"file\">";


// Helper for linkHandler.
String handlerQuery(Void(a) fn, a dat, Bool prepost) {
    str = "kaya_function="+urlEncode(encode(marshal(fn,888)));
    str += "&kaya_arg="+urlEncode(encode(marshal(dat,fnid(fn))));
    if (!prepost) {
	str += "&kaya_prepost="+urlEncode(encode(marshal(prepost,0)));
    }

    return str;
}

"
Set up a link, handled by the function <em>fn</em>.
When processing the
link, <em>fn</em> is passed the value <em>dat</em>.
<em>inf</em> is the link text.
<em>others</em> is a list of pairs of variables and values to be
passed through the query string.
<em>prepost</em> determines whether <em>PreContent</em> and 
<em>PostContent</em> are called for this link. Default is to call them, but
it can be useful to turn it off if the content type of the link is not 
text/html."
public HTML linkHandler(Void(a) fn, a dat, String inf, 
			  [(String,String)] others = [], Bool prepost = true) 
{
    url = scriptName()+"?"+handlerQuery(fn,dat,prepost);
    for o in others {
	url = url + "&" + o.fst + "=" + o.snd;
    }
    return "<a href=\""+url+"\">"+inf+"</a>";
}

"Embed an image.
<em>fn</em> is the function which generates the image, and is passed the 
value <em>dat</em>. <em>alt</em> is the (required!) ALT text.
<em>width</em> and <em>height</em> can be given optionally, as can
a list of other attributes."
public HTML imageHandler(Void(a) fn, a dat, String alt, 
			 Int width = -1, Int height =-1, String attribs="")
{
    url = scriptName()+"?"+handlerQuery(fn,dat,false);
    if (width!=-1) {
	size = "width="+width+" height="+height;
    }
    else {
	size = "";
    }
    return "<img src=\""+url+"\" alt=\""+alt+"\" "+size+" "+attribs+">";
}

"Link to the default function."
public HTML goDefault(String inf)
{
    url = scriptName();
    return "<a href=\""+url+"\">"+inf+"</a>";
}

"Pass a variable to a form."
public HTML passVar(String httpvar, String value)
{
    return "<input type=\"hidden\" name=\""+httpvar+"\" value=\""+value+"\">";
}

"Create a text box"
public HTML textBox(String name, String value="", Int len = 20)
{
    return "<input type=\"text\" size="+String(len)+" name=\""+name+"\" value=\""+value+"\">";
}

"Create a password box"
public HTML passwordBox(String name, Int len = 20)
{
    return "<input type=\"password\" size="+String(len)+" name=\""+name+"\">";
}

"Create a selection box.
The possible values are listed in <em>opts</em>, and the default
selection is passed in <em>def</em>."
public HTML selBox(String name, Int len, [String] opts, String def = "")
{
    str = "<select name=\""+name+"\" size="+ String(len)+">";
    for entry in opts {
	if (entry==def) {
	    str+="<option selected>";
	}
	else {
	    str+="<option>";
	}
	str+=entry+"</option>";
    }
    str+="</select>";
    return str;
}

"Make a checkbox.
<em>def</em> denotes whether this is the default value."
public HTML checkBox(String name,Bool def = false)
{
    str = "<input type=\"checkbox\" name=\""+name+"\" ";
    if (def) str+="checked>"; else str+=">";
    return str;
}

"Return whether a checkbox was checked."
public Bool checked(String name) 
{
    return httpVar(name)=="on";
}

"Create a radio button."
public HTML radio(String name, String val, Bool set = false)
{
    str = "<input type=\"radio\" name=\""+name+"\" value=\""+val+"\" ";
    if (set) str+="checked>"; else str+=">";
    return str;
}

/// Create a file upload thingy
/// Won't work yet though. Need to handle enctype="multipart/form-data"
/*
String fileUpload(String name) 
    = "<input type=\"file\" name=\""+name+"\" size=20>";
*/

"End a form
Simply returns <code>&lt;/form></code>"
public HTML closeForm()
{
    return "</form>";
}

"Output a table."
public HTML table([String] titles, [[String]] rows, 
		    String tableattribs="",
		    String headattribs="",
		    String dataattribs="")
{
    str = "<table "+tableattribs+">";
    if (titles!=[]) {
	str+=tablerow("th",headattribs, titles)+"\n";
    }

    for row in rows {
	str+=tablerow("td",dataattribs, row)+"\n";
    }

    return str+"</table>";
}

String tablerow(String tag,String attribs,[String] stuff)
{
    str = "";
    str += "<tr>";
    for t in stuff {
	str+="<"+tag+" "+attribs+">"+t+"</"+tag+">";
    }
    str += "</tr>";
    return str;
}

/*
Void webappMain(Void() headerfn, Void() defaultfn, Void() footerfn)
{
    foreign Void storeHTTPargs();
    try {
	dfun = httparg("kaya_function");
	darg = httparg("kaya_arg");

	id = Int(decode(dfun));
...
    }
    catch(e) {
	defaultfn();
    }
}*/

String htmlEncodeChar(Char x) {
    if (size(esctable)==0) {
	esctable = [('&',"&amp;"),
		    ('<',"&lt;"),
		    ('>',"&gt;"),
		    ('',"&pound;")];
    }

    for p in esctable {
	if (x==p.fst)
	    return p.snd;
    }
    return String(x);
}

"Transforms HTML special chars.
Transforms chars like '&lt;', '&gt;' and others in HTML form, like '&amp;lt' and '&amp;gt'"
public String htmlEscape(String x)
{
    str = x;
    current = "";
    while(str!="") {
	c = head(str);
	str = tail(str);
	current += htmlEncodeChar(c);
    }
    return current;
}



/// Safe cast functions

"Convert a string to an Int.
If the resulting Int is out of the specified range, throws an exception."
public Int safeInt(String x, Int min, Int max)
{
    num = Int(x);
    if (num<min || num>max) {
        throw(OutOfRange);
    }
    return num;
} 

"Convert a string to a Float.
If the resulting Float is out of the specified range, throws an exception."
public Float safeFloat(String x, Float min, Float max)
{
    num = Float(x);
    if (num<min || num>max) {
	throw(OutOfRange);
    }
    return num;
}