File: configure.in

package info (click to toggle)
kdbg 1.2.4-2
  • links: PTS
  • area: main
  • in suites: woody
  • size: 2,504 kB
  • ctags: 1,945
  • sloc: cpp: 15,961; sh: 8,183; makefile: 481; perl: 71; ansic: 16
file content (118 lines) | stat: -rw-r--r-- 3,767 bytes parent folder | download
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118

dnl without this order in this file, autoconf will not work!
dnl the argument is a source file out of your sources. But
dnl acinclude.m4 makes the job for all programs ;-)
AC_INIT(acinclude.m4)

dnl without this order in this file, automake will be confused!
dnl the argument 
AM_CONFIG_HEADER(config.h)

dnl ask for Qt and KDE version
with_kde_version="2"
AM_CONDITIONAL(BUILDFORKDE2, test "x$with_kde_version" = "x2")

dnl insert here your program name and version number
KDE_USE_QT($with_kde_version)
KDE_DO_IT_ALL(kdbg, 1.2.4)

dnl in this space add everything you want to check for
dnl examples are specific headers, libraries, etc.
dnl everything to compile and run a KDE program is already checked

dnl Checks for header files.
AC_LANG_C dnl switch to C
AC_HEADER_DIRENT dnl check for dirent.h
AC_HEADER_STDC dnl check for other stdc headers. More traditional ;)
dnl check for some more header files. You can remove some of
dnl them, if you want to. But it doesn't hurt
AC_CHECK_HEADERS(fcntl.h sys/time.h unistd.h sys/cdefs.h)
AC_CHECK_HEADERS(fnmatch.h sysent.h strings.h sys/stat.h)
AC_CHECK_HEADERS(sys/ioctl.h pty.h libutil.h)

dnl Checks for libraries.
AC_CHECK_LIB(socket, socket, [LIBSOCKET="-lsocket -lnsl"]) dnl for Solaris' X11
AC_SUBST(LIBSOCKET)

dnl Checks for typedefs, structures, and compiler characteristics.
AC_HEADER_TIME

dnl Checks for library functions.
AC_CHECK_FUNCS(setpgid putenv socket vsnprintf mkfifo)
AC_CHECK_SETENV

dnl pseudo tty support in glibc2
AC_SEARCH_LIBS(openpty, util,
  AC_DEFINE_UNQUOTED(HAVE_FUNC_OPENPTY, 1, [Define if you have openpty]))

dnl Check whether we want much debugging output
AC_MSG_CHECKING([whether kdbg should generate lots of trace output])
dnl Default is no trace output
AC_ARG_ENABLE(lots-a-trace,
  [  --enable-lots-a-trace   generate lots of trace output [default=no]],
  WANT_TRACE_OUTPUT=$enableval, WANT_TRACE_OUTPUT=no)
AC_MSG_RESULT($WANT_TRACE_OUTPUT)
if test "x$WANT_TRACE_OUTPUT" = "xyes"; then
  AC_DEFINE_UNQUOTED(WANT_TRACE_OUTPUT)
fi

dnl Check whether test programs should be compiled
dnl Default is not to compile them
AC_ARG_ENABLE(testprogs,
  [  --enable-testprogs      compile test programs [default=no]],
  [buildtestprogs=$enableval],[buildtestprogs=no])
AM_CONDITIONAL(BUILDTESTPROGS,test "x$buildtestprogs" = "xyes")
dnl write a notice into the log
echo "build test programs: $buildtestprogs" >&5

dnl Check where the communication with gdb should be logged
AC_MSG_CHECKING([where communication with gdb should be logged])
dnl Default is ./gdb-transcript until kdbg is released
AC_ARG_WITH(transcript,
  [  --with-transcript=file  log communication with gdb [default=not logged]],
  GDB_TRANSCRIPT=$withval, GDB_TRANSCRIPT=no)
if test "x$GDB_TRANSCRIPT" = "xyes"; then
  GDB_TRANSCRIPT="./gdb-transcript"
fi
if test "x$GDB_TRANSCRIPT" = "xno"; then
  GDB_TRANSCRIPT="not logged"
else
  dnl add quotes
  GDB_TRANSCRIPT=\"$GDB_TRANSCRIPT\"
  AC_DEFINE_UNQUOTED(GDB_TRANSCRIPT, $GDB_TRANSCRIPT)
fi
AC_MSG_RESULT($GDB_TRANSCRIPT)

dnl Check whether placement new works
AC_LANG_CPLUSPLUS
AC_MSG_CHECKING(whether placement new is available)
AC_CACHE_VAL(ac_cv_have_placement_new,
[
AC_TRY_COMPILE([
#include <new>
],
[
int ii;
new(&ii) int;
],
ac_cv_have_placement_new=yes,
ac_cv_have_placement_new=no)
])
AC_MSG_RESULT($ac_cv_have_placement_new)
if eval "test \"`echo `$ac_cv_have_placement_new\" = yes"; then
  AC_DEFINE(HAVE_PLACEMENT_NEW)
fi

dnl add here all your Makefiles. These are created by configure
AC_OUTPUT(Makefile \
	STabCtl/Makefile \
	DockWidget/Makefile \
	kdbg/Makefile \
	kdbg/doc/Makefile \
	kdbg/doc/de/Makefile \
	kdbg/doc/en/Makefile \
	kdbg/doc/ru/Makefile \
	kdbg/pics/Makefile \
	kdbg/typetables/Makefile \
	kdbg/testprogs/Makefile \
	po/Makefile)