1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
|
# Variables
unix:!macx {
# QMAKE_CXXFLAGS += `pkg-config --cflags poppler-qt4`
# QMAKE_LFLAGS += `pkg-config --libs poppler-qt4` # using this, qmake adds 3 times "--libs" to the LFLAGS, which is not recognized by g++ 4.6
PKG_CONFIG = $$pkgConfigExecutable()
greaterThan(QT_MAJOR_VERSION, 4) {
POPPLERINCLUDES = $$system($$PKG_CONFIG --cflags poppler-qt5)
POPPLERLIBS = $$system($$PKG_CONFIG --libs poppler-qt5)
} else {
POPPLERINCLUDES = $$system($$PKG_CONFIG --cflags poppler-qt4)
POPPLERLIBS = $$system($$PKG_CONFIG --libs poppler-qt4)
}
QMAKE_CXXFLAGS += $$POPPLERINCLUDES
QMAKE_LFLAGS += $$POPPLERLIBS
}
# Functions
defineTest(QtVersionGreaterThan) {
isEqual(QT_MAJOR_VERSION, $$1)|greaterThan(QT_MAJOR_VERSION, $$1) {
isEqual(QT_MINOR_VERSION, $$2)|greaterThan(QT_MINOR_VERSION, $$2) {
isEqual(QT_PATCH_VERSION, $$3)|greaterThan(QT_PATCH_VERSION, $$3) {
return(true)
}
}
}
return(false)
}
defineReplace(formSources) {
names = $$ARGS
sourceNames =
for(name, names) {
baseName = $$replace(name, "\\.ui", "")
sourceName = $${baseName}.cpp
exists($$sourceName) {
sourceNames += $$sourceName
}
}
return($$sourceNames)
}
defineReplace(headerFiles) {
names = $$ARGS
headerNames =
for(name, names) {
baseName = $$replace(name, "\\.cpp", "")
headerName = $${baseName}.h
exists($$headerName) {
headerNames += $$headerName
}
}
return($$headerNames)
}
defineReplace(replaceArgs) {
template = $$member(ARGS, 0)
args = $$replace(ARGS, $${template}, "")
itemList =
for(arg, args) {
item = $$replace(template, "%1", $$arg)
itemList += $$item
}
return($$itemList)
}
defineReplace(tsFilesInDir) {
dir = $$1
languages = $$2
tsfiles =
for(lang, languages) {
tsName = $${dir}/$${lang}/qtikz_$${lang}.ts
exists($$tsName) {
tsfiles += $$tsName
}
}
return($$tsfiles)
}
defineReplace(qmFiles) {
dir = $$1
names = $$2
qmfiles =
for(name, names) {
baseName = $$replace(name, "\\.ts", "")
baseName = $$replace(baseName, ".*\\/", "")
qmName = $${dir}/$${baseName}.qm
qmfiles += $$qmName
}
return($$qmfiles)
}
defineReplace(manTemplateFilesInDir) {
dir = $$member(ARGS, 0)
languages = $$replace(ARGS, $${dir}, "")
manfiles =
for(lang, languages) {
manName = $${dir}/$${lang}/qtikz.1.template
exists($$manName) {
manfiles += $$manName
}
}
return($$manfiles)
}
defineReplace(manFiles) {
names = $$ARGS
manfiles =
for(name, names) {
baseName = $$replace(name, "\\.template", "")
baseName = $$replace(baseName, ".*\\/", "")
manName = $${OUT_PWD}/$${LOCALEDIR}$${baseName}
manfiles += $$manName
}
return($$qmfiles)
}
defineReplace(addPrefix) {
prefix = $$member(ARGS, 0)
names = $$replace(ARGS, $${prefix}, "")
files =
for(name, names) {
newName = $${prefix}$${name}
files += $$newName
}
return($$files)
}
defineReplace(addSuffix) {
suffix = $$member(ARGS, 0)
names = $$replace(ARGS, $${suffix}, "")
files =
for(name, names) {
newName = $${name}$${suffix}
files += $$newName
}
return($$files)
}
|
