1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162
163
164
165
166
167
168
169
170
171
172
173
174
175
176
177
178
179
180
181
182
183
184
185
186
187
|
SUBROUTINE CSTT22( N, M, KBAND, AD, AE, SD, SE, U, LDU, WORK,
$ LDWORK, RWORK, RESULT )
*
* -- LAPACK test routine (version 3.0) --
* Univ. of Tennessee, Univ. of California Berkeley, NAG Ltd.,
* Courant Institute, Argonne National Lab, and Rice University
* June 30, 1999
*
* .. Scalar Arguments ..
INTEGER KBAND, LDU, LDWORK, M, N
* ..
* .. Array Arguments ..
REAL AD( * ), AE( * ), RESULT( 2 ), RWORK( * ),
$ SD( * ), SE( * )
COMPLEX U( LDU, * ), WORK( LDWORK, * )
* ..
*
* Purpose
* =======
*
* CSTT22 checks a set of M eigenvalues and eigenvectors,
*
* A U = U S
*
* where A is Hermitian tridiagonal, the columns of U are unitary,
* and S is diagonal (if KBAND=0) or Hermitian tridiagonal (if KBAND=1).
* Two tests are performed:
*
* RESULT(1) = | U* A U - S | / ( |A| m ulp )
*
* RESULT(2) = | I - U*U | / ( m ulp )
*
* Arguments
* =========
*
* N (input) INTEGER
* The size of the matrix. If it is zero, CSTT22 does nothing.
* It must be at least zero.
*
* M (input) INTEGER
* The number of eigenpairs to check. If it is zero, CSTT22
* does nothing. It must be at least zero.
*
* KBAND (input) INTEGER
* The bandwidth of the matrix S. It may only be zero or one.
* If zero, then S is diagonal, and SE is not referenced. If
* one, then S is Hermitian tri-diagonal.
*
* AD (input) REAL array, dimension (N)
* The diagonal of the original (unfactored) matrix A. A is
* assumed to be Hermitian tridiagonal.
*
* AE (input) REAL array, dimension (N)
* The off-diagonal of the original (unfactored) matrix A. A
* is assumed to be Hermitian tridiagonal. AE(1) is ignored,
* AE(2) is the (1,2) and (2,1) element, etc.
*
* SD (input) REAL array, dimension (N)
* The diagonal of the (Hermitian tri-) diagonal matrix S.
*
* SE (input) REAL array, dimension (N)
* The off-diagonal of the (Hermitian tri-) diagonal matrix S.
* Not referenced if KBSND=0. If KBAND=1, then AE(1) is
* ignored, SE(2) is the (1,2) and (2,1) element, etc.
*
* U (input) REAL array, dimension (LDU, N)
* The unitary matrix in the decomposition.
*
* LDU (input) INTEGER
* The leading dimension of U. LDU must be at least N.
*
* WORK (workspace) COMPLEX array, dimension (LDWORK, M+1)
*
* LDWORK (input) INTEGER
* The leading dimension of WORK. LDWORK must be at least
* max(1,M).
*
* RWORK (workspace) REAL array, dimension (N)
*
* RESULT (output) REAL array, dimension (2)
* The values computed by the two tests described above. The
* values are currently limited to 1/ulp, to avoid overflow.
*
* =====================================================================
*
* .. Parameters ..
REAL ZERO, ONE
PARAMETER ( ZERO = 0.0E0, ONE = 1.0E0 )
COMPLEX CZERO, CONE
PARAMETER ( CZERO = ( 0.0E+0, 0.0E+0 ),
$ CONE = ( 1.0E+0, 0.0E+0 ) )
* ..
* .. Local Scalars ..
INTEGER I, J, K
REAL ANORM, ULP, UNFL, WNORM
COMPLEX AUKJ
* ..
* .. External Functions ..
REAL CLANGE, CLANSY, SLAMCH
EXTERNAL CLANGE, CLANSY, SLAMCH
* ..
* .. External Subroutines ..
EXTERNAL CGEMM
* ..
* .. Intrinsic Functions ..
INTRINSIC ABS, MAX, MIN, REAL
* ..
* .. Executable Statements ..
*
RESULT( 1 ) = ZERO
RESULT( 2 ) = ZERO
IF( N.LE.0 .OR. M.LE.0 )
$ RETURN
*
UNFL = SLAMCH( 'Safe minimum' )
ULP = SLAMCH( 'Epsilon' )
*
* Do Test 1
*
* Compute the 1-norm of A.
*
IF( N.GT.1 ) THEN
ANORM = ABS( AD( 1 ) ) + ABS( AE( 1 ) )
DO 10 J = 2, N - 1
ANORM = MAX( ANORM, ABS( AD( J ) )+ABS( AE( J ) )+
$ ABS( AE( J-1 ) ) )
10 CONTINUE
ANORM = MAX( ANORM, ABS( AD( N ) )+ABS( AE( N-1 ) ) )
ELSE
ANORM = ABS( AD( 1 ) )
END IF
ANORM = MAX( ANORM, UNFL )
*
* Norm of U*AU - S
*
DO 40 I = 1, M
DO 30 J = 1, M
WORK( I, J ) = CZERO
DO 20 K = 1, N
AUKJ = AD( K )*U( K, J )
IF( K.NE.N )
$ AUKJ = AUKJ + AE( K )*U( K+1, J )
IF( K.NE.1 )
$ AUKJ = AUKJ + AE( K-1 )*U( K-1, J )
WORK( I, J ) = WORK( I, J ) + U( K, I )*AUKJ
20 CONTINUE
30 CONTINUE
WORK( I, I ) = WORK( I, I ) - SD( I )
IF( KBAND.EQ.1 ) THEN
IF( I.NE.1 )
$ WORK( I, I-1 ) = WORK( I, I-1 ) - SE( I-1 )
IF( I.NE.N )
$ WORK( I, I+1 ) = WORK( I, I+1 ) - SE( I )
END IF
40 CONTINUE
*
WNORM = CLANSY( '1', 'L', M, WORK, M, RWORK )
*
IF( ANORM.GT.WNORM ) THEN
RESULT( 1 ) = ( WNORM / ANORM ) / ( M*ULP )
ELSE
IF( ANORM.LT.ONE ) THEN
RESULT( 1 ) = ( MIN( WNORM, M*ANORM ) / ANORM ) / ( M*ULP )
ELSE
RESULT( 1 ) = MIN( WNORM / ANORM, REAL( M ) ) / ( M*ULP )
END IF
END IF
*
* Do Test 2
*
* Compute U*U - I
*
CALL CGEMM( 'T', 'N', M, M, N, CONE, U, LDU, U, LDU, CZERO, WORK,
$ M )
*
DO 50 J = 1, M
WORK( J, J ) = WORK( J, J ) - ONE
50 CONTINUE
*
RESULT( 2 ) = MIN( REAL( M ), CLANGE( '1', M, M, WORK, M,
$ RWORK ) ) / ( M*ULP )
*
RETURN
*
* End of CSTT22
*
END
|
