1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162
163
164
165
166
167
168
169
|
SUBROUTINE CRQT02( M, N, K, A, AF, Q, R, LDA, TAU, WORK, LWORK,
$ RWORK, RESULT )
*
* -- LAPACK test routine (version 3.0) --
* Univ. of Tennessee, Univ. of California Berkeley, NAG Ltd.,
* Courant Institute, Argonne National Lab, and Rice University
* September 30, 1994
*
* .. Scalar Arguments ..
INTEGER K, LDA, LWORK, M, N
* ..
* .. Array Arguments ..
REAL RESULT( * ), RWORK( * )
COMPLEX A( LDA, * ), AF( LDA, * ), Q( LDA, * ),
$ R( LDA, * ), TAU( * ), WORK( LWORK )
* ..
*
* Purpose
* =======
*
* CRQT02 tests CUNGRQ, which generates an m-by-n matrix Q with
* orthonornmal rows that is defined as the product of k elementary
* reflectors.
*
* Given the RQ factorization of an m-by-n matrix A, CRQT02 generates
* the orthogonal matrix Q defined by the factorization of the last k
* rows of A; it compares R(m-k+1:m,n-m+1:n) with
* A(m-k+1:m,1:n)*Q(n-m+1:n,1:n)', and checks that the rows of Q are
* orthonormal.
*
* Arguments
* =========
*
* M (input) INTEGER
* The number of rows of the matrix Q to be generated. M >= 0.
*
* N (input) INTEGER
* The number of columns of the matrix Q to be generated.
* N >= M >= 0.
*
* K (input) INTEGER
* The number of elementary reflectors whose product defines the
* matrix Q. M >= K >= 0.
*
* A (input) COMPLEX array, dimension (LDA,N)
* The m-by-n matrix A which was factorized by CRQT01.
*
* AF (input) COMPLEX array, dimension (LDA,N)
* Details of the RQ factorization of A, as returned by CGERQF.
* See CGERQF for further details.
*
* Q (workspace) COMPLEX array, dimension (LDA,N)
*
* R (workspace) COMPLEX array, dimension (LDA,M)
*
* LDA (input) INTEGER
* The leading dimension of the arrays A, AF, Q and L. LDA >= N.
*
* TAU (input) COMPLEX array, dimension (M)
* The scalar factors of the elementary reflectors corresponding
* to the RQ factorization in AF.
*
* WORK (workspace) COMPLEX array, dimension (LWORK)
*
* LWORK (input) INTEGER
* The dimension of the array WORK.
*
* RWORK (workspace) REAL array, dimension (M)
*
* RESULT (output) REAL array, dimension (2)
* The test ratios:
* RESULT(1) = norm( R - A*Q' ) / ( N * norm(A) * EPS )
* RESULT(2) = norm( I - Q*Q' ) / ( N * EPS )
*
* =====================================================================
*
* .. Parameters ..
REAL ZERO, ONE
PARAMETER ( ZERO = 0.0E+0, ONE = 1.0E+0 )
COMPLEX ROGUE
PARAMETER ( ROGUE = ( -1.0E+10, -1.0E+10 ) )
* ..
* .. Local Scalars ..
INTEGER INFO
REAL ANORM, EPS, RESID
* ..
* .. External Functions ..
REAL CLANGE, CLANSY, SLAMCH
EXTERNAL CLANGE, CLANSY, SLAMCH
* ..
* .. External Subroutines ..
EXTERNAL CGEMM, CHERK, CLACPY, CLASET, CUNGRQ
* ..
* .. Intrinsic Functions ..
INTRINSIC CMPLX, MAX, REAL
* ..
* .. Scalars in Common ..
CHARACTER*6 SRNAMT
* ..
* .. Common blocks ..
COMMON / SRNAMC / SRNAMT
* ..
* .. Executable Statements ..
*
* Quick return if possible
*
IF( M.EQ.0 .OR. N.EQ.0 .OR. K.EQ.0 ) THEN
RESULT( 1 ) = ZERO
RESULT( 2 ) = ZERO
RETURN
END IF
*
EPS = SLAMCH( 'Epsilon' )
*
* Copy the last k rows of the factorization to the array Q
*
CALL CLASET( 'Full', M, N, ROGUE, ROGUE, Q, LDA )
IF( K.LT.N )
$ CALL CLACPY( 'Full', K, N-K, AF( M-K+1, 1 ), LDA,
$ Q( M-K+1, 1 ), LDA )
IF( K.GT.1 )
$ CALL CLACPY( 'Lower', K-1, K-1, AF( M-K+2, N-K+1 ), LDA,
$ Q( M-K+2, N-K+1 ), LDA )
*
* Generate the last n rows of the matrix Q
*
SRNAMT = 'CUNGRQ'
CALL CUNGRQ( M, N, K, Q, LDA, TAU( M-K+1 ), WORK, LWORK, INFO )
*
* Copy R(m-k+1:m,n-m+1:n)
*
CALL CLASET( 'Full', K, M, CMPLX( ZERO ), CMPLX( ZERO ),
$ R( M-K+1, N-M+1 ), LDA )
CALL CLACPY( 'Upper', K, K, AF( M-K+1, N-K+1 ), LDA,
$ R( M-K+1, N-K+1 ), LDA )
*
* Compute R(m-k+1:m,n-m+1:n) - A(m-k+1:m,1:n) * Q(n-m+1:n,1:n)'
*
CALL CGEMM( 'No transpose', 'Conjugate transpose', K, M, N,
$ CMPLX( -ONE ), A( M-K+1, 1 ), LDA, Q, LDA,
$ CMPLX( ONE ), R( M-K+1, N-M+1 ), LDA )
*
* Compute norm( R - A*Q' ) / ( N * norm(A) * EPS ) .
*
ANORM = CLANGE( '1', K, N, A( M-K+1, 1 ), LDA, RWORK )
RESID = CLANGE( '1', K, M, R( M-K+1, N-M+1 ), LDA, RWORK )
IF( ANORM.GT.ZERO ) THEN
RESULT( 1 ) = ( ( RESID / REAL( MAX( 1, N ) ) ) / ANORM ) / EPS
ELSE
RESULT( 1 ) = ZERO
END IF
*
* Compute I - Q*Q'
*
CALL CLASET( 'Full', M, M, CMPLX( ZERO ), CMPLX( ONE ), R, LDA )
CALL CHERK( 'Upper', 'No transpose', M, N, -ONE, Q, LDA, ONE, R,
$ LDA )
*
* Compute norm( I - Q*Q' ) / ( N * EPS ) .
*
RESID = CLANSY( '1', 'Upper', M, R, LDA, RWORK )
*
RESULT( 2 ) = ( RESID / REAL( MAX( 1, N ) ) ) / EPS
*
RETURN
*
* End of CRQT02
*
END
|
