1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162
163
164
165
166
167
168
169
170
171
172
173
174
175
176
177
178
179
180
181
182
183
184
185
|
SUBROUTINE ZPPT03( UPLO, N, A, AINV, WORK, LDWORK, RWORK, RCOND,
$ RESID )
*
* -- LAPACK test routine (version 3.0) --
* Univ. of Tennessee, Univ. of California Berkeley, NAG Ltd.,
* Courant Institute, Argonne National Lab, and Rice University
* September 30, 1994
*
* .. Scalar Arguments ..
CHARACTER UPLO
INTEGER LDWORK, N
DOUBLE PRECISION RCOND, RESID
* ..
* .. Array Arguments ..
DOUBLE PRECISION RWORK( * )
COMPLEX*16 A( * ), AINV( * ), WORK( LDWORK, * )
* ..
*
* Purpose
* =======
*
* ZPPT03 computes the residual for a Hermitian packed matrix times its
* inverse:
* norm( I - A*AINV ) / ( N * norm(A) * norm(AINV) * EPS ),
* where EPS is the machine epsilon.
*
* Arguments
* ==========
*
* UPLO (input) CHARACTER*1
* Specifies whether the upper or lower triangular part of the
* Hermitian matrix A is stored:
* = 'U': Upper triangular
* = 'L': Lower triangular
*
* N (input) INTEGER
* The number of rows and columns of the matrix A. N >= 0.
*
* A (input) COMPLEX*16 array, dimension (N*(N+1)/2)
* The original Hermitian matrix A, stored as a packed
* triangular matrix.
*
* AINV (input) COMPLEX*16 array, dimension (N*(N+1)/2)
* The (Hermitian) inverse of the matrix A, stored as a packed
* triangular matrix.
*
* WORK (workspace) COMPLEX*16 array, dimension (LDWORK,N)
*
* LDWORK (input) INTEGER
* The leading dimension of the array WORK. LDWORK >= max(1,N).
*
* RWORK (workspace) DOUBLE PRECISION array, dimension (N)
*
* RCOND (output) DOUBLE PRECISION
* The reciprocal of the condition number of A, computed as
* ( 1/norm(A) ) / norm(AINV).
*
* RESID (output) DOUBLE PRECISION
* norm(I - A*AINV) / ( N * norm(A) * norm(AINV) * EPS )
*
* =====================================================================
*
* .. Parameters ..
DOUBLE PRECISION ZERO, ONE
PARAMETER ( ZERO = 0.0D+0, ONE = 1.0D+0 )
COMPLEX*16 CZERO, CONE
PARAMETER ( CZERO = ( 0.0D+0, 0.0D+0 ),
$ CONE = ( 1.0D+0, 0.0D+0 ) )
* ..
* .. Local Scalars ..
INTEGER I, J, JJ
DOUBLE PRECISION AINVNM, ANORM, EPS
* ..
* .. External Functions ..
LOGICAL LSAME
DOUBLE PRECISION DLAMCH, ZLANGE, ZLANHP
EXTERNAL LSAME, DLAMCH, ZLANGE, ZLANHP
* ..
* .. Intrinsic Functions ..
INTRINSIC DBLE, DCONJG
* ..
* .. External Subroutines ..
EXTERNAL ZCOPY, ZHPMV
* ..
* .. Executable Statements ..
*
* Quick exit if N = 0.
*
IF( N.LE.0 ) THEN
RCOND = ONE
RESID = ZERO
RETURN
END IF
*
* Exit with RESID = 1/EPS if ANORM = 0 or AINVNM = 0.
*
EPS = DLAMCH( 'Epsilon' )
ANORM = ZLANHP( '1', UPLO, N, A, RWORK )
AINVNM = ZLANHP( '1', UPLO, N, AINV, RWORK )
IF( ANORM.LE.ZERO .OR. AINVNM.LE.ZERO ) THEN
RCOND = ZERO
RESID = ONE / EPS
RETURN
END IF
RCOND = ( ONE / ANORM ) / AINVNM
*
* UPLO = 'U':
* Copy the leading N-1 x N-1 submatrix of AINV to WORK(1:N,2:N) and
* expand it to a full matrix, then multiply by A one column at a
* time, moving the result one column to the left.
*
IF( LSAME( UPLO, 'U' ) ) THEN
*
* Copy AINV
*
JJ = 1
DO 20 J = 1, N - 1
CALL ZCOPY( J, AINV( JJ ), 1, WORK( 1, J+1 ), 1 )
DO 10 I = 1, J - 1
WORK( J, I+1 ) = DCONJG( AINV( JJ+I-1 ) )
10 CONTINUE
JJ = JJ + J
20 CONTINUE
JJ = ( ( N-1 )*N ) / 2 + 1
DO 30 I = 1, N - 1
WORK( N, I+1 ) = DCONJG( AINV( JJ+I-1 ) )
30 CONTINUE
*
* Multiply by A
*
DO 40 J = 1, N - 1
CALL ZHPMV( 'Upper', N, -CONE, A, WORK( 1, J+1 ), 1, CZERO,
$ WORK( 1, J ), 1 )
40 CONTINUE
CALL ZHPMV( 'Upper', N, -CONE, A, AINV( JJ ), 1, CZERO,
$ WORK( 1, N ), 1 )
*
* UPLO = 'L':
* Copy the trailing N-1 x N-1 submatrix of AINV to WORK(1:N,1:N-1)
* and multiply by A, moving each column to the right.
*
ELSE
*
* Copy AINV
*
DO 50 I = 1, N - 1
WORK( 1, I ) = DCONJG( AINV( I+1 ) )
50 CONTINUE
JJ = N + 1
DO 70 J = 2, N
CALL ZCOPY( N-J+1, AINV( JJ ), 1, WORK( J, J-1 ), 1 )
DO 60 I = 1, N - J
WORK( J, J+I-1 ) = DCONJG( AINV( JJ+I ) )
60 CONTINUE
JJ = JJ + N - J + 1
70 CONTINUE
*
* Multiply by A
*
DO 80 J = N, 2, -1
CALL ZHPMV( 'Lower', N, -CONE, A, WORK( 1, J-1 ), 1, CZERO,
$ WORK( 1, J ), 1 )
80 CONTINUE
CALL ZHPMV( 'Lower', N, -CONE, A, AINV( 1 ), 1, CZERO,
$ WORK( 1, 1 ), 1 )
*
END IF
*
* Add the identity matrix to WORK .
*
DO 90 I = 1, N
WORK( I, I ) = WORK( I, I ) + CONE
90 CONTINUE
*
* Compute norm(I - A*AINV) / (N * norm(A) * norm(AINV) * EPS)
*
RESID = ZLANGE( '1', N, N, WORK, LDWORK, RWORK )
*
RESID = ( ( RESID*RCOND ) / EPS ) / DBLE( N )
*
RETURN
*
* End of ZPPT03
*
END
|
