1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
|
DOUBLE PRECISION FUNCTION ZRZT02( M, N, AF, LDA, TAU, WORK,
$ LWORK )
*
* -- LAPACK test routine (version 3.0) --
* Univ. of Tennessee, Univ. of California Berkeley, NAG Ltd.,
* Courant Institute, Argonne National Lab, and Rice University
* June 30, 1999
*
* .. Scalar Arguments ..
INTEGER LDA, LWORK, M, N
* ..
* .. Array Arguments ..
COMPLEX*16 AF( LDA, * ), TAU( * ), WORK( LWORK )
* ..
*
* Purpose
* =======
*
* ZRZT02 returns
* || I - Q'*Q || / ( M * eps)
* where the matrix Q is defined by the Householder transformations
* generated by ZTZRZF.
*
* Arguments
* =========
*
* M (input) INTEGER
* The number of rows of the matrix AF.
*
* N (input) INTEGER
* The number of columns of the matrix AF.
*
* AF (input) COMPLEX*16 array, dimension (LDA,N)
* The output of ZTZRZF.
*
* LDA (input) INTEGER
* The leading dimension of the array AF.
*
* TAU (input) COMPLEX*16 array, dimension (M)
* Details of the Householder transformations as returned by
* ZTZRZF.
*
* WORK (workspace) COMPLEX*16 array, dimension (LWORK)
*
* LWORK (input) INTEGER
* Length of WORK array. LWORK >= N*N+N.
*
* =====================================================================
*
* .. Parameters ..
DOUBLE PRECISION ZERO, ONE
PARAMETER ( ZERO = 0.0D0, ONE = 1.0D0 )
* ..
* .. Local Scalars ..
INTEGER I, INFO
* ..
* .. Local Arrays ..
DOUBLE PRECISION RWORK( 1 )
* ..
* .. External Functions ..
DOUBLE PRECISION DLAMCH, ZLANGE
EXTERNAL DLAMCH, ZLANGE
* ..
* .. External Subroutines ..
EXTERNAL XERBLA, ZLASET, ZUNMRZ
* ..
* .. Intrinsic Functions ..
INTRINSIC DBLE, DCMPLX, MAX
* ..
* .. Executable Statements ..
*
ZRZT02 = ZERO
*
IF( LWORK.LT.N*N+N ) THEN
CALL XERBLA( 'ZRZT02', 7 )
RETURN
END IF
*
* Quick return if possible
*
IF( M.LE.0 .OR. N.LE.0 )
$ RETURN
*
* Q := I
*
CALL ZLASET( 'Full', N, N, DCMPLX( ZERO ), DCMPLX( ONE ), WORK,
$ N )
*
* Q := P(1) * ... * P(m) * Q
*
CALL ZUNMRZ( 'Left', 'No transpose', N, N, M, N-M, AF, LDA, TAU,
$ WORK, N, WORK( N*N+1 ), LWORK-N*N, INFO )
*
* Q := P(m)' * ... * P(1)' * Q
*
CALL ZUNMRZ( 'Left', 'Conjugate transpose', N, N, M, N-M, AF, LDA,
$ TAU, WORK, N, WORK( N*N+1 ), LWORK-N*N, INFO )
*
* Q := Q - I
*
DO 10 I = 1, N
WORK( ( I-1 )*N+I ) = WORK( ( I-1 )*N+I ) - ONE
10 CONTINUE
*
ZRZT02 = ZLANGE( 'One-norm', N, N, WORK, N, RWORK ) /
$ ( DLAMCH( 'Epsilon' )*DBLE( MAX( M, N ) ) )
RETURN
*
* End of ZRZT02
*
END
|
