1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
|
REAL FUNCTION STZT02( M, N, AF, LDA, TAU, WORK,
$ LWORK )
*
* -- LAPACK test routine (version 3.0) --
* Univ. of Tennessee, Univ. of California Berkeley, NAG Ltd.,
* Courant Institute, Argonne National Lab, and Rice University
* September 30, 1994
*
* .. Scalar Arguments ..
INTEGER LDA, LWORK, M, N
* ..
* .. Array Arguments ..
REAL AF( LDA, * ), TAU( * ), WORK( LWORK )
* ..
*
* Purpose
* =======
*
* STZT02 returns
* || I - Q'*Q || / ( M * eps)
* where the matrix Q is defined by the Householder transformations
* generated by STZRQF.
*
* Arguments
* =========
*
* M (input) INTEGER
* The number of rows of the matrix AF.
*
* N (input) INTEGER
* The number of columns of the matrix AF.
*
* AF (input) REAL array, dimension (LDA,N)
* The output of STZRQF.
*
* LDA (input) INTEGER
* The leading dimension of the array AF.
*
* TAU (input) REAL array, dimension (M)
* Details of the Householder transformations as returned by
* STZRQF.
*
* WORK (workspace) REAL array, dimension (LWORK)
*
* LWORK (input) INTEGER
* length of WORK array. Must be >= N*N+N
*
* =====================================================================
*
* .. Parameters ..
REAL ZERO, ONE
PARAMETER ( ZERO = 0.0E0, ONE = 1.0E0 )
* ..
* .. Local Scalars ..
INTEGER I
* ..
* .. Local Arrays ..
REAL RWORK( 1 )
* ..
* .. External Functions ..
REAL SLAMCH, SLANGE
EXTERNAL SLAMCH, SLANGE
* ..
* .. External Subroutines ..
EXTERNAL SLATZM, SLASET, XERBLA
* ..
* .. Intrinsic Functions ..
INTRINSIC MAX, REAL
* ..
* .. Executable Statements ..
*
STZT02 = ZERO
*
IF( LWORK.LT.N*N+N ) THEN
CALL XERBLA( 'STZT02', 7 )
RETURN
END IF
*
* Quick return if possible
*
IF( M.LE.0 .OR. N.LE.0 )
$ RETURN
*
* Q := I
*
CALL SLASET( 'Full', N, N, ZERO, ONE, WORK, N )
*
* Q := P(1) * ... * P(m) * Q
*
DO 10 I = M, 1, -1
CALL SLATZM( 'Left', N-M+1, N, AF( I, M+1 ), LDA, TAU( I ),
$ WORK( I ), WORK( M+1 ), N, WORK( N*N+1 ) )
10 CONTINUE
*
* Q := P(m) * ... * P(1) * Q
*
DO 20 I = 1, M
CALL SLATZM( 'Left', N-M+1, N, AF( I, M+1 ), LDA, TAU( I ),
$ WORK( I ), WORK( M+1 ), N, WORK( N*N+1 ) )
20 CONTINUE
*
* Q := Q - I
*
DO 30 I = 1, N
WORK( ( I-1 )*N+I ) = WORK( ( I-1 )*N+I ) - ONE
30 CONTINUE
*
STZT02 = SLANGE( 'One-norm', N, N, WORK, N, RWORK ) /
$ ( SLAMCH( 'Epsilon' )*REAL( MAX( M, N ) ) )
RETURN
*
* End of STZT02
*
END
|
