1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
|
SUBROUTINE ZGERQS( M, N, NRHS, A, LDA, TAU, B, LDB, WORK, LWORK,
$ INFO )
*
* -- LAPACK routine (version 3.0) --
* Univ. of Tennessee, Univ. of California Berkeley, NAG Ltd.,
* Courant Institute, Argonne National Lab, and Rice University
* September 30, 1994
*
* .. Scalar Arguments ..
INTEGER INFO, LDA, LDB, LWORK, M, N, NRHS
* ..
* .. Array Arguments ..
COMPLEX*16 A( LDA, * ), B( LDB, * ), TAU( * ),
$ WORK( LWORK )
* ..
*
* Purpose
* =======
*
* Compute a minimum-norm solution
* min || A*X - B ||
* using the RQ factorization
* A = R*Q
* computed by ZGERQF.
*
* Arguments
* =========
*
* M (input) INTEGER
* The number of rows of the matrix A. M >= 0.
*
* N (input) INTEGER
* The number of columns of the matrix A. N >= M >= 0.
*
* NRHS (input) INTEGER
* The number of columns of B. NRHS >= 0.
*
* A (input) COMPLEX*16 array, dimension (LDA,N)
* Details of the RQ factorization of the original matrix A as
* returned by ZGERQF.
*
* LDA (input) INTEGER
* The leading dimension of the array A. LDA >= M.
*
* TAU (input) COMPLEX*16 array, dimension (M)
* Details of the orthogonal matrix Q.
*
* B (input/output) COMPLEX*16 array, dimension (LDB,NRHS)
* On entry, the right hand side vectors for the linear system.
* On exit, the solution vectors X. Each solution vector
* is contained in rows 1:N of a column of B.
*
* LDB (input) INTEGER
* The leading dimension of the array B. LDB >= max(1,N).
*
* WORK (workspace) COMPLEX*16 array, dimension (LWORK)
*
* LWORK (input) INTEGER
* The length of the array WORK. LWORK must be at least NRHS,
* and should be at least NRHS*NB, where NB is the block size
* for this environment.
*
* INFO (output) INTEGER
* = 0: successful exit
* < 0: if INFO = -i, the i-th argument had an illegal value
*
* =====================================================================
*
* .. Parameters ..
COMPLEX*16 CZERO, CONE
PARAMETER ( CZERO = ( 0.0D+0, 0.0D+0 ),
$ CONE = ( 1.0D+0, 0.0D+0 ) )
* ..
* .. External Subroutines ..
EXTERNAL XERBLA, ZLASET, ZTRSM, ZUNMRQ
* ..
* .. Intrinsic Functions ..
INTRINSIC MAX
* ..
* .. Executable Statements ..
*
* Test the input parameters.
*
INFO = 0
IF( M.LT.0 ) THEN
INFO = -1
ELSE IF( N.LT.0 .OR. M.GT.N ) THEN
INFO = -2
ELSE IF( NRHS.LT.0 ) THEN
INFO = -3
ELSE IF( LDA.LT.MAX( 1, M ) ) THEN
INFO = -5
ELSE IF( LDB.LT.MAX( 1, N ) ) THEN
INFO = -8
ELSE IF( LWORK.LT.1 .OR. LWORK.LT.NRHS .AND. M.GT.0 .AND. N.GT.0 )
$ THEN
INFO = -10
END IF
IF( INFO.NE.0 ) THEN
CALL XERBLA( 'ZGERQS', -INFO )
RETURN
END IF
*
* Quick return if possible
*
IF( N.EQ.0 .OR. NRHS.EQ.0 .OR. M.EQ.0 )
$ RETURN
*
* Solve R*X = B(n-m+1:n,:)
*
CALL ZTRSM( 'Left', 'Upper', 'No transpose', 'Non-unit', M, NRHS,
$ CONE, A( 1, N-M+1 ), LDA, B( N-M+1, 1 ), LDB )
*
* Set B(1:n-m,:) to zero
*
CALL ZLASET( 'Full', N-M, NRHS, CZERO, CZERO, B, LDB )
*
* B := Q' * B
*
CALL ZUNMRQ( 'Left', 'Conjugate transpose', N, NRHS, M, A, LDA,
$ TAU, B, LDB, WORK, LWORK, INFO )
*
RETURN
*
* End of ZGERQS
*
END
|
