1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
|
REAL FUNCTION CQRT11( M, K, A, LDA, TAU, WORK, LWORK )
*
* -- LAPACK routine (version 3.0) --
* Univ. of Tennessee, Univ. of California Berkeley, NAG Ltd.,
* Courant Institute, Argonne National Lab, and Rice University
* September 30, 1994
*
* .. Scalar Arguments ..
INTEGER K, LDA, LWORK, M
* ..
* .. Array Arguments ..
COMPLEX A( LDA, * ), TAU( * ), WORK( LWORK )
* ..
*
* Purpose
* =======
*
* CQRT11 computes the test ratio
*
* || Q'*Q - I || / (eps * m)
*
* where the orthogonal matrix Q is represented as a product of
* elementary transformations. Each transformation has the form
*
* H(k) = I - tau(k) v(k) v(k)'
*
* where tau(k) is stored in TAU(k) and v(k) is an m-vector of the form
* [ 0 ... 0 1 x(k) ]', where x(k) is a vector of length m-k stored
* in A(k+1:m,k).
*
* Arguments
* =========
*
* M (input) INTEGER
* The number of rows of the matrix A.
*
* K (input) INTEGER
* The number of columns of A whose subdiagonal entries
* contain information about orthogonal transformations.
*
* A (input) COMPLEX array, dimension (LDA,K)
* The (possibly partial) output of a QR reduction routine.
*
* LDA (input) INTEGER
* The leading dimension of the array A.
*
* TAU (input) COMPLEX array, dimension (K)
* The scaling factors tau for the elementary transformations as
* computed by the QR factorization routine.
*
* WORK (workspace) COMPLEX array, dimension (LWORK)
*
* LWORK (input) INTEGER
* The length of the array WORK. LWORK >= M*M + M.
*
* =====================================================================
*
* .. Parameters ..
REAL ZERO, ONE
PARAMETER ( ZERO = 0.0E0, ONE = 1.0E0 )
* ..
* .. Local Scalars ..
INTEGER INFO, J
* ..
* .. External Functions ..
REAL CLANGE, SLAMCH
EXTERNAL CLANGE, SLAMCH
* ..
* .. External Subroutines ..
EXTERNAL CLASET, CUNM2R, XERBLA
* ..
* .. Intrinsic Functions ..
INTRINSIC CMPLX, REAL
* ..
* .. Local Arrays ..
REAL RDUMMY( 1 )
* ..
* .. Executable Statements ..
*
CQRT11 = ZERO
*
* Test for sufficient workspace
*
IF( LWORK.LT.M*M+M ) THEN
CALL XERBLA( 'CQRT11', 7 )
RETURN
END IF
*
* Quick return if possible
*
IF( M.LE.0 )
$ RETURN
*
CALL CLASET( 'Full', M, M, CMPLX( ZERO ), CMPLX( ONE ), WORK, M )
*
* Form Q
*
CALL CUNM2R( 'Left', 'No transpose', M, M, K, A, LDA, TAU, WORK,
$ M, WORK( M*M+1 ), INFO )
*
* Form Q'*Q
*
CALL CUNM2R( 'Left', 'Conjugate transpose', M, M, K, A, LDA, TAU,
$ WORK, M, WORK( M*M+1 ), INFO )
*
DO 10 J = 1, M
WORK( ( J-1 )*M+J ) = WORK( ( J-1 )*M+J ) - ONE
10 CONTINUE
*
CQRT11 = CLANGE( 'One-norm', M, M, WORK, M, RDUMMY ) /
$ ( REAL( M )*SLAMCH( 'Epsilon' ) )
*
RETURN
*
* End of CQRT11
*
END
|
