1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162
163
164
165
166
167
168
169
170
171
172
173
174
175
176
177
178
179
180
181
182
183
184
185
186
187
188
189
190
191
192
193
194
195
196
197
198
199
200
201
202
203
204
205
206
207
208
209
210
211
212
213
214
215
216
217
218
219
220
221
222
223
224
225
226
227
228
229
230
231
232
233
|
SUBROUTINE CQRT15( SCALE, RKSEL, M, N, NRHS, A, LDA, B, LDB, S,
$ RANK, NORMA, NORMB, ISEED, WORK, LWORK )
*
* -- LAPACK test routine (version 3.0) --
* Univ. of Tennessee, Univ. of California Berkeley, NAG Ltd.,
* Courant Institute, Argonne National Lab, and Rice University
* September 30, 1994
*
* .. Scalar Arguments ..
INTEGER LDA, LDB, LWORK, M, N, NRHS, RANK, RKSEL, SCALE
REAL NORMA, NORMB
* ..
* .. Array Arguments ..
INTEGER ISEED( 4 )
REAL S( * )
COMPLEX A( LDA, * ), B( LDB, * ), WORK( LWORK )
* ..
*
* Purpose
* =======
*
* CQRT15 generates a matrix with full or deficient rank and of various
* norms.
*
* Arguments
* =========
*
* SCALE (input) INTEGER
* SCALE = 1: normally scaled matrix
* SCALE = 2: matrix scaled up
* SCALE = 3: matrix scaled down
*
* RKSEL (input) INTEGER
* RKSEL = 1: full rank matrix
* RKSEL = 2: rank-deficient matrix
*
* M (input) INTEGER
* The number of rows of the matrix A.
*
* N (input) INTEGER
* The number of columns of A.
*
* NRHS (input) INTEGER
* The number of columns of B.
*
* A (output) COMPLEX array, dimension (LDA,N)
* The M-by-N matrix A.
*
* LDA (input) INTEGER
* The leading dimension of the array A.
*
* B (output) COMPLEX array, dimension (LDB, NRHS)
* A matrix that is in the range space of matrix A.
*
* LDB (input) INTEGER
* The leading dimension of the array B.
*
* S (output) REAL array, dimension MIN(M,N)
* Singular values of A.
*
* RANK (output) INTEGER
* number of nonzero singular values of A.
*
* NORMA (output) REAL
* one-norm norm of A.
*
* NORMB (output) REAL
* one-norm norm of B.
*
* ISEED (input/output) integer array, dimension (4)
* seed for random number generator.
*
* WORK (workspace) COMPLEX array, dimension (LWORK)
*
* LWORK (input) INTEGER
* length of work space required.
* LWORK >= MAX(M+MIN(M,N),NRHS*MIN(M,N),2*N+M)
*
* =====================================================================
*
* .. Parameters ..
REAL ZERO, ONE, TWO, SVMIN
PARAMETER ( ZERO = 0.0E+0, ONE = 1.0E+0, TWO = 2.0E+0,
$ SVMIN = 0.1E+0 )
COMPLEX CZERO, CONE
PARAMETER ( CZERO = ( 0.0E+0, 0.0E+0 ),
$ CONE = ( 1.0E+0, 0.0E+0 ) )
* ..
* .. Local Scalars ..
INTEGER INFO, J, MN
REAL BIGNUM, EPS, SMLNUM, TEMP
* ..
* .. Local Arrays ..
REAL DUMMY( 1 )
* ..
* .. External Functions ..
REAL CLANGE, SASUM, SCNRM2, SLAMCH, SLARND
EXTERNAL CLANGE, SASUM, SCNRM2, SLAMCH, SLARND
* ..
* .. External Subroutines ..
EXTERNAL CGEMM, CLARF, CLARNV, CLAROR, CLASCL, CLASET,
$ CSSCAL, SLABAD, SLAORD, SLASCL, XERBLA
* ..
* .. Intrinsic Functions ..
INTRINSIC ABS, CMPLX, MAX, MIN
* ..
* .. Executable Statements ..
*
MN = MIN( M, N )
IF( LWORK.LT.MAX( M+MN, MN*NRHS, 2*N+M ) ) THEN
CALL XERBLA( 'CQRT15', 16 )
RETURN
END IF
*
SMLNUM = SLAMCH( 'Safe minimum' )
BIGNUM = ONE / SMLNUM
CALL SLABAD( SMLNUM, BIGNUM )
EPS = SLAMCH( 'Epsilon' )
SMLNUM = ( SMLNUM / EPS ) / EPS
BIGNUM = ONE / SMLNUM
*
* Determine rank and (unscaled) singular values
*
IF( RKSEL.EQ.1 ) THEN
RANK = MN
ELSE IF( RKSEL.EQ.2 ) THEN
RANK = ( 3*MN ) / 4
DO 10 J = RANK + 1, MN
S( J ) = ZERO
10 CONTINUE
ELSE
CALL XERBLA( 'CQRT15', 2 )
END IF
*
IF( RANK.GT.0 ) THEN
*
* Nontrivial case
*
S( 1 ) = ONE
DO 30 J = 2, RANK
20 CONTINUE
TEMP = SLARND( 1, ISEED )
IF( TEMP.GT.SVMIN ) THEN
S( J ) = ABS( TEMP )
ELSE
GO TO 20
END IF
30 CONTINUE
CALL SLAORD( 'Decreasing', RANK, S, 1 )
*
* Generate 'rank' columns of a random orthogonal matrix in A
*
CALL CLARNV( 2, ISEED, M, WORK )
CALL CSSCAL( M, ONE / SCNRM2( M, WORK, 1 ), WORK, 1 )
CALL CLASET( 'Full', M, RANK, CZERO, CONE, A, LDA )
CALL CLARF( 'Left', M, RANK, WORK, 1, CMPLX( TWO ), A, LDA,
$ WORK( M+1 ) )
*
* workspace used: m+mn
*
* Generate consistent rhs in the range space of A
*
CALL CLARNV( 2, ISEED, RANK*NRHS, WORK )
CALL CGEMM( 'No transpose', 'No transpose', M, NRHS, RANK,
$ CONE, A, LDA, WORK, RANK, CZERO, B, LDB )
*
* work space used: <= mn *nrhs
*
* generate (unscaled) matrix A
*
DO 40 J = 1, RANK
CALL CSSCAL( M, S( J ), A( 1, J ), 1 )
40 CONTINUE
IF( RANK.LT.N )
$ CALL CLASET( 'Full', M, N-RANK, CZERO, CZERO,
$ A( 1, RANK+1 ), LDA )
CALL CLAROR( 'Right', 'No initialization', M, N, A, LDA, ISEED,
$ WORK, INFO )
*
ELSE
*
* work space used 2*n+m
*
* Generate null matrix and rhs
*
DO 50 J = 1, MN
S( J ) = ZERO
50 CONTINUE
CALL CLASET( 'Full', M, N, CZERO, CZERO, A, LDA )
CALL CLASET( 'Full', M, NRHS, CZERO, CZERO, B, LDB )
*
END IF
*
* Scale the matrix
*
IF( SCALE.NE.1 ) THEN
NORMA = CLANGE( 'Max', M, N, A, LDA, DUMMY )
IF( NORMA.NE.ZERO ) THEN
IF( SCALE.EQ.2 ) THEN
*
* matrix scaled up
*
CALL CLASCL( 'General', 0, 0, NORMA, BIGNUM, M, N, A,
$ LDA, INFO )
CALL SLASCL( 'General', 0, 0, NORMA, BIGNUM, MN, 1, S,
$ MN, INFO )
CALL CLASCL( 'General', 0, 0, NORMA, BIGNUM, M, NRHS, B,
$ LDB, INFO )
ELSE IF( SCALE.EQ.3 ) THEN
*
* matrix scaled down
*
CALL CLASCL( 'General', 0, 0, NORMA, SMLNUM, M, N, A,
$ LDA, INFO )
CALL SLASCL( 'General', 0, 0, NORMA, SMLNUM, MN, 1, S,
$ MN, INFO )
CALL CLASCL( 'General', 0, 0, NORMA, SMLNUM, M, NRHS, B,
$ LDB, INFO )
ELSE
CALL XERBLA( 'CQRT15', 1 )
RETURN
END IF
END IF
END IF
*
NORMA = SASUM( MN, S, 1 )
NORMB = CLANGE( 'One-norm', M, NRHS, B, LDB, DUMMY )
*
RETURN
*
* End of CQRT15
*
END
|
