1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162
163
164
165
166
167
168
169
170
171
172
173
174
175
176
|
SUBROUTINE DRQT01( M, N, A, AF, Q, R, LDA, TAU, WORK, LWORK,
$ RWORK, RESULT )
*
* -- LAPACK test routine (version 3.0) --
* Univ. of Tennessee, Univ. of California Berkeley, NAG Ltd.,
* Courant Institute, Argonne National Lab, and Rice University
* September 30, 1994
*
* .. Scalar Arguments ..
INTEGER LDA, LWORK, M, N
* ..
* .. Array Arguments ..
DOUBLE PRECISION A( LDA, * ), AF( LDA, * ), Q( LDA, * ),
$ R( LDA, * ), RESULT( * ), RWORK( * ), TAU( * ),
$ WORK( LWORK )
* ..
*
* Purpose
* =======
*
* DRQT01 tests DGERQF, which computes the RQ factorization of an m-by-n
* matrix A, and partially tests DORGRQ which forms the n-by-n
* orthogonal matrix Q.
*
* DRQT01 compares R with A*Q', and checks that Q is orthogonal.
*
* Arguments
* =========
*
* M (input) INTEGER
* The number of rows of the matrix A. M >= 0.
*
* N (input) INTEGER
* The number of columns of the matrix A. N >= 0.
*
* A (input) DOUBLE PRECISION array, dimension (LDA,N)
* The m-by-n matrix A.
*
* AF (output) DOUBLE PRECISION array, dimension (LDA,N)
* Details of the RQ factorization of A, as returned by DGERQF.
* See DGERQF for further details.
*
* Q (output) DOUBLE PRECISION array, dimension (LDA,N)
* The n-by-n orthogonal matrix Q.
*
* R (workspace) DOUBLE PRECISION array, dimension (LDA,max(M,N))
*
* LDA (input) INTEGER
* The leading dimension of the arrays A, AF, Q and L.
* LDA >= max(M,N).
*
* TAU (output) DOUBLE PRECISION array, dimension (min(M,N))
* The scalar factors of the elementary reflectors, as returned
* by DGERQF.
*
* WORK (workspace) DOUBLE PRECISION array, dimension (LWORK)
*
* LWORK (input) INTEGER
* The dimension of the array WORK.
*
* RWORK (workspace) DOUBLE PRECISION array, dimension (max(M,N))
*
* RESULT (output) DOUBLE PRECISION array, dimension (2)
* The test ratios:
* RESULT(1) = norm( R - A*Q' ) / ( N * norm(A) * EPS )
* RESULT(2) = norm( I - Q*Q' ) / ( N * EPS )
*
* =====================================================================
*
* .. Parameters ..
DOUBLE PRECISION ZERO, ONE
PARAMETER ( ZERO = 0.0D+0, ONE = 1.0D+0 )
DOUBLE PRECISION ROGUE
PARAMETER ( ROGUE = -1.0D+10 )
* ..
* .. Local Scalars ..
INTEGER INFO, MINMN
DOUBLE PRECISION ANORM, EPS, RESID
* ..
* .. External Functions ..
DOUBLE PRECISION DLAMCH, DLANGE, DLANSY
EXTERNAL DLAMCH, DLANGE, DLANSY
* ..
* .. External Subroutines ..
EXTERNAL DGEMM, DGERQF, DLACPY, DLASET, DORGRQ, DSYRK
* ..
* .. Intrinsic Functions ..
INTRINSIC DBLE, MAX, MIN
* ..
* .. Scalars in Common ..
CHARACTER*6 SRNAMT
* ..
* .. Common blocks ..
COMMON / SRNAMC / SRNAMT
* ..
* .. Executable Statements ..
*
MINMN = MIN( M, N )
EPS = DLAMCH( 'Epsilon' )
*
* Copy the matrix A to the array AF.
*
CALL DLACPY( 'Full', M, N, A, LDA, AF, LDA )
*
* Factorize the matrix A in the array AF.
*
SRNAMT = 'DGERQF'
CALL DGERQF( M, N, AF, LDA, TAU, WORK, LWORK, INFO )
*
* Copy details of Q
*
CALL DLASET( 'Full', N, N, ROGUE, ROGUE, Q, LDA )
IF( M.LE.N ) THEN
IF( M.GT.0 .AND. M.LT.N )
$ CALL DLACPY( 'Full', M, N-M, AF, LDA, Q( N-M+1, 1 ), LDA )
IF( M.GT.1 )
$ CALL DLACPY( 'Lower', M-1, M-1, AF( 2, N-M+1 ), LDA,
$ Q( N-M+2, N-M+1 ), LDA )
ELSE
IF( N.GT.1 )
$ CALL DLACPY( 'Lower', N-1, N-1, AF( M-N+2, 1 ), LDA,
$ Q( 2, 1 ), LDA )
END IF
*
* Generate the n-by-n matrix Q
*
SRNAMT = 'DORGRQ'
CALL DORGRQ( N, N, MINMN, Q, LDA, TAU, WORK, LWORK, INFO )
*
* Copy R
*
CALL DLASET( 'Full', M, N, ZERO, ZERO, R, LDA )
IF( M.LE.N ) THEN
IF( M.GT.0 )
$ CALL DLACPY( 'Upper', M, M, AF( 1, N-M+1 ), LDA,
$ R( 1, N-M+1 ), LDA )
ELSE
IF( M.GT.N .AND. N.GT.0 )
$ CALL DLACPY( 'Full', M-N, N, AF, LDA, R, LDA )
IF( N.GT.0 )
$ CALL DLACPY( 'Upper', N, N, AF( M-N+1, 1 ), LDA,
$ R( M-N+1, 1 ), LDA )
END IF
*
* Compute R - A*Q'
*
CALL DGEMM( 'No transpose', 'Transpose', M, N, N, -ONE, A, LDA, Q,
$ LDA, ONE, R, LDA )
*
* Compute norm( R - Q'*A ) / ( N * norm(A) * EPS ) .
*
ANORM = DLANGE( '1', M, N, A, LDA, RWORK )
RESID = DLANGE( '1', M, N, R, LDA, RWORK )
IF( ANORM.GT.ZERO ) THEN
RESULT( 1 ) = ( ( RESID / DBLE( MAX( 1, N ) ) ) / ANORM ) / EPS
ELSE
RESULT( 1 ) = ZERO
END IF
*
* Compute I - Q*Q'
*
CALL DLASET( 'Full', N, N, ZERO, ONE, R, LDA )
CALL DSYRK( 'Upper', 'No transpose', N, N, -ONE, Q, LDA, ONE, R,
$ LDA )
*
* Compute norm( I - Q*Q' ) / ( N * EPS ) .
*
RESID = DLANSY( '1', 'Upper', N, R, LDA, RWORK )
*
RESULT( 2 ) = ( RESID / DBLE( MAX( 1, N ) ) ) / EPS
*
RETURN
*
* End of DRQT01
*
END
|
