1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
|
SUBROUTINE SGTT02( TRANS, N, NRHS, DL, D, DU, X, LDX, B, LDB,
$ RWORK, RESID )
*
* -- LAPACK test routine (version 3.0) --
* Univ. of Tennessee, Univ. of California Berkeley, NAG Ltd.,
* Courant Institute, Argonne National Lab, and Rice University
* February 29, 1992
*
* .. Scalar Arguments ..
CHARACTER TRANS
INTEGER LDB, LDX, N, NRHS
REAL RESID
* ..
* .. Array Arguments ..
REAL B( LDB, * ), D( * ), DL( * ), DU( * ),
$ RWORK( * ), X( LDX, * )
* ..
*
* Purpose
* =======
*
* SGTT02 computes the residual for the solution to a tridiagonal
* system of equations:
* RESID = norm(B - op(A)*X) / (norm(A) * norm(X) * EPS),
* where EPS is the machine epsilon.
*
* Arguments
* =========
*
* TRANS (input) CHARACTER
* Specifies the form of the residual.
* = 'N': B - A * X (No transpose)
* = 'T': B - A'* X (Transpose)
* = 'C': B - A'* X (Conjugate transpose = Transpose)
*
* N (input) INTEGTER
* The order of the matrix A. N >= 0.
*
* NRHS (input) INTEGER
* The number of right hand sides, i.e., the number of columns
* of the matrices B and X. NRHS >= 0.
*
* DL (input) REAL array, dimension (N-1)
* The (n-1) sub-diagonal elements of A.
*
* D (input) REAL array, dimension (N)
* The diagonal elements of A.
*
* DU (input) REAL array, dimension (N-1)
* The (n-1) super-diagonal elements of A.
*
* X (input) REAL array, dimension (LDX,NRHS)
* The computed solution vectors X.
*
* LDX (input) INTEGER
* The leading dimension of the array X. LDX >= max(1,N).
*
* B (input/output) REAL array, dimension (LDB,NRHS)
* On entry, the right hand side vectors for the system of
* linear equations.
* On exit, B is overwritten with the difference B - op(A)*X.
*
* LDB (input) INTEGER
* The leading dimension of the array B. LDB >= max(1,N).
*
* RWORK (workspace) REAL array, dimension (N)
*
* RESID (output) REAL
* norm(B - op(A)*X) / (norm(A) * norm(X) * EPS)
*
* =====================================================================
*
* .. Parameters ..
REAL ONE, ZERO
PARAMETER ( ONE = 1.0E+0, ZERO = 0.0E+0 )
* ..
* .. Local Scalars ..
INTEGER J
REAL ANORM, BNORM, EPS, XNORM
* ..
* .. External Functions ..
LOGICAL LSAME
REAL SASUM, SLAMCH, SLANGT
EXTERNAL LSAME, SASUM, SLAMCH, SLANGT
* ..
* .. External Subroutines ..
EXTERNAL SLAGTM
* ..
* .. Intrinsic Functions ..
INTRINSIC MAX
* ..
* .. Executable Statements ..
*
* Quick exit if N = 0 or NRHS = 0
*
RESID = ZERO
IF( N.LE.0 .OR. NRHS.EQ.0 )
$ RETURN
*
* Compute the maximum over the number of right hand sides of
* norm(B - op(A)*X) / ( norm(A) * norm(X) * EPS ).
*
IF( LSAME( TRANS, 'N' ) ) THEN
ANORM = SLANGT( '1', N, DL, D, DU )
ELSE
ANORM = SLANGT( 'I', N, DL, D, DU )
END IF
*
* Exit with RESID = 1/EPS if ANORM = 0.
*
EPS = SLAMCH( 'Epsilon' )
IF( ANORM.LE.ZERO ) THEN
RESID = ONE / EPS
RETURN
END IF
*
* Compute B - op(A)*X.
*
CALL SLAGTM( TRANS, N, NRHS, -ONE, DL, D, DU, X, LDX, ONE, B,
$ LDB )
*
DO 10 J = 1, NRHS
BNORM = SASUM( N, B( 1, J ), 1 )
XNORM = SASUM( N, X( 1, J ), 1 )
IF( XNORM.LE.ZERO ) THEN
RESID = ONE / EPS
ELSE
RESID = MAX( RESID, ( ( BNORM / ANORM ) / XNORM ) / EPS )
END IF
10 CONTINUE
*
RETURN
*
* End of SGTT02
*
END
|
