1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
|
SUBROUTINE SQRT16( TRANS, M, N, NRHS, A, LDA, X, LDX, B, LDB,
$ RWORK, RESID )
*
* -- LAPACK test routine (version 3.0) --
* Univ. of Tennessee, Univ. of California Berkeley, NAG Ltd.,
* Courant Institute, Argonne National Lab, and Rice University
* February 29, 1992
*
* .. Scalar Arguments ..
CHARACTER TRANS
INTEGER LDA, LDB, LDX, M, N, NRHS
REAL RESID
* ..
* .. Array Arguments ..
REAL A( LDA, * ), B( LDB, * ), RWORK( * ),
$ X( LDX, * )
* ..
*
* Purpose
* =======
*
* SQRT16 computes the residual for a solution of a system of linear
* equations A*x = b or A'*x = b:
* RESID = norm(B - A*X) / ( max(m,n) * norm(A) * norm(X) * EPS ),
* where EPS is the machine epsilon.
*
* Arguments
* =========
*
* TRANS (input) CHARACTER*1
* Specifies the form of the system of equations:
* = 'N': A *x = b
* = 'T': A'*x = b, where A' is the transpose of A
* = 'C': A'*x = b, where A' is the transpose of A
*
* M (input) INTEGER
* The number of rows of the matrix A. M >= 0.
*
* N (input) INTEGER
* The number of columns of the matrix A. N >= 0.
*
* NRHS (input) INTEGER
* The number of columns of B, the matrix of right hand sides.
* NRHS >= 0.
*
* A (input) REAL array, dimension (LDA,N)
* The original M x N matrix A.
*
* LDA (input) INTEGER
* The leading dimension of the array A. LDA >= max(1,M).
*
* X (input) REAL array, dimension (LDX,NRHS)
* The computed solution vectors for the system of linear
* equations.
*
* LDX (input) INTEGER
* The leading dimension of the array X. If TRANS = 'N',
* LDX >= max(1,N); if TRANS = 'T' or 'C', LDX >= max(1,M).
*
* B (input/output) REAL array, dimension (LDB,NRHS)
* On entry, the right hand side vectors for the system of
* linear equations.
* On exit, B is overwritten with the difference B - A*X.
*
* LDB (input) INTEGER
* The leading dimension of the array B. IF TRANS = 'N',
* LDB >= max(1,M); if TRANS = 'T' or 'C', LDB >= max(1,N).
*
* RWORK (workspace) REAL array, dimension (M)
*
* RESID (output) REAL
* The maximum over the number of right hand sides of
* norm(B - A*X) / ( max(m,n) * norm(A) * norm(X) * EPS ).
*
* =====================================================================
*
* .. Parameters ..
REAL ZERO, ONE
PARAMETER ( ZERO = 0.0E+0, ONE = 1.0E+0 )
* ..
* .. Local Scalars ..
INTEGER J, N1, N2
REAL ANORM, BNORM, EPS, XNORM
* ..
* .. External Functions ..
LOGICAL LSAME
REAL SASUM, SLAMCH, SLANGE
EXTERNAL LSAME, SASUM, SLAMCH, SLANGE
* ..
* .. External Subroutines ..
EXTERNAL SGEMM
* ..
* .. Intrinsic Functions ..
INTRINSIC MAX
* ..
* .. Executable Statements ..
*
* Quick exit if M = 0 or N = 0 or NRHS = 0
*
IF( M.LE.0 .OR. N.LE.0 .OR. NRHS.EQ.0 ) THEN
RESID = ZERO
RETURN
END IF
*
IF( LSAME( TRANS, 'T' ) .OR. LSAME( TRANS, 'C' ) ) THEN
ANORM = SLANGE( 'I', M, N, A, LDA, RWORK )
N1 = N
N2 = M
ELSE
ANORM = SLANGE( '1', M, N, A, LDA, RWORK )
N1 = M
N2 = N
END IF
*
EPS = SLAMCH( 'Epsilon' )
*
* Compute B - A*X (or B - A'*X ) and store in B.
*
CALL SGEMM( TRANS, 'No transpose', N1, NRHS, N2, -ONE, A, LDA, X,
$ LDX, ONE, B, LDB )
*
* Compute the maximum over the number of right hand sides of
* norm(B - A*X) / ( max(m,n) * norm(A) * norm(X) * EPS ) .
*
RESID = ZERO
DO 10 J = 1, NRHS
BNORM = SASUM( N1, B( 1, J ), 1 )
XNORM = SASUM( N2, X( 1, J ), 1 )
IF( ANORM.EQ.ZERO .AND. BNORM.EQ.ZERO ) THEN
RESID = ZERO
ELSE IF( ANORM.LE.ZERO .OR. XNORM.LE.ZERO ) THEN
RESID = ONE / EPS
ELSE
RESID = MAX( RESID, ( ( BNORM / ANORM ) / XNORM ) /
$ ( MAX( M, N )*EPS ) )
END IF
10 CONTINUE
*
RETURN
*
* End of SQRT16
*
END
|
