1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
|
SUBROUTINE SSPT01( UPLO, N, A, AFAC, IPIV, C, LDC, RWORK, RESID )
*
* -- LAPACK test routine (version 3.0) --
* Univ. of Tennessee, Univ. of California Berkeley, NAG Ltd.,
* Courant Institute, Argonne National Lab, and Rice University
* September 30, 1994
*
* .. Scalar Arguments ..
CHARACTER UPLO
INTEGER LDC, N
REAL RESID
* ..
* .. Array Arguments ..
INTEGER IPIV( * )
REAL A( * ), AFAC( * ), C( LDC, * ), RWORK( * )
* ..
*
* Purpose
* =======
*
* SSPT01 reconstructs a symmetric indefinite packed matrix A from its
* block L*D*L' or U*D*U' factorization and computes the residual
* norm( C - A ) / ( N * norm(A) * EPS ),
* where C is the reconstructed matrix and EPS is the machine epsilon.
*
* Arguments
* ==========
*
* UPLO (input) CHARACTER*1
* Specifies whether the upper or lower triangular part of the
* symmetric matrix A is stored:
* = 'U': Upper triangular
* = 'L': Lower triangular
*
* N (input) INTEGER
* The number of rows and columns of the matrix A. N >= 0.
*
* A (input) REAL array, dimension (N*(N+1)/2)
* The original symmetric matrix A, stored as a packed
* triangular matrix.
*
* AFAC (input) REAL array, dimension (N*(N+1)/2)
* The factored form of the matrix A, stored as a packed
* triangular matrix. AFAC contains the block diagonal matrix D
* and the multipliers used to obtain the factor L or U from the
* block L*D*L' or U*D*U' factorization as computed by SSPTRF.
*
* IPIV (input) INTEGER array, dimension (N)
* The pivot indices from SSPTRF.
*
* C (workspace) REAL array, dimension (LDC,N)
*
* LDC (integer) INTEGER
* The leading dimension of the array C. LDC >= max(1,N).
*
* RWORK (workspace) REAL array, dimension (N)
*
* RESID (output) REAL
* If UPLO = 'L', norm(L*D*L' - A) / ( N * norm(A) * EPS )
* If UPLO = 'U', norm(U*D*U' - A) / ( N * norm(A) * EPS )
*
* =====================================================================
*
* .. Parameters ..
REAL ZERO, ONE
PARAMETER ( ZERO = 0.0E+0, ONE = 1.0E+0 )
* ..
* .. Local Scalars ..
INTEGER I, INFO, J, JC
REAL ANORM, EPS
* ..
* .. External Functions ..
LOGICAL LSAME
REAL SLAMCH, SLANSP, SLANSY
EXTERNAL LSAME, SLAMCH, SLANSP, SLANSY
* ..
* .. External Subroutines ..
EXTERNAL SLAVSP, SLASET
* ..
* .. Intrinsic Functions ..
INTRINSIC REAL
* ..
* .. Executable Statements ..
*
* Quick exit if N = 0.
*
IF( N.LE.0 ) THEN
RESID = ZERO
RETURN
END IF
*
* Determine EPS and the norm of A.
*
EPS = SLAMCH( 'Epsilon' )
ANORM = SLANSP( '1', UPLO, N, A, RWORK )
*
* Initialize C to the identity matrix.
*
CALL SLASET( 'Full', N, N, ZERO, ONE, C, LDC )
*
* Call SLAVSP to form the product D * U' (or D * L' ).
*
CALL SLAVSP( UPLO, 'Transpose', 'Non-unit', N, N, AFAC, IPIV, C,
$ LDC, INFO )
*
* Call SLAVSP again to multiply by U ( or L ).
*
CALL SLAVSP( UPLO, 'No transpose', 'Unit', N, N, AFAC, IPIV, C,
$ LDC, INFO )
*
* Compute the difference C - A .
*
IF( LSAME( UPLO, 'U' ) ) THEN
JC = 0
DO 20 J = 1, N
DO 10 I = 1, J
C( I, J ) = C( I, J ) - A( JC+I )
10 CONTINUE
JC = JC + J
20 CONTINUE
ELSE
JC = 1
DO 40 J = 1, N
DO 30 I = J, N
C( I, J ) = C( I, J ) - A( JC+I-J )
30 CONTINUE
JC = JC + N - J + 1
40 CONTINUE
END IF
*
* Compute norm( C - A ) / ( N * norm(A) * EPS )
*
RESID = SLANSY( '1', UPLO, N, C, LDC, RWORK )
*
IF( ANORM.LE.ZERO ) THEN
IF( RESID.NE.ZERO )
$ RESID = ONE / EPS
ELSE
RESID = ( ( RESID / REAL( N ) ) / ANORM ) / EPS
END IF
*
RETURN
*
* End of SSPT01
*
END
|
