1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162
163
164
165
166
167
168
169
170
171
172
173
174
175
176
177
178
179
180
181
182
183
184
185
186
187
188
189
190
191
192
193
194
195
196
197
198
199
200
201
202
203
204
205
206
207
208
209
210
211
212
213
214
215
216
217
218
219
220
221
222
223
224
225
226
227
228
229
230
231
232
233
234
235
236
237
238
239
240
241
242
243
244
245
246
247
248
249
250
251
252
253
254
255
256
257
258
259
260
261
262
263
264
265
266
267
268
269
270
271
272
273
274
275
276
277
278
279
280
281
282
283
284
285
286
287
288
289
290
291
292
293
294
295
296
297
298
299
300
301
302
303
304
305
306
307
308
309
310
311
312
313
314
315
316
317
318
319
320
321
322
323
324
325
326
327
328
329
330
331
332
333
334
335
336
337
338
339
340
341
342
343
344
345
346
347
348
349
350
351
352
353
354
355
356
357
358
359
360
361
362
363
364
365
366
367
368
369
370
371
372
373
374
375
376
377
378
379
380
381
382
383
384
385
386
387
388
389
390
391
392
393
394
395
396
397
398
399
400
401
402
403
404
405
406
407
408
409
410
411
412
413
414
415
416
417
418
419
420
421
422
423
424
425
426
427
428
429
430
431
432
433
434
435
436
437
438
439
440
441
442
443
444
445
446
447
448
449
450
451
452
453
454
455
456
457
458
459
460
461
462
463
464
465
466
467
468
469
470
471
472
473
474
475
476
477
478
479
480
481
482
483
484
|
SUBROUTINE ZCHKTR( DOTYPE, NN, NVAL, NNB, NBVAL, NNS, NSVAL,
$ THRESH, TSTERR, NMAX, A, AINV, B, X, XACT,
$ WORK, RWORK, NOUT )
*
* -- LAPACK test routine (version 3.0) --
* Univ. of Tennessee, Univ. of California Berkeley, NAG Ltd.,
* Courant Institute, Argonne National Lab, and Rice University
* December 7, 1999
*
* .. Scalar Arguments ..
LOGICAL TSTERR
INTEGER NMAX, NN, NNB, NNS, NOUT
DOUBLE PRECISION THRESH
* ..
* .. Array Arguments ..
LOGICAL DOTYPE( * )
INTEGER NBVAL( * ), NSVAL( * ), NVAL( * )
DOUBLE PRECISION RWORK( * )
COMPLEX*16 A( * ), AINV( * ), B( * ), WORK( * ), X( * ),
$ XACT( * )
* ..
*
* Purpose
* =======
*
* ZCHKTR tests ZTRTRI, -TRS, -RFS, and -CON, and ZLATRS
*
* Arguments
* =========
*
* DOTYPE (input) LOGICAL array, dimension (NTYPES)
* The matrix types to be used for testing. Matrices of type j
* (for 1 <= j <= NTYPES) are used for testing if DOTYPE(j) =
* .TRUE.; if DOTYPE(j) = .FALSE., then type j is not used.
*
* NN (input) INTEGER
* The number of values of N contained in the vector NVAL.
*
* NVAL (input) INTEGER array, dimension (NN)
* The values of the matrix column dimension N.
*
* NNB (input) INTEGER
* The number of values of NB contained in the vector NBVAL.
*
* NBVAL (input) INTEGER array, dimension (NNB)
* The values of the blocksize NB.
*
* NNS (input) INTEGER
* The number of values of NRHS contained in the vector NSVAL.
*
* NSVAL (input) INTEGER array, dimension (NNS)
* The values of the number of right hand sides NRHS.
*
* THRESH (input) DOUBLE PRECISION
* The threshold value for the test ratios. A result is
* included in the output file if RESULT >= THRESH. To have
* every test ratio printed, use THRESH = 0.
*
* TSTERR (input) LOGICAL
* Flag that indicates whether error exits are to be tested.
*
* NMAX (input) INTEGER
* The leading dimension of the work arrays.
* NMAX >= the maximum value of N in NVAL.
*
* A (workspace) COMPLEX*16 array, dimension (NMAX*NMAX)
*
* AINV (workspace) COMPLEX*16 array, dimension (NMAX*NMAX)
*
* B (workspace) COMPLEX*16 array, dimension (NMAX*NSMAX)
* where NSMAX is the largest entry in NSVAL.
*
* X (workspace) COMPLEX*16 array, dimension (NMAX*NSMAX)
*
* XACT (workspace) COMPLEX*16 array, dimension (NMAX*NSMAX)
*
* WORK (workspace) COMPLEX*16 array, dimension
* (NMAX*max(3,NSMAX))
*
* RWORK (workspace) DOUBLE PRECISION array, dimension
* (max(NMAX,2*NSMAX))
*
* NOUT (input) INTEGER
* The unit number for output.
*
* =====================================================================
*
* .. Parameters ..
INTEGER NTYPE1, NTYPES
PARAMETER ( NTYPE1 = 10, NTYPES = 18 )
INTEGER NTESTS
PARAMETER ( NTESTS = 9 )
INTEGER NTRAN
PARAMETER ( NTRAN = 3 )
DOUBLE PRECISION ONE, ZERO
PARAMETER ( ONE = 1.0D0, ZERO = 0.0D0 )
* ..
* .. Local Scalars ..
CHARACTER DIAG, NORM, TRANS, UPLO, XTYPE
CHARACTER*3 PATH
INTEGER I, IDIAG, IMAT, IN, INB, INFO, IRHS, ITRAN,
$ IUPLO, K, LDA, N, NB, NERRS, NFAIL, NRHS, NRUN
DOUBLE PRECISION AINVNM, ANORM, DUMMY, RCOND, RCONDC, RCONDI,
$ RCONDO, SCALE
* ..
* .. Local Arrays ..
CHARACTER TRANSS( NTRAN ), UPLOS( 2 )
INTEGER ISEED( 4 ), ISEEDY( 4 )
DOUBLE PRECISION RESULT( NTESTS )
* ..
* .. External Functions ..
LOGICAL LSAME
DOUBLE PRECISION ZLANTR
EXTERNAL LSAME, ZLANTR
* ..
* .. External Subroutines ..
EXTERNAL ALAERH, ALAHD, ALASUM, XLAENV, ZCOPY, ZERRTR,
$ ZGET04, ZLACPY, ZLARHS, ZLATRS, ZLATTR, ZTRCON,
$ ZTRRFS, ZTRT01, ZTRT02, ZTRT03, ZTRT05, ZTRT06,
$ ZTRTRI, ZTRTRS
* ..
* .. Scalars in Common ..
LOGICAL LERR, OK
CHARACTER*6 SRNAMT
INTEGER INFOT, IOUNIT
* ..
* .. Common blocks ..
COMMON / INFOC / INFOT, IOUNIT, OK, LERR
COMMON / SRNAMC / SRNAMT
* ..
* .. Intrinsic Functions ..
INTRINSIC MAX
* ..
* .. Data statements ..
DATA ISEEDY / 1988, 1989, 1990, 1991 /
DATA UPLOS / 'U', 'L' / , TRANSS / 'N', 'T', 'C' /
* ..
* .. Executable Statements ..
*
* Initialize constants and the random number seed.
*
PATH( 1: 1 ) = 'Zomplex precision'
PATH( 2: 3 ) = 'TR'
NRUN = 0
NFAIL = 0
NERRS = 0
DO 10 I = 1, 4
ISEED( I ) = ISEEDY( I )
10 CONTINUE
*
* Test the error exits
*
IF( TSTERR )
$ CALL ZERRTR( PATH, NOUT )
INFOT = 0
*
DO 120 IN = 1, NN
*
* Do for each value of N in NVAL
*
N = NVAL( IN )
LDA = MAX( 1, N )
XTYPE = 'N'
*
DO 80 IMAT = 1, NTYPE1
*
* Do the tests only if DOTYPE( IMAT ) is true.
*
IF( .NOT.DOTYPE( IMAT ) )
$ GO TO 80
*
DO 70 IUPLO = 1, 2
*
* Do first for UPLO = 'U', then for UPLO = 'L'
*
UPLO = UPLOS( IUPLO )
*
* Call ZLATTR to generate a triangular test matrix.
*
SRNAMT = 'ZLATTR'
CALL ZLATTR( IMAT, UPLO, 'No transpose', DIAG, ISEED, N,
$ A, LDA, X, WORK, RWORK, INFO )
*
* Set IDIAG = 1 for non-unit matrices, 2 for unit.
*
IF( LSAME( DIAG, 'N' ) ) THEN
IDIAG = 1
ELSE
IDIAG = 2
END IF
*
DO 60 INB = 1, NNB
*
* Do for each blocksize in NBVAL
*
NB = NBVAL( INB )
CALL XLAENV( 1, NB )
*
*+ TEST 1
* Form the inverse of A.
*
CALL ZLACPY( UPLO, N, N, A, LDA, AINV, LDA )
SRNAMT = 'ZTRTRI'
CALL ZTRTRI( UPLO, DIAG, N, AINV, LDA, INFO )
*
* Check error code from ZTRTRI.
*
IF( INFO.NE.0 )
$ CALL ALAERH( PATH, 'ZTRTRI', INFO, 0, UPLO // DIAG,
$ N, N, -1, -1, NB, IMAT, NFAIL, NERRS,
$ NOUT )
*
* Compute the infinity-norm condition number of A.
*
ANORM = ZLANTR( 'I', UPLO, DIAG, N, N, A, LDA, RWORK )
AINVNM = ZLANTR( 'I', UPLO, DIAG, N, N, AINV, LDA,
$ RWORK )
IF( ANORM.LE.ZERO .OR. AINVNM.LE.ZERO ) THEN
RCONDI = ONE
ELSE
RCONDI = ( ONE / ANORM ) / AINVNM
END IF
*
* Compute the residual for the triangular matrix times
* its inverse. Also compute the 1-norm condition number
* of A.
*
CALL ZTRT01( UPLO, DIAG, N, A, LDA, AINV, LDA, RCONDO,
$ RWORK, RESULT( 1 ) )
* Print the test ratio if it is .GE. THRESH.
*
IF( RESULT( 1 ).GE.THRESH ) THEN
IF( NFAIL.EQ.0 .AND. NERRS.EQ.0 )
$ CALL ALAHD( NOUT, PATH )
WRITE( NOUT, FMT = 9999 )UPLO, DIAG, N, NB, IMAT,
$ 1, RESULT( 1 )
NFAIL = NFAIL + 1
END IF
NRUN = NRUN + 1
*
* Skip remaining tests if not the first block size.
*
IF( INB.NE.1 )
$ GO TO 60
*
DO 40 IRHS = 1, NNS
NRHS = NSVAL( IRHS )
XTYPE = 'N'
*
DO 30 ITRAN = 1, NTRAN
*
* Do for op(A) = A, A**T, or A**H.
*
TRANS = TRANSS( ITRAN )
IF( ITRAN.EQ.1 ) THEN
NORM = 'O'
RCONDC = RCONDO
ELSE
NORM = 'I'
RCONDC = RCONDI
END IF
*
*+ TEST 2
* Solve and compute residual for op(A)*x = b.
*
SRNAMT = 'ZLARHS'
CALL ZLARHS( PATH, XTYPE, UPLO, TRANS, N, N, 0,
$ IDIAG, NRHS, A, LDA, XACT, LDA, B,
$ LDA, ISEED, INFO )
XTYPE = 'C'
CALL ZLACPY( 'Full', N, NRHS, B, LDA, X, LDA )
*
SRNAMT = 'ZTRTRS'
CALL ZTRTRS( UPLO, TRANS, DIAG, N, NRHS, A, LDA,
$ X, LDA, INFO )
*
* Check error code from ZTRTRS.
*
IF( INFO.NE.0 )
$ CALL ALAERH( PATH, 'ZTRTRS', INFO, 0,
$ UPLO // TRANS // DIAG, N, N, -1,
$ -1, NRHS, IMAT, NFAIL, NERRS,
$ NOUT )
*
* This line is needed on a Sun SPARCstation.
*
IF( N.GT.0 )
$ DUMMY = A( 1 )
*
CALL ZTRT02( UPLO, TRANS, DIAG, N, NRHS, A, LDA,
$ X, LDA, B, LDA, WORK, RWORK,
$ RESULT( 2 ) )
*
*+ TEST 3
* Check solution from generated exact solution.
*
CALL ZGET04( N, NRHS, X, LDA, XACT, LDA, RCONDC,
$ RESULT( 3 ) )
*
*+ TESTS 4, 5, and 6
* Use iterative refinement to improve the solution
* and compute error bounds.
*
SRNAMT = 'ZTRRFS'
CALL ZTRRFS( UPLO, TRANS, DIAG, N, NRHS, A, LDA,
$ B, LDA, X, LDA, RWORK,
$ RWORK( NRHS+1 ), WORK,
$ RWORK( 2*NRHS+1 ), INFO )
*
* Check error code from ZTRRFS.
*
IF( INFO.NE.0 )
$ CALL ALAERH( PATH, 'ZTRRFS', INFO, 0,
$ UPLO // TRANS // DIAG, N, N, -1,
$ -1, NRHS, IMAT, NFAIL, NERRS,
$ NOUT )
*
CALL ZGET04( N, NRHS, X, LDA, XACT, LDA, RCONDC,
$ RESULT( 4 ) )
CALL ZTRT05( UPLO, TRANS, DIAG, N, NRHS, A, LDA,
$ B, LDA, X, LDA, XACT, LDA, RWORK,
$ RWORK( NRHS+1 ), RESULT( 5 ) )
*
* Print information about the tests that did not
* pass the threshold.
*
DO 20 K = 2, 6
IF( RESULT( K ).GE.THRESH ) THEN
IF( NFAIL.EQ.0 .AND. NERRS.EQ.0 )
$ CALL ALAHD( NOUT, PATH )
WRITE( NOUT, FMT = 9998 )UPLO, TRANS,
$ DIAG, N, NRHS, IMAT, K, RESULT( K )
NFAIL = NFAIL + 1
END IF
20 CONTINUE
NRUN = NRUN + 5
30 CONTINUE
40 CONTINUE
*
*+ TEST 7
* Get an estimate of RCOND = 1/CNDNUM.
*
DO 50 ITRAN = 1, 2
IF( ITRAN.EQ.1 ) THEN
NORM = 'O'
RCONDC = RCONDO
ELSE
NORM = 'I'
RCONDC = RCONDI
END IF
SRNAMT = 'ZTRCON'
CALL ZTRCON( NORM, UPLO, DIAG, N, A, LDA, RCOND,
$ WORK, RWORK, INFO )
*
* Check error code from ZTRCON.
*
IF( INFO.NE.0 )
$ CALL ALAERH( PATH, 'ZTRCON', INFO, 0,
$ NORM // UPLO // DIAG, N, N, -1, -1,
$ -1, IMAT, NFAIL, NERRS, NOUT )
*
CALL ZTRT06( RCOND, RCONDC, UPLO, DIAG, N, A, LDA,
$ RWORK, RESULT( 7 ) )
*
* Print the test ratio if it is .GE. THRESH.
*
IF( RESULT( 7 ).GE.THRESH ) THEN
IF( NFAIL.EQ.0 .AND. NERRS.EQ.0 )
$ CALL ALAHD( NOUT, PATH )
WRITE( NOUT, FMT = 9997 )NORM, UPLO, N, IMAT,
$ 7, RESULT( 7 )
NFAIL = NFAIL + 1
END IF
NRUN = NRUN + 1
50 CONTINUE
60 CONTINUE
70 CONTINUE
80 CONTINUE
*
* Use pathological test matrices to test ZLATRS.
*
DO 110 IMAT = NTYPE1 + 1, NTYPES
*
* Do the tests only if DOTYPE( IMAT ) is true.
*
IF( .NOT.DOTYPE( IMAT ) )
$ GO TO 110
*
DO 100 IUPLO = 1, 2
*
* Do first for UPLO = 'U', then for UPLO = 'L'
*
UPLO = UPLOS( IUPLO )
DO 90 ITRAN = 1, NTRAN
*
* Do for op(A) = A, A**T, and A**H.
*
TRANS = TRANSS( ITRAN )
*
* Call ZLATTR to generate a triangular test matrix.
*
SRNAMT = 'ZLATTR'
CALL ZLATTR( IMAT, UPLO, TRANS, DIAG, ISEED, N, A,
$ LDA, X, WORK, RWORK, INFO )
*
*+ TEST 8
* Solve the system op(A)*x = b.
*
SRNAMT = 'ZLATRS'
CALL ZCOPY( N, X, 1, B, 1 )
CALL ZLATRS( UPLO, TRANS, DIAG, 'N', N, A, LDA, B,
$ SCALE, RWORK, INFO )
*
* Check error code from ZLATRS.
*
IF( INFO.NE.0 )
$ CALL ALAERH( PATH, 'ZLATRS', INFO, 0,
$ UPLO // TRANS // DIAG // 'N', N, N,
$ -1, -1, -1, IMAT, NFAIL, NERRS, NOUT )
*
CALL ZTRT03( UPLO, TRANS, DIAG, N, 1, A, LDA, SCALE,
$ RWORK, ONE, B, LDA, X, LDA, WORK,
$ RESULT( 8 ) )
*
*+ TEST 9
* Solve op(A)*X = b again with NORMIN = 'Y'.
*
CALL ZCOPY( N, X, 1, B( N+1 ), 1 )
CALL ZLATRS( UPLO, TRANS, DIAG, 'Y', N, A, LDA,
$ B( N+1 ), SCALE, RWORK, INFO )
*
* Check error code from ZLATRS.
*
IF( INFO.NE.0 )
$ CALL ALAERH( PATH, 'ZLATRS', INFO, 0,
$ UPLO // TRANS // DIAG // 'Y', N, N,
$ -1, -1, -1, IMAT, NFAIL, NERRS, NOUT )
*
CALL ZTRT03( UPLO, TRANS, DIAG, N, 1, A, LDA, SCALE,
$ RWORK, ONE, B( N+1 ), LDA, X, LDA, WORK,
$ RESULT( 9 ) )
*
* Print information about the tests that did not pass
* the threshold.
*
IF( RESULT( 8 ).GE.THRESH ) THEN
IF( NFAIL.EQ.0 .AND. NERRS.EQ.0 )
$ CALL ALAHD( NOUT, PATH )
WRITE( NOUT, FMT = 9996 )'ZLATRS', UPLO, TRANS,
$ DIAG, 'N', N, IMAT, 8, RESULT( 8 )
NFAIL = NFAIL + 1
END IF
IF( RESULT( 9 ).GE.THRESH ) THEN
IF( NFAIL.EQ.0 .AND. NERRS.EQ.0 )
$ CALL ALAHD( NOUT, PATH )
WRITE( NOUT, FMT = 9996 )'ZLATRS', UPLO, TRANS,
$ DIAG, 'Y', N, IMAT, 9, RESULT( 9 )
NFAIL = NFAIL + 1
END IF
NRUN = NRUN + 2
90 CONTINUE
100 CONTINUE
110 CONTINUE
120 CONTINUE
*
* Print a summary of the results.
*
CALL ALASUM( PATH, NOUT, NFAIL, NRUN, NERRS )
*
9999 FORMAT( ' UPLO=''', A1, ''', DIAG=''', A1, ''', N=', I5, ', NB=',
$ I4, ', type ', I2, ', test(', I2, ')= ', G12.5 )
9998 FORMAT( ' UPLO=''', A1, ''', TRANS=''', A1, ''', DIAG=''', A1,
$ ''', N=', I5, ', NB=', I4, ', type ', I2, ',
$ test(', I2, ')= ', G12.5 )
9997 FORMAT( ' NORM=''', A1, ''', UPLO =''', A1, ''', N=', I5, ',',
$ 11X, ' type ', I2, ', test(', I2, ')=', G12.5 )
9996 FORMAT( 1X, A6, '( ''', A1, ''', ''', A1, ''', ''', A1, ''', ''',
$ A1, ''',', I5, ', ... ), type ', I2, ', test(', I2, ')=',
$ G12.5 )
RETURN
*
* End of ZCHKTR
*
END
|
