1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162
163
164
165
166
167
168
169
170
171
172
173
174
175
176
177
178
179
180
181
182
183
184
185
186
187
188
189
190
191
192
193
194
195
196
197
198
199
200
201
202
203
204
205
206
207
208
209
210
211
212
213
214
215
216
217
218
219
220
221
222
223
224
225
226
227
228
229
230
231
232
233
234
235
236
237
238
239
240
241
242
243
244
245
246
247
248
249
250
251
252
253
254
255
256
257
258
259
260
261
262
263
264
265
266
267
268
269
270
271
272
273
274
275
276
277
278
279
280
281
282
283
284
285
286
287
288
289
290
291
292
293
294
295
296
297
298
299
300
301
302
303
304
305
306
307
308
309
310
311
312
313
314
315
316
317
318
319
320
321
322
323
324
325
326
327
328
329
330
331
|
SUBROUTINE DTIMPO( LINE, NN, NVAL, NNS, NSVAL, NNB, NBVAL, NLDA,
$ LDAVAL, TIMMIN, A, B, IWORK, RESLTS, LDR1,
$ LDR2, LDR3, NOUT )
*
* -- LAPACK timing routine (version 3.0) --
* Univ. of Tennessee, Univ. of California Berkeley, NAG Ltd.,
* Courant Institute, Argonne National Lab, and Rice University
* March 31, 1993
*
* .. Scalar Arguments ..
CHARACTER*80 LINE
INTEGER LDR1, LDR2, LDR3, NLDA, NN, NNB, NNS, NOUT
DOUBLE PRECISION TIMMIN
* ..
* .. Array Arguments ..
INTEGER IWORK( * ), LDAVAL( * ), NBVAL( * ),
$ NSVAL( * ), NVAL( * )
DOUBLE PRECISION A( * ), B( * ), RESLTS( LDR1, LDR2, LDR3, * )
* ..
*
* Purpose
* =======
*
* DTIMPO times DPOTRF, -TRS, and -TRI.
*
* Arguments
* =========
*
* LINE (input) CHARACTER*80
* The input line that requested this routine. The first six
* characters contain either the name of a subroutine or a
* generic path name. The remaining characters may be used to
* specify the individual routines to be timed. See ATIMIN for
* a full description of the format of the input line.
*
* NN (input) INTEGER
* The number of values of N contained in the vector NVAL.
*
* NVAL (input) INTEGER array, dimension (NN)
* The values of the matrix size N.
*
* NNS (input) INTEGER
* The number of values of NRHS contained in the vector NSVAL.
*
* NSVAL (input) INTEGER array, dimension (NNS)
* The values of the number of right hand sides NRHS.
*
* NNB (input) INTEGER
* The number of values of NB contained in the vector NBVAL.
*
* NBVAL (input) INTEGER array, dimension (NNB)
* The values of the blocksize NB.
*
* NLDA (input) INTEGER
* The number of values of LDA contained in the vector LDAVAL.
*
* LDAVAL (input) INTEGER array, dimension (NLDA)
* The values of the leading dimension of the array A.
*
* TIMMIN (input) DOUBLE PRECISION
* The minimum time a subroutine will be timed.
*
* A (workspace) DOUBLE PRECISION array, dimension (LDAMAX*NMAX)
* where LDAMAX and NMAX are the maximum values permitted
* for LDA and N.
*
* B (workspace) DOUBLE PRECISION array, dimension (LDAMAX*NMAX)
*
* IWORK (workspace) INTEGER array, dimension (NMAX)
*
* RESLTS (output) DOUBLE PRECISION array, dimension
* (LDR1,LDR2,LDR3,NSUBS)
* The timing results for each subroutine over the relevant
* values of N, NB, and LDA.
*
* LDR1 (input) INTEGER
* The first dimension of RESLTS. LDR1 >= max(4,NNB).
*
* LDR2 (input) INTEGER
* The second dimension of RESLTS. LDR2 >= max(1,NN).
*
* LDR3 (input) INTEGER
* The third dimension of RESLTS. LDR3 >= max(1,2*NLDA).
*
* NOUT (input) INTEGER
* The unit number for output.
*
* =====================================================================
*
* .. Parameters ..
INTEGER NSUBS
PARAMETER ( NSUBS = 3 )
* ..
* .. Local Scalars ..
CHARACTER UPLO
CHARACTER*3 PATH
CHARACTER*6 CNAME
INTEGER I, I3, IC, ICL, ILDA, IN, INB, INFO, ISUB,
$ IUPLO, LDA, LDB, MAT, N, NB, NRHS
DOUBLE PRECISION OPS, S1, S2, TIME, UNTIME
* ..
* .. Local Arrays ..
LOGICAL TIMSUB( NSUBS )
CHARACTER UPLOS( 2 )
CHARACTER*6 SUBNAM( NSUBS )
* ..
* .. External Functions ..
LOGICAL LSAME
DOUBLE PRECISION DMFLOP, DOPLA, DSECND
EXTERNAL LSAME, DMFLOP, DOPLA, DSECND
* ..
* .. External Subroutines ..
EXTERNAL ATIMCK, ATIMIN, DLACPY, DPOTRF, DPOTRI, DPOTRS,
$ DPRTBL, DTIMMG, XLAENV
* ..
* .. Intrinsic Functions ..
INTRINSIC DBLE
* ..
* .. Data statements ..
DATA UPLOS / 'U', 'L' /
DATA SUBNAM / 'DPOTRF', 'DPOTRS', 'DPOTRI' /
* ..
* .. Executable Statements ..
*
* Extract the timing request from the input line.
*
PATH( 1: 1 ) = 'Double precision'
PATH( 2: 3 ) = 'PO'
CALL ATIMIN( PATH, LINE, NSUBS, SUBNAM, TIMSUB, NOUT, INFO )
IF( INFO.NE.0 )
$ GO TO 150
*
* Check that N <= LDA for the input values.
*
CNAME = LINE( 1: 6 )
CALL ATIMCK( 2, CNAME, NN, NVAL, NLDA, LDAVAL, NOUT, INFO )
IF( INFO.GT.0 ) THEN
WRITE( NOUT, FMT = 9999 )CNAME
GO TO 150
END IF
*
* Do first for UPLO = 'U', then for UPLO = 'L'
*
DO 110 IUPLO = 1, 2
UPLO = UPLOS( IUPLO )
IF( LSAME( UPLO, 'U' ) ) THEN
MAT = 3
ELSE
MAT = -3
END IF
*
* Do for each value of N in NVAL.
*
DO 100 IN = 1, NN
N = NVAL( IN )
*
* Do for each value of LDA:
*
DO 90 ILDA = 1, NLDA
LDA = LDAVAL( ILDA )
I3 = ( IUPLO-1 )*NLDA + ILDA
*
* Do for each value of NB in NBVAL. Only the blocked
* routines are timed in this loop since the other routines
* are independent of NB.
*
DO 50 INB = 1, NNB
NB = NBVAL( INB )
CALL XLAENV( 1, NB )
*
* Time DPOTRF
*
IF( TIMSUB( 1 ) ) THEN
CALL DTIMMG( MAT, N, N, A, LDA, 0, 0 )
IC = 0
S1 = DSECND( )
10 CONTINUE
CALL DPOTRF( UPLO, N, A, LDA, INFO )
S2 = DSECND( )
TIME = S2 - S1
IC = IC + 1
IF( TIME.LT.TIMMIN ) THEN
CALL DTIMMG( MAT, N, N, A, LDA, 0, 0 )
GO TO 10
END IF
*
* Subtract the time used in DTIMMG.
*
ICL = 1
S1 = DSECND( )
20 CONTINUE
S2 = DSECND( )
UNTIME = S2 - S1
ICL = ICL + 1
IF( ICL.LE.IC ) THEN
CALL DTIMMG( MAT, N, N, A, LDA, 0, 0 )
GO TO 20
END IF
*
TIME = ( TIME-UNTIME ) / DBLE( IC )
OPS = DOPLA( 'DPOTRF', N, N, 0, 0, NB )
RESLTS( INB, IN, I3, 1 ) = DMFLOP( OPS, TIME,
$ INFO )
*
ELSE
IC = 0
CALL DTIMMG( MAT, N, N, A, LDA, 0, 0 )
END IF
*
* Generate another matrix and factor it using DPOTRF so
* that the factored form can be used in timing the other
* routines.
*
IF( IC.NE.1 )
$ CALL DPOTRF( UPLO, N, A, LDA, INFO )
*
* Time DPOTRI
*
IF( TIMSUB( 3 ) ) THEN
CALL DLACPY( UPLO, N, N, A, LDA, B, LDA )
IC = 0
S1 = DSECND( )
30 CONTINUE
CALL DPOTRI( UPLO, N, B, LDA, INFO )
S2 = DSECND( )
TIME = S2 - S1
IC = IC + 1
IF( TIME.LT.TIMMIN ) THEN
CALL DLACPY( UPLO, N, N, A, LDA, B, LDA )
GO TO 30
END IF
*
* Subtract the time used in DLACPY.
*
ICL = 1
S1 = DSECND( )
40 CONTINUE
S2 = DSECND( )
UNTIME = S2 - S1
ICL = ICL + 1
IF( ICL.LE.IC ) THEN
CALL DLACPY( UPLO, N, N, A, LDA, B, LDA )
GO TO 40
END IF
*
TIME = ( TIME-UNTIME ) / DBLE( IC )
OPS = DOPLA( 'DPOTRI', N, N, 0, 0, NB )
RESLTS( INB, IN, I3, 3 ) = DMFLOP( OPS, TIME,
$ INFO )
END IF
50 CONTINUE
*
* Time DPOTRS
*
IF( TIMSUB( 2 ) ) THEN
DO 80 I = 1, NNS
NRHS = NSVAL( I )
LDB = LDA
CALL DTIMMG( 0, N, NRHS, B, LDB, 0, 0 )
IC = 0
S1 = DSECND( )
60 CONTINUE
CALL DPOTRS( UPLO, N, NRHS, A, LDA, B, LDB, INFO )
S2 = DSECND( )
TIME = S2 - S1
IC = IC + 1
IF( TIME.LT.TIMMIN ) THEN
CALL DTIMMG( 0, N, NRHS, B, LDB, 0, 0 )
GO TO 60
END IF
*
* Subtract the time used in DTIMMG.
*
ICL = 1
S1 = DSECND( )
70 CONTINUE
S2 = DSECND( )
UNTIME = S2 - S1
ICL = ICL + 1
IF( ICL.LE.IC ) THEN
CALL DTIMMG( 0, N, NRHS, B, LDB, 0, 0 )
GO TO 70
END IF
*
TIME = ( TIME-UNTIME ) / DBLE( IC )
OPS = DOPLA( 'DPOTRS', N, NRHS, 0, 0, 0 )
RESLTS( I, IN, I3, 2 ) = DMFLOP( OPS, TIME, INFO )
80 CONTINUE
END IF
90 CONTINUE
100 CONTINUE
110 CONTINUE
*
* Print tables of results for each timed routine.
*
DO 140 ISUB = 1, NSUBS
IF( .NOT.TIMSUB( ISUB ) )
$ GO TO 140
WRITE( NOUT, FMT = 9998 )SUBNAM( ISUB )
IF( NLDA.GT.1 ) THEN
DO 120 I = 1, NLDA
WRITE( NOUT, FMT = 9997 )I, LDAVAL( I )
120 CONTINUE
END IF
WRITE( NOUT, FMT = * )
DO 130 IUPLO = 1, 2
WRITE( NOUT, FMT = 9996 )SUBNAM( ISUB ), UPLOS( IUPLO )
I3 = ( IUPLO-1 )*NLDA + 1
IF( ISUB.EQ.1 ) THEN
CALL DPRTBL( 'NB', 'N', NNB, NBVAL, NN, NVAL, NLDA,
$ RESLTS( 1, 1, I3, 1 ), LDR1, LDR2, NOUT )
ELSE IF( ISUB.EQ.2 ) THEN
CALL DPRTBL( 'NRHS', 'N', NNS, NSVAL, NN, NVAL, NLDA,
$ RESLTS( 1, 1, I3, 2 ), LDR1, LDR2, NOUT )
ELSE IF( ISUB.EQ.3 ) THEN
CALL DPRTBL( 'NB', 'N', NNB, NBVAL, NN, NVAL, NLDA,
$ RESLTS( 1, 1, I3, 3 ), LDR1, LDR2, NOUT )
END IF
130 CONTINUE
140 CONTINUE
*
150 CONTINUE
9999 FORMAT( 1X, A6, ' timing run not attempted', / )
9998 FORMAT( / ' *** Speed of ', A6, ' in megaflops ***' )
9997 FORMAT( 5X, 'line ', I2, ' with LDA = ', I5 )
9996 FORMAT( 5X, A6, ' with UPLO = ''', A1, '''', / )
RETURN
*
* End of DTIMPO
*
END
|
