1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
|
*> \brief \b ZLARND
*
* =========== DOCUMENTATION ===========
*
* Online html documentation available at
* http://www.netlib.org/lapack/explore-html/
*
* Definition:
* ===========
*
* COMPLEX*16 FUNCTION ZLARND( IDIST, ISEED )
*
* .. Scalar Arguments ..
* INTEGER IDIST
* ..
* .. Array Arguments ..
* INTEGER ISEED( 4 )
* ..
*
*
*> \par Purpose:
* =============
*>
*> \verbatim
*>
*> ZLARND returns a random complex number from a uniform or normal
*> distribution.
*> \endverbatim
*
* Arguments:
* ==========
*
*> \param[in] IDIST
*> \verbatim
*> IDIST is INTEGER
*> Specifies the distribution of the random numbers:
*> = 1: real and imaginary parts each uniform (0,1)
*> = 2: real and imaginary parts each uniform (-1,1)
*> = 3: real and imaginary parts each normal (0,1)
*> = 4: uniformly distributed on the disc abs(z) <= 1
*> = 5: uniformly distributed on the circle abs(z) = 1
*> \endverbatim
*>
*> \param[in,out] ISEED
*> \verbatim
*> ISEED is INTEGER array, dimension (4)
*> On entry, the seed of the random number generator; the array
*> elements must be between 0 and 4095, and ISEED(4) must be
*> odd.
*> On exit, the seed is updated.
*> \endverbatim
*
* Authors:
* ========
*
*> \author Univ. of Tennessee
*> \author Univ. of California Berkeley
*> \author Univ. of Colorado Denver
*> \author NAG Ltd.
*
*> \date November 2011
*
*> \ingroup complex16_matgen
*
*> \par Further Details:
* =====================
*>
*> \verbatim
*>
*> This routine calls the auxiliary routine DLARAN to generate a random
*> real number from a uniform (0,1) distribution. The Box-Muller method
*> is used to transform numbers from a uniform to a normal distribution.
*> \endverbatim
*>
* =====================================================================
COMPLEX*16 FUNCTION ZLARND( IDIST, ISEED )
*
* -- LAPACK auxiliary routine (version 3.4.0) --
* -- LAPACK is a software package provided by Univ. of Tennessee, --
* -- Univ. of California Berkeley, Univ. of Colorado Denver and NAG Ltd..--
* November 2011
*
* .. Scalar Arguments ..
INTEGER IDIST
* ..
* .. Array Arguments ..
INTEGER ISEED( 4 )
* ..
*
* =====================================================================
*
* .. Parameters ..
DOUBLE PRECISION ZERO, ONE, TWO
PARAMETER ( ZERO = 0.0D+0, ONE = 1.0D+0, TWO = 2.0D+0 )
DOUBLE PRECISION TWOPI
PARAMETER ( TWOPI = 6.2831853071795864769252867663D+0 )
* ..
* .. Local Scalars ..
DOUBLE PRECISION T1, T2
* ..
* .. External Functions ..
DOUBLE PRECISION DLARAN
EXTERNAL DLARAN
* ..
* .. Intrinsic Functions ..
INTRINSIC DCMPLX, EXP, LOG, SQRT
* ..
* .. Executable Statements ..
*
* Generate a pair of real random numbers from a uniform (0,1)
* distribution
*
T1 = DLARAN( ISEED )
T2 = DLARAN( ISEED )
*
IF( IDIST.EQ.1 ) THEN
*
* real and imaginary parts each uniform (0,1)
*
ZLARND = DCMPLX( T1, T2 )
ELSE IF( IDIST.EQ.2 ) THEN
*
* real and imaginary parts each uniform (-1,1)
*
ZLARND = DCMPLX( TWO*T1-ONE, TWO*T2-ONE )
ELSE IF( IDIST.EQ.3 ) THEN
*
* real and imaginary parts each normal (0,1)
*
ZLARND = SQRT( -TWO*LOG( T1 ) )*EXP( DCMPLX( ZERO, TWOPI*T2 ) )
ELSE IF( IDIST.EQ.4 ) THEN
*
* uniform distribution on the unit disc abs(z) <= 1
*
ZLARND = SQRT( T1 )*EXP( DCMPLX( ZERO, TWOPI*T2 ) )
ELSE IF( IDIST.EQ.5 ) THEN
*
* uniform distribution on the unit circle abs(z) = 1
*
ZLARND = EXP( DCMPLX( ZERO, TWOPI*T2 ) )
END IF
RETURN
*
* End of ZLARND
*
END
|
