1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162
163
164
165
166
167
168
169
170
171
172
173
174
175
176
177
178
179
180
181
182
183
184
185
186
187
188
189
190
191
192
193
|
SUBROUTINE ZPPT01( UPLO, N, A, AFAC, RWORK, RESID )
*
* -- LAPACK test routine (version 3.0) --
* Univ. of Tennessee, Univ. of California Berkeley, NAG Ltd.,
* Courant Institute, Argonne National Lab, and Rice University
* September 30, 1994
*
* .. Scalar Arguments ..
CHARACTER UPLO
INTEGER N
DOUBLE PRECISION RESID
* ..
* .. Array Arguments ..
DOUBLE PRECISION RWORK( * )
COMPLEX*16 A( * ), AFAC( * )
* ..
*
* Purpose
* =======
*
* ZPPT01 reconstructs a Hermitian positive definite packed matrix A
* from its L*L' or U'*U factorization and computes the residual
* norm( L*L' - A ) / ( N * norm(A) * EPS ) or
* norm( U'*U - A ) / ( N * norm(A) * EPS ),
* where EPS is the machine epsilon, L' is the conjugate transpose of
* L, and U' is the conjugate transpose of U.
*
* Arguments
* ==========
*
* UPLO (input) CHARACTER*1
* Specifies whether the upper or lower triangular part of the
* Hermitian matrix A is stored:
* = 'U': Upper triangular
* = 'L': Lower triangular
*
* N (input) INTEGER
* The number of rows and columns of the matrix A. N >= 0.
*
* A (input) COMPLEX*16 array, dimension (N*(N+1)/2)
* The original Hermitian matrix A, stored as a packed
* triangular matrix.
*
* AFAC (input/output) COMPLEX*16 array, dimension (N*(N+1)/2)
* On entry, the factor L or U from the L*L' or U'*U
* factorization of A, stored as a packed triangular matrix.
* Overwritten with the reconstructed matrix, and then with the
* difference L*L' - A (or U'*U - A).
*
* RWORK (workspace) DOUBLE PRECISION array, dimension (N)
*
* RESID (output) DOUBLE PRECISION
* If UPLO = 'L', norm(L*L' - A) / ( N * norm(A) * EPS )
* If UPLO = 'U', norm(U'*U - A) / ( N * norm(A) * EPS )
*
* =====================================================================
*
* .. Parameters ..
DOUBLE PRECISION ZERO, ONE
PARAMETER ( ZERO = 0.0D+0, ONE = 1.0D+0 )
* ..
* .. Local Scalars ..
INTEGER I, K, KC
DOUBLE PRECISION ANORM, EPS, TR
COMPLEX*16 TC
* ..
* .. External Functions ..
LOGICAL LSAME
DOUBLE PRECISION DLAMCH, ZLANHP
COMPLEX*16 ZDOTC
EXTERNAL LSAME, DLAMCH, ZLANHP, ZDOTC
* ..
* .. External Subroutines ..
EXTERNAL ZHPR, ZSCAL, ZTPMV
* ..
* .. Intrinsic Functions ..
INTRINSIC DBLE, DIMAG
* ..
* .. Executable Statements ..
*
* Quick exit if N = 0
*
IF( N.LE.0 ) THEN
RESID = ZERO
RETURN
END IF
*
* Exit with RESID = 1/EPS if ANORM = 0.
*
EPS = DLAMCH( 'Epsilon' )
ANORM = ZLANHP( '1', UPLO, N, A, RWORK )
IF( ANORM.LE.ZERO ) THEN
RESID = ONE / EPS
RETURN
END IF
*
* Check the imaginary parts of the diagonal elements and return with
* an error code if any are nonzero.
*
KC = 1
IF( LSAME( UPLO, 'U' ) ) THEN
DO 10 K = 1, N
IF( DIMAG( AFAC( KC ) ).NE.ZERO ) THEN
RESID = ONE / EPS
RETURN
END IF
KC = KC + K + 1
10 CONTINUE
ELSE
DO 20 K = 1, N
IF( DIMAG( AFAC( KC ) ).NE.ZERO ) THEN
RESID = ONE / EPS
RETURN
END IF
KC = KC + N - K + 1
20 CONTINUE
END IF
*
* Compute the product U'*U, overwriting U.
*
IF( LSAME( UPLO, 'U' ) ) THEN
KC = ( N*( N-1 ) ) / 2 + 1
DO 30 K = N, 1, -1
*
* Compute the (K,K) element of the result.
*
TR = ZDOTC( K, AFAC( KC ), 1, AFAC( KC ), 1 )
AFAC( KC+K-1 ) = TR
*
* Compute the rest of column K.
*
IF( K.GT.1 ) THEN
CALL ZTPMV( 'Upper', 'Conjugate', 'Non-unit', K-1, AFAC,
$ AFAC( KC ), 1 )
KC = KC - ( K-1 )
END IF
30 CONTINUE
*
* Compute the difference L*L' - A
*
KC = 1
DO 50 K = 1, N
DO 40 I = 1, K - 1
AFAC( KC+I-1 ) = AFAC( KC+I-1 ) - A( KC+I-1 )
40 CONTINUE
AFAC( KC+K-1 ) = AFAC( KC+K-1 ) - DBLE( A( KC+K-1 ) )
KC = KC + K
50 CONTINUE
*
* Compute the product L*L', overwriting L.
*
ELSE
KC = ( N*( N+1 ) ) / 2
DO 60 K = N, 1, -1
*
* Add a multiple of column K of the factor L to each of
* columns K+1 through N.
*
IF( K.LT.N )
$ CALL ZHPR( 'Lower', N-K, ONE, AFAC( KC+1 ), 1,
$ AFAC( KC+N-K+1 ) )
*
* Scale column K by the diagonal element.
*
TC = AFAC( KC )
CALL ZSCAL( N-K+1, TC, AFAC( KC ), 1 )
*
KC = KC - ( N-K+2 )
60 CONTINUE
*
* Compute the difference U'*U - A
*
KC = 1
DO 80 K = 1, N
AFAC( KC ) = AFAC( KC ) - DBLE( A( KC ) )
DO 70 I = K + 1, N
AFAC( KC+I-K ) = AFAC( KC+I-K ) - A( KC+I-K )
70 CONTINUE
KC = KC + N - K + 1
80 CONTINUE
END IF
*
* Compute norm( L*U - A ) / ( N * norm(A) * EPS )
*
RESID = ZLANHP( '1', UPLO, N, AFAC, RWORK )
*
RESID = ( ( RESID / DBLE( N ) ) / ANORM ) / EPS
*
RETURN
*
* End of ZPPT01
*
END
|
