1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162
163
164
165
166
167
168
169
170
171
172
173
174
175
176
177
178
179
180
181
182
183
184
185
186
187
188
189
190
191
192
193
194
195
196
197
198
199
200
201
202
203
204
205
206
|
{
***************************************************************************
* *
* This source is free software; you can redistribute it and/or modify *
* it under the terms of the GNU General Public License as published by *
* the Free Software Foundation; either version 2 of the License, or *
* (at your option) any later version. *
* *
* This code is distributed in the hope that it will be useful, but *
* WITHOUT ANY WARRANTY; without even the implied warranty of *
* MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the GNU *
* General Public License for more details. *
* *
* A copy of the GNU General Public License is available on the World *
* Wide Web at <http://www.gnu.org/copyleft/gpl.html>. You can also *
* obtain it by writing to the Free Software Foundation, *
* Inc., 51 Franklin Street - Fifth Floor, Boston, MA 02110-1335, USA. *
* *
***************************************************************************
Author: Mattias Gaertner
Abstract:
Functions and classes to build dependency graphs for groups of pascal units.
}
unit CTUnitGroupGraph;
{$mode objfpc}{$H+}
interface
uses
Classes, SysUtils, Laz_AVL_Tree, CTUnitGraph;
type
TUGGroup = class;
TUGGroups = class;
{ TUGGroupUnit }
TUGGroupUnit = class(TUGUnit)
public
Group: TUGGroup;
end;
TUGGroup = class
private
FBaseDir: string;
FGroups: TUGGroups;
FName: string;
FUnits: TAVLTree;
procedure SetName(AValue: string);
public
constructor Create(aName: string; TheGroups: TUGGroups);
destructor Destroy; override;
procedure Clear;
procedure AddUnit(anUnit: TUGGroupUnit);
procedure RemoveUnit(anUnit: TUGGroupUnit);
property Name: string read FName write SetName;
property BaseDir: string read FBaseDir write FBaseDir;
property Groups: TUGGroups read FGroups;
property Units: TAVLTree read FUnits; // tree of TUGGroupUnit sorted for Filename
end;
{ TUGGroups }
TUGGroups = class
private
fClearing: boolean;
FGroups: TAVLTree;
public
constructor Create(Graph: TUsesGraph);
destructor Destroy; override;
procedure Clear;
function GetGroup(Name: string; CreateIfNotExists: boolean): TUGGroup;
property Groups: TAVLTree read FGroups; // tree of TUGGroup sorted for Name
end;
function CompareUGGroupNames(UGGroup1, UGGroup2: Pointer): integer;
function CompareNameAndUGGroup(NameAnsistring, UGGroup: Pointer): integer;
implementation
function CompareUGGroupNames(UGGroup1, UGGroup2: Pointer): integer;
var
Group1: TUGGroup absolute UGGroup1;
Group2: TUGGroup absolute UGGroup2;
begin
Result:=SysUtils.CompareText(Group1.Name,Group2.Name);
end;
function CompareNameAndUGGroup(NameAnsistring, UGGroup: Pointer): integer;
var
Group: TUGGroup absolute UGGroup;
Name: String;
begin
Name:=AnsiString(NameAnsistring);
Result:=SysUtils.CompareText(Name,Group.Name);
end;
{ TUGGroups }
constructor TUGGroups.Create(Graph: TUsesGraph);
begin
if (not Graph.UnitClass.InheritsFrom(TUGGroup))
and ((Graph.FilesTree.Count>0) or (Graph.QueuedFilesTree.Count>0)
or (Graph.TargetFilesTree.Count>0))
then
raise Exception.Create('TUGGroups.Create You must create TUGGroups before adding units');
FGroups:=TAVLTree.Create(@CompareUGGroupNames);
Graph.UnitClass:=TUGGroupUnit;
end;
destructor TUGGroups.Destroy;
begin
Clear;
FreeAndNil(FGroups);
inherited Destroy;
end;
procedure TUGGroups.Clear;
begin
if FGroups=nil then exit;
fClearing:=true;
try
FGroups.FreeAndClear;
finally
fClearing:=false;
end;
end;
function TUGGroups.GetGroup(Name: string; CreateIfNotExists: boolean): TUGGroup;
var
Node: TAVLTreeNode;
begin
Node:=FGroups.FindKey(Pointer(Name),@CompareNameAndUGGroup);
if Node<>nil then begin
Result:=TUGGroup(Node.Data);
end else if CreateIfNotExists then begin
Result:=TUGGroup.Create(Name,Self);
FGroups.Add(Result);
end else
Result:=nil;
end;
{ TUGGroup }
procedure TUGGroup.SetName(AValue: string);
begin
if FName=AValue then Exit;
if Groups.GetGroup(AValue,false)<>nil then
raise Exception.Create('TUGGroup.SetName name already exists');
Groups.fGroups.Remove(Self);
FName:=AValue;
Groups.fGroups.Add(Self);
end;
constructor TUGGroup.Create(aName: string; TheGroups: TUGGroups);
begin
FName:=aName;
FGroups:=TheGroups;
FUnits:=TAVLTree.Create(@CompareUGUnitFilenames);
end;
destructor TUGGroup.Destroy;
begin
Clear;
if not Groups.fClearing then
Groups.FGroups.Remove(Self);
fGroups:=nil;
FreeAndNil(FUnits);
inherited Destroy;
end;
procedure TUGGroup.Clear;
var
Node: TAVLTreeNode;
begin
Node:=FUnits.FindLowest;
while Node<>nil do begin
TUGGroupUnit(Node.Data).Group:=nil;
Node:=FUnits.FindSuccessor(Node);
end;
FUnits.Clear;
end;
procedure TUGGroup.AddUnit(anUnit: TUGGroupUnit);
begin
if anUnit.Group<>nil then begin
anUnit.Group.FUnits.Remove(anUnit);
anUnit.Group:=nil;
end;
FUnits.Add(anUnit);
anUnit.Group:=Self;
end;
procedure TUGGroup.RemoveUnit(anUnit: TUGGroupUnit);
begin
if (anUnit.Group<>nil) and (anUnit.Group<>Self) then
raise Exception.Create('TUGGroup.RemoveUnit inconsistency');
FUnits.Remove(anUnit);
anUnit.Group:=nil;
end;
end.
|
