1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162
163
164
165
166
167
168
169
170
171
172
173
174
175
176
177
178
179
180
181
182
183
184
185
186
187
188
189
190
191
192
193
194
195
196
197
198
199
200
201
202
203
204
205
206
207
208
209
210
211
212
213
214
215
216
217
218
219
220
221
222
223
224
225
226
227
228
229
230
231
232
233
234
235
236
237
238
239
240
241
242
243
244
245
246
247
248
249
250
251
252
253
254
255
256
257
258
259
260
261
262
263
264
265
266
267
268
269
270
|
unit DebugInOutputProcessor;
{$mode objfpc}{$H+}
interface
uses
Classes,
SysUtils,
fpjson,
FpDbgUtil,
DebugThreadCommand,
DbgIntfDebuggerBase,
debugthread,
FpDbgClasses,
typinfo,
variants,
jsonparser;
type
{ TCustomInOutputProcessor }
TCustomInOutputProcessor = class
private
FConnectionIdentifier: integer;
protected
FOnLog: TOnLog;
public
constructor create(AConnectionIdentifier: integer; AnOnLog: TOnLog); virtual;
function TextToCommand(const ACommandText: string): TFpDebugThreadCommand; virtual; abstract;
function EventToText(AnEvent: TFpDebugEvent): string; virtual; abstract;
end;
{ TJSonInOutputProcessor }
TJSonInOutputProcessor = class(TCustomInOutputProcessor)
public
function TextToCommand(const ACommandText: string): TFpDebugThreadCommand; override;
function EventToText(AnEvent: TFpDebugEvent): string; override;
class function InteractiveInitializationMessage(APort: integer): string;
end;
implementation
{ TCustomInOutputProcessor }
constructor TCustomInOutputProcessor.create(AConnectionIdentifier: integer; AnOnLog: TOnLog);
begin
FConnectionIdentifier:=AConnectionIdentifier;
FOnLog:=AnOnLog;
end;
{ TJSonInOutputProcessor }
function TJSonInOutputProcessor.TextToCommand(const ACommandText: string): TFpDebugThreadCommand;
var
AJSonCommand: TJSONData;
AJSonProp: TJSONData;
AJSonUID: TJSONData;
AnUID: variant;
ACommandClass: TFpDebugThreadCommandClass;
s: string;
i: integer;
APropCount: integer;
APropList: PPropList;
APropName: string;
begin
result := nil;
try
AJSonCommand := GetJSON(ACommandText);
except
on E: Exception do
begin
TFpDebugThread.Instance.SendNotification(FConnectionIdentifier, ntInvalidCommand, NULL, 'Command "%s" is not a valid JSON string: %s', ACommandText, [ACommandText, e.Message]);
Exit;
end;
end;
if not assigned(AJSonCommand) then
begin
TFpDebugThread.Instance.SendNotification(FConnectionIdentifier, ntInvalidCommand, NULL, 'Command "%s" is not a valid JSON string.', ACommandText, [ACommandText]);
exit;
end;
try
if AJSonCommand.JSONType<>jtObject then
begin
TFpDebugThread.Instance.SendNotification(FConnectionIdentifier, ntInvalidCommand, NULL, 'Command "%s" is not a JSON-object.', ACommandText, [ACommandText]);
exit;
end;
s := TJSONObject(AJSonCommand).Get('command', '');
if s = '' then
begin
TFpDebugThread.Instance.SendNotification(FConnectionIdentifier, ntInvalidCommand, NULL, 'Command "%s" does not contain a "command" entry.', ACommandText,[ACommandText]);
exit;
end;
ACommandClass := TFpDebugThreadCommandList.instance.GetCommandByName(s);
if not assigned(ACommandClass) then
begin
TFpDebugThread.Instance.SendNotification(FConnectionIdentifier, ntInvalidCommand, NULL, 'Command "%s" does not exist.', s, [S]);
exit;
end;
AJSonUID := TJSONObject(AJSonCommand).find('uid');
if assigned(AJSonUID) then
AnUID := AJSonUID.Value
else
AnUID := null;
result := ACommandClass.Create(FConnectionIdentifier, AnUID, FOnLog);
APropCount := GetPropList(result, APropList);
try
for i := 0 to APropCount-1 do
begin
APropName := APropList^[i]^.Name;
AJSonProp := TJSONObject(AJSonCommand).Find(LowerCase(APropName));
if assigned(AJSonProp) then
begin
case APropList^[i]^.PropType^.Kind of
tkAString, tkString, tkUString:
SetStrProp(result, APropList^[i], AJSonProp.AsString);
tkInteger:
SetOrdProp(result, APropList^[i], AJSonProp.AsInteger);
end;
end;
end;
finally
Freemem(APropList);
end;
finally
AJSonCommand.Free;
end;
end;
function TJSonInOutputProcessor.EventToText(AnEvent: TFpDebugEvent): string;
var
JSonEvent: TJSONObject;
JSonLocationRec: TJSONObject;
JSonArray: TJSONArray;
JSonArrayEntry: TJSONObject;
i: Integer;
begin
JSonEvent := TJSONObject.Create;
try
JSonEvent.Add('type',FpEventTypeNames[AnEvent.EventType]);
if AnEvent.BreakpointServerIdr<>0 then
JSonEvent.Add('BreakpointServerIdr', AnEvent.BreakpointServerIdr);
if AnEvent.SendByConnectionIdentifier>0 then
JSonEvent.Add('connIdentifier', AnEvent.SendByConnectionIdentifier);
if AnEvent.Validity<>ddsUnknown then
JSonEvent.Add('validity', DebuggerDataStateStr[AnEvent.Validity]);
if AnEvent.LocationRec.Address <> 0 then
begin
JSonLocationRec := TJSONObject.Create;
JSonLocationRec.Add('address', FormatAddress(AnEvent.LocationRec.Address));
JSonLocationRec.Add('funcName', AnEvent.LocationRec.FuncName);
JSonLocationRec.Add('srcFile', AnEvent.LocationRec.SrcFile);
JSonLocationRec.Add('srcFullName', AnEvent.LocationRec.SrcFullName);
JSonLocationRec.Add('srcLine', AnEvent.LocationRec.SrcLine);
JSonEvent.Add('locationRec',JSonLocationRec);
end;
if not varisnull(AnEvent.AnUID) then
begin
if VarIsOrdinal(AnEvent.AnUID) then
JSonEvent.Add('uid', integer(AnEvent.AnUID))
else
JSonEvent.Add('uid', VarToStr(AnEvent.AnUID));
end;
case AnEvent.EventType of
etEvent:
begin
JSonEvent.Add('eventName',AnEvent.EventName);
if AnEvent.InstructionPointerRegValue<>0 then
JSonEvent.Add('instrPointer', FormatAddress(AnEvent.InstructionPointerRegValue));
end;
etLog :
begin
case AnEvent.LogLevel of
dllDebug: JSonEvent.Add('logType','debug');
dllError: JSonEvent.Add('logType','error');
dllInfo: JSonEvent.Add('logType','info');
end;
end;
etNotification:
begin
JSonEvent.Add('notificationType',FpDebugNotificationTypeNames[AnEvent.NotificationType]);
if AnEvent.EventName<>'' then
JSonEvent.Add('command',AnEvent.EventName);
end;
end;
JSonEvent.Add('message',AnEvent.Message);
if length(AnEvent.StackEntryArray)>0 then
begin
JSonArray := TJSONArray.Create;
for i := 0 to high(AnEvent.StackEntryArray) do
begin
JSonArrayEntry := TJSONObject.Create;
JSonArrayEntry.Add('address', FormatAddress(AnEvent.StackEntryArray[i].AnAddress));
JSonArrayEntry.Add('frameaddress', FormatAddress(AnEvent.StackEntryArray[i].FrameAdress));
JSonArrayEntry.Add('sourcefile', AnEvent.StackEntryArray[i].SourceFile);
JSonArrayEntry.Add('line', AnEvent.StackEntryArray[i].Line);
JSonArrayEntry.Add('functionname', AnEvent.StackEntryArray[i].FunctionName);
JSonArray.Add(JSonArrayEntry);
end;
JSonEvent.Add('callstack', JSonArray);
end;
if length(AnEvent.DisassemblerEntryArray)>0 then
begin
JSonArray := TJSONArray.Create;
for i := 0 to high(AnEvent.DisassemblerEntryArray) do
begin
JSonArrayEntry := TJSONObject.Create;
JSonArrayEntry.Add('address', FormatAddress(AnEvent.DisassemblerEntryArray[i].Addr));
JSonArrayEntry.Add('dump', AnEvent.DisassemblerEntryArray[i].Dump);
JSonArrayEntry.Add('statement', AnEvent.DisassemblerEntryArray[i].Statement);
JSonArrayEntry.Add('srcfilename', AnEvent.DisassemblerEntryArray[i].SrcFileName);
JSonArrayEntry.Add('srcfileline', AnEvent.DisassemblerEntryArray[i].SrcFileLine);
JSonArrayEntry.Add('srcstatementindex', AnEvent.DisassemblerEntryArray[i].SrcStatementIndex);
JSonArrayEntry.Add('srcstatementcount', AnEvent.DisassemblerEntryArray[i].SrcStatementCount);
JSonArrayEntry.Add('functionname', AnEvent.DisassemblerEntryArray[i].FuncName);
JSonArrayEntry.Add('offset', AnEvent.DisassemblerEntryArray[i].Offset);
JSonArray.Add(JSonArrayEntry);
end;
JSonEvent.Add('disassembly', JSonArray);
JSonEvent.Add('startaddress', FormatAddress(AnEvent.Addr1));
JSonEvent.Add('endaddress', FormatAddress(AnEvent.Addr2));
JSonEvent.Add('lastentryendaddress', FormatAddress(AnEvent.Addr3));
end;
if length(AnEvent.WatchEntryArray)>0 then
begin
JSonArray := TJSONArray.Create;
for i := 0 to high(AnEvent.WatchEntryArray) do
begin
JSonArrayEntry := TJSONObject.Create;
JSonArrayEntry.Add('name', AnEvent.WatchEntryArray[i].Expression);
JSonArrayEntry.Add('value', AnEvent.WatchEntryArray[i].TextValue);
if AnEvent.EventName='registers' then
begin
JSonArrayEntry.Add('numvalue', AnEvent.WatchEntryArray[i].NumValue);
JSonArrayEntry.Add('size', AnEvent.WatchEntryArray[i].Size);
end;
JSonArray.Add(JSonArrayEntry);
end;
JSonEvent.Add(AnEvent.EventName, JSonArray);
end;
result := JSonEvent.AsJSON;
finally
JSonEvent.Free;
end;
end;
class function TJSonInOutputProcessor.InteractiveInitializationMessage(APort: integer): string;
var
JSonMessage: TJSONObject;
begin
JSonMessage := TJSONObject.Create;
try
JSonMessage.Add('welcome', 'FPDebug Server');
JSonMessage.Add('copyright', 'Joost van der Sluis (2015)');
if APort>-1 then
JSonMessage.Add('port', APort);
result := JSonMessage.AsJSON;
finally
JSonMessage.Free;
end;
end;
end.
|
