1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162
163
164
165
166
167
168
169
170
171
172
173
174
175
176
177
178
179
180
181
182
183
184
185
186
|
unit NoSpaceBefore;
{ AFS 5 Jan 2002
No space before certain tokens (e.g. '.' ';'
the Colon has it's own unit }
{(*}
(*------------------------------------------------------------------------------
Delphi Code formatter source code
The Original Code is NoSpaceBefore, released May 2003.
The Initial Developer of the Original Code is Anthony Steele.
Portions created by Anthony Steele are Copyright (C) 1999-2008 Anthony Steele.
All Rights Reserved.
Contributor(s): Anthony Steele.
The contents of this file are subject to the Mozilla Public License Version 1.1
(the "License"). you may not use this file except in compliance with the License.
You may obtain a copy of the License at http://www.mozilla.org/NPL/
Software distributed under the License is distributed on an "AS IS" basis,
WITHOUT WARRANTY OF ANY KIND, either express or implied.
See the License for the specific language governing rights and limitations
under the License.
Alternatively, the contents of this file may be used under the terms of
the GNU General Public License Version 2 or later (the "GPL")
See http://www.gnu.org/licenses/gpl.html
------------------------------------------------------------------------------*)
{*)}
{$I JcfGlobal.inc}
interface
uses SwitchableVisitor;
type
TNoSpaceBefore = class(TSwitchableVisitor)
private
fbSafeToRemoveReturn: boolean; // this taken from NoReturnBefore
protected
function EnabledVisitSourceToken(const pcNode: TObject): boolean; override;
public
constructor Create; override;
function IsIncludedInSettings: boolean; override;
end;
implementation
uses JcfSettings, SourceToken, Tokens, ParseTreeNodeType,
FormatFlags, TokenUtils, SettingsTypes;
const
NoSpaceAnywhere: TTokenTypeSet = [ttDot, ttComma,
ttCloseSquareBracket, ttCloseBracket];
function HasNoSpaceBefore(const pt: TSourceToken): boolean;
var
lcPrev: TSourceToken;
begin
Result := False;
if pt = nil then
exit;
{ do not apply this rule just after a conditional compilation directive }
lcPrev := pt.PriorTokenWithExclusions([ttWhiteSpace, ttReturn]);
if (lcPrev <> nil) and (lcPrev.TokenType = ttComment) and (lcPrev.CommentStyle = eCompilerDirective) then
exit;
if pt.HasParentNode(nLiteralString) then
begin
Result := not StartsLiteralString(pt);
exit;
end;
// '@@' in asm, e.g. "JE @@initTls" needs the space
if pt.HasParentNode(nAsm) then
exit;
if pt.TokenType in NoSpaceAnywhere then
begin
Result := True;
exit;
end;
// semicolon usually, except after 'begin' and another semicolon
if pt.TokenType = ttSemiColon then
begin
lcPrev := pt.PriorTokenWithExclusions(NotSolidTokens);
if not (lcPrev.TokenType in [ttSemiColon, ttBegin]) then
begin
Result := True;
exit;
end;
end;
{ hat (dereference) in expression is unary postfix operator - so no space before it }
if (pt.HasParentNode(nExpression)) and (pt.TokenType = ttHat) then
begin
Result := True;
exit;
end;
{ no space before open brackets for fn name - declaration or use }
if IsActualParamOpenBracket(pt) or IsFormalParamOpenBracket(pt) then
begin
Result := True;
exit;
end;
{ no space before colon -- anywhere? }
if pt.TokenType = ttColon then
begin
Result := True;
exit;
end;
if (FormattingSettings.Spaces.SpaceForOperator = eNever) then
begin
if IsSymbolOperator(pt) then
begin
Result := True;
exit;
end;
end;
{ '[' of array property definition }
if (pt.TokenType = ttOpenSquareBracket) and pt.HasParentNode(nProperty) then
begin
Result := True;
exit;
end;
end;
constructor TNoSpaceBefore.Create;
begin
inherited;
fbSafeToRemoveReturn := True;
FormatFlags := FormatFlags + [eRemoveSpace];
end;
function TNoSpaceBefore.EnabledVisitSourceToken(const pcNode: TObject): boolean;
var
lcSourceToken: TSourceToken;
lcNext: TSourceToken;
begin
Result := False;
lcSourceToken := TSourceToken(pcNode);
// not safe to remove return at a comment like this
if (lcSourceToken.TokenType = ttComment) and
(lcSourceToken.CommentStyle = eDoubleSlash) then
fbSafeToRemoveReturn := False
else if (lcSourceToken.TokenType <> ttReturn) then
fbSafeToRemoveReturn := True;
// work on whitespace and returns
if ( not (lcSourceToken.TokenType in [ttWhiteSpace, ttReturn])) or
( not fbSafeToRemoveReturn) then
exit;
lcNext := lcSourceToken.NextToken;
if lcNext = nil then
exit;
if HasNoSpaceBefore(lcNext) then
begin
// the space
BlankToken(lcSourceToken);
end;
end;
function TNoSpaceBefore.IsIncludedInSettings: boolean;
begin
Result := FormattingSettings.Spaces.FixSpacing;
end;
end.
|
