1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
|
{ Copyright (C) 2006 Darius Blaszijk
This source is free software; you can redistribute it and/or modify it under
the terms of the GNU General Public License as published by the Free
Software Foundation; either version 2 of the License, or (at your option)
any later version.
This code is distributed in the hope that it will be useful, but WITHOUT ANY
WARRANTY; without even the implied warranty of MERCHANTABILITY or FITNESS
FOR A PARTICULAR PURPOSE. See the GNU General Public License for more
details.
A copy of the GNU General Public License is available on the World Wide Web
at <http://www.gnu.org/copyleft/gpl.html>. You can also obtain it by writing
to the Free Software Foundation, Inc., 51 Franklin Street - Fifth Floor,
Boston, MA 02110-1335, USA.
}
unit ideprinting;
{$mode objfpc}{$H+}
interface
uses
Classes, SysUtils, LCLtype;
procedure PrintFile(Sender: TObject);
procedure Register;
implementation
uses
MenuIntf, IDECommands, Controls, Forms, Dialogs, SrcEditorIntf, SourcePrinter;
resourcestring
SDescrFormatting = 'Formatting';
SDescrPFSelection = 'Print ...';
SPFSelectionCmd = 'Print';
SPrintSources = 'Print sources';
SPrintWhat = 'What would you like to print ?';
SPrintFile = 'Complete file';
SPrintSelection = 'Selected text';
var
CmdFormatSelection : TIDECommand;
procedure Register;
var
Key : TIDEShortCut;
Cat : TIDECommandCategory;
begin
Key:=IDEShortCut(VK_P,[SSctrl],VK_UNKNOWN,[]);
{$ifndef USECustomCategory}
Cat:=IDECommandList.CreateCategory(nil,
'PrintFormatting',
SDescrFormatting,
IDECmdScopeSrcEditOnly);
{$else}
cat:=nil;
{$endif}
CmdFormatSelection:=RegisterIDECommand(Cat,
'PrintSelection',
SPFSelectionCmd,
Key,nil,@PrintFile);
//file main menu item
RegisterIDEMenuCommand(itmFileDirectories,
'PrintSelection',
SDescrPFSelection,
nil,nil,CmdFormatSelection, 'menu_file_print');
//source editor popup
RegisterIDEMenuCommand(SrcEditMenuSectionPages,
'PrintSelection',
SDescrPFSelection,
nil,nil,CmdFormatSelection, 'menu_file_print');
end;
procedure PrintFile(Sender: TObject);
var
sp: TSourcePrinter;
L : TStrings;
R : TModalResult;
begin
If Not Assigned(SourceEditorManagerIntf) or Not Assigned(SourceEditorManagerIntf.ActiveEditor) then
Exit;
If (SourceEditorManagerIntf.ActiveEditor.Selection='') then
R:=mrYesToAll
else
R:=QuestionDlg(SPrintSources,SPrintWhat,mtInformation,[mrYesToAll,SPrintFile,mrYes,SPrintSelection,mrCancel],0);
If R=mrCancel then
exit;
L:=TStringList.Create;
try
case R of
mrYesToAll : L.Assign(SourceEditorManagerIntf.ActiveEditor.Lines);
mrYes : L.Text:=SourceEditorManagerIntf.ActiveEditor.Selection;
end;
sp := TSourcePrinter.Create;
try
sp.Execute(L);
finally
sp.Free;
end;
finally
L.Free;
end;
end;
end.
|
