1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162
163
164
165
166
167
168
169
170
171
172
173
174
175
176
177
178
179
180
181
182
183
184
185
186
187
188
189
190
191
192
193
194
195
196
197
198
199
200
201
202
203
204
205
206
207
208
209
210
211
212
213
214
215
216
217
218
219
220
221
222
223
224
225
226
227
228
229
230
|
{
***************************************************************************
* *
* This source is free software; you can redistribute it and/or modify *
* it under the terms of the GNU General Public License as published by *
* the Free Software Foundation; either version 2 of the License, or *
* (at your option) any later version. *
* *
* This code is distributed in the hope that it will be useful, but *
* WITHOUT ANY WARRANTY; without even the implied warranty of *
* MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the GNU *
* General Public License for more details. *
* *
* A copy of the GNU General Public License is available on the World *
* Wide Web at <http://www.gnu.org/copyleft/gpl.html>. You can also *
* obtain it by writing to the Free Software Foundation, *
* Inc., 51 Franklin Street - Fifth Floor, Boston, MA 02110-1335, USA. *
* *
***************************************************************************
}
unit codeobserver_options;
{$mode objfpc}{$H+}
interface
uses
Classes, SysUtils,
// LCL
Forms, Graphics, ExtCtrls, Spin, StdCtrls,
// IdeIntf
IDEOptionsIntf, IDEOptEditorIntf,
// IDE
LazarusIDEStrConsts, CodeExplOpts;
type
{ TCodeObserverOptionsFrame }
TCodeObserverOptionsFrame = class(TAbstractIDEOptionsEditor)
UnnamedCharConstCheckBox: TCheckBox;
CodeObsCategoriesCheckGroup: TCheckGroup;
CodeObsIgnoreConstantsLabel: TLabel;
COIgnoreConstInFuncsLabel: TLabel;
LongProcLineCountLabel: TLabel;
LongParamListCountLabel: TLabel;
CodeObsIgnoreConstantsMemo: TMemo;
COIgnoreConstInFuncsMemo: TMemo;
NestedProcCountLabel: TLabel;
LongProcLineCountSpinEdit: TSpinEdit;
LongParamListCountSpinEdit: TSpinEdit;
NestedProcCountSpinEdit: TSpinEdit;
CodeObsLeftPanel: TPanel;
UnnamedCharConstLabel: TLabel;
procedure CodeObsCategoriesCheckGroupItemClick(Sender: TObject;
Index: integer);
private
FCategoryCheckBoxes: array [TCEObserverCategory] of TCheckBox;
FGroupCheckBoxes: array [TCEObserverCategoryGroup] of TCheckBox;
public
function GetTitle: String; override;
procedure Setup({%H-}ADialog: TAbstractOptionsEditorDialog); override;
procedure ReadSettings(AOptions: TAbstractIDEOptions); override;
procedure WriteSettings(AOptions: TAbstractIDEOptions); override;
class function SupportedOptionsClass: TAbstractIDEOptionsClass; override;
end;
implementation
{$R *.lfm}
const
GroupCategories: array [TCEObserverCategoryGroup] of TCEObserverCategories = (
[cefcLongProcs, cefcLongParamLists, cefcNestedProcs],
[cefcEmptyProcs, cefcEmptyBlocks, cefcEmptyClassSections],
[cefcUnnamedConsts, cefcUnsortedClassVisibility, cefcUnsortedClassMembers],
[cefcPublishedPropWithoutDefault, cefcWrongIndentation, cefcToDos]);
function GroupName(AGroup: TCEObserverCategoryGroup): String;
begin
case AGroup of
ocgComplexity: Result := lisCEComplexityGroup;
ocgEmpty: Result := lisCEEmptyGroup;
ocgStyle: Result := lisCEStyleGroup;
ocgOther: Result := lisCEOtherGroup;
else Result := '?';
end;
end;
{ TCodeObserverOptionsFrame }
procedure TCodeObserverOptionsFrame.CodeObsCategoriesCheckGroupItemClick(
Sender: TObject; Index: integer);
var
c: TCEObserverCategory;
g: TCEObserverCategoryGroup;
hasState: array [Boolean] of Boolean;
begin
CodeObsCategoriesCheckGroup.OnItemClick := nil;
try
for g := Low(g) to High(g) do begin
hasState[true] := false;
hasState[false] := false;
for c := Low(c) to High(c) do
if c in GroupCategories[g] then
hasState[FCategoryCheckBoxes[c].Checked] := true;
if (Sender <> nil)
and (FGroupCheckBoxes[g] = CodeObsCategoriesCheckGroup.Components[Index])
then begin
// Check/uncheck all categories in group
for c := Low(c) to High(c) do
if c in GroupCategories[g] then
FCategoryCheckBoxes[c].Checked := hasState[false];
FGroupCheckBoxes[g].Checked := hasState[false]
end
else if hasState[true] and hasState[false] then
FGroupCheckBoxes[g].State := cbGrayed
else
FGroupCheckBoxes[g].Checked := not hasState[false];
end;
finally
CodeObsCategoriesCheckGroup.OnItemClick :=
@CodeObsCategoriesCheckGroupItemClick;
end;
end;
function TCodeObserverOptionsFrame.GetTitle: String;
begin
Result := lisCodeObserver;
end;
procedure TCodeObserverOptionsFrame.Setup(
ADialog: TAbstractOptionsEditorDialog);
var
c: TCEObserverCategory;
g: TCEObserverCategoryGroup;
function AddCheckBox(ACaption: String): TCheckBox;
begin
with CodeObsCategoriesCheckGroup do
Result := TCheckBox(Components[Items.Add(ACaption)]);
end;
begin
CodeObsCategoriesCheckGroup.Caption := lisCEShowCodeObserver;
CodeObsCategoriesCheckGroup.OnItemClick := nil;
try
for g := Low(g) to High(g) do begin
FGroupCheckBoxes[g] := AddCheckBox(GroupName(g) + ':');
with FGroupCheckBoxes[g] do begin
AllowGrayed := true;
State := cbGrayed;
Font.Style := [fsItalic];
end;
for c := Low(c) to High(c) do
if c in GroupCategories[g] then
FCategoryCheckBoxes[c] :=
AddCheckBox(' ' + CodeExplorerLocalizedString(c));
end;
finally
CodeObsCategoriesCheckGroup.OnItemClick :=
@CodeObsCategoriesCheckGroupItemClick;
end;
LongProcLineCountLabel.Caption := lisCELongProcLineCount;
LongParamListCountLabel.Caption := lisCELongParamListCount;
NestedProcCountLabel.Caption := lisCENestedProcCount;
UnnamedCharConstLabel.Caption := lisCodeObsCharConst;
UnnamedCharConstCheckBox.Caption := lisShow;
CodeObsIgnoreConstantsLabel.Caption := lisCodeObsIgnoreeConstants;
COIgnoreConstInFuncsLabel.Caption := lisCodeObIgnoreConstInFuncs;
end;
procedure TCodeObserverOptionsFrame.ReadSettings(
AOptions: TAbstractIDEOptions);
var
c: TCEObserverCategory;
Tmp: TStrings;
begin
with TCodeExplorerOptions(AOptions) do
begin
for c := Low(c) to High(c) do
FCategoryCheckBoxes[c].Checked := c in ObserverCategories;
CodeObsCategoriesCheckGroupItemClick(nil, -1);
LongProcLineCountSpinEdit.Value := LongProcLineCount;
LongParamListCountSpinEdit.Value := LongParamListCount;
NestedProcCountSpinEdit.Value := NestedProcCount;
UnnamedCharConstCheckBox.Checked := ObserveCharConst;
Tmp := CreateListOfCOIgnoreConstants;
CodeObsIgnoreConstantsMemo.Lines.Assign(Tmp);
Tmp.Free;
Tmp := CreateListOfCOIgnoreConstInFuncs;
COIgnoreConstInFuncsMemo.Lines.Assign(Tmp);
Tmp.Free;
end;
end;
procedure TCodeObserverOptionsFrame.WriteSettings(
AOptions: TAbstractIDEOptions);
var
NewCategories: TCEObserverCategories;
c: TCEObserverCategory;
begin
NewCategories := [];
for c := Low(c) to high(c) do
if FCategoryCheckBoxes[c].Checked then
Include(NewCategories, c);
with TCodeExplorerOptions(AOptions) do
begin
ObserverCategories := NewCategories;
LongProcLineCount := LongProcLineCountSpinEdit.Value;
LongParamListCount := LongParamListCountSpinEdit.Value;
NestedProcCount := NestedProcCountSpinEdit.Value;
ObserveCharConst := UnnamedCharConstCheckBox.Checked;
SetListOf_COIgnoreConstants(CodeObsIgnoreConstantsMemo.Lines, False);
SetListOf_COIgnoreConstInFuncs(COIgnoreConstInFuncsMemo.Lines, False);
end;
end;
class function TCodeObserverOptionsFrame.SupportedOptionsClass: TAbstractIDEOptionsClass;
begin
Result := TCodeExplorerOptions;
end;
initialization
RegisterIDEOptionsEditor(GroupCodeExplorer, TCodeObserverOptionsFrame, cdeOptionsFigures);
end.
|
