1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
|
unit FppkgHelper;
{$mode objfpc}{$H+}
interface
uses
Classes,
SysUtils,
{$IFNDEF VER3_0}
pkgFppkg,
{$ENDIF VER3_0}
fprepos;
type
{ TFppkgHelper }
TFppkgHelper = class
private
{$IFNDEF VER3_0}
FFPpkg: TpkgFPpkg;
{$ENDIF}
public
constructor Create;
destructor Destroy; override;
class function Instance: TFppkgHelper;
function HasPackage(const PackageName: string): Boolean;
procedure ListPackages(AList: TStringList);
end;
implementation
var
GFppkgHelper: TFppkgHelper = nil;
{ TFppkgHelper }
constructor TFppkgHelper.Create;
{$IFNDEF VER3_0}
var
FPpkg: TpkgFPpkg;
begin
FPpkg := TpkgFPpkg.Create(nil);
try
FPpkg.InitializeGlobalOptions('');
FPpkg.InitializeCompilerOptions;
FPpkg.CompilerOptions.CheckCompilerValues;
FPpkg.FpmakeCompilerOptions.CheckCompilerValues;
FPpkg.LoadLocalAvailableMirrors;
FPpkg.ScanPackages;
FFPpkg := FPpkg;
FPpkg := nil;
finally
FPpkg.Free;
end;
end;
{$ELSE}
begin
end;
{$ENDIF VER3_0}
destructor TFppkgHelper.Destroy;
begin
{$IFNDEF VER3_0}
FFPpkg.Free;
{$ENDIF VER3_0}
inherited Destroy;
end;
class function TFppkgHelper.Instance: TFppkgHelper;
begin
if not Assigned(GFppkgHelper) then
GFppkgHelper := TFppkgHelper.Create;
Result := GFppkgHelper;
end;
function TFppkgHelper.HasPackage(const PackageName: string): Boolean;
begin
{$IFNDEF VER3_0}
Result :=
Assigned(FFPpkg.FindPackage(PackageName,pkgpkInstalled)) or
Assigned(FFPpkg.FindPackage(PackageName,pkgpkAvailable)) or
Assigned(FFPpkg.FindPackage(PackageName,pkgpkBoth));
if not Result then
begin
// rescan and try again
FFppkg.LoadLocalAvailableMirrors;
FFppkg.ScanPackages;
Result :=
Assigned(FFPpkg.FindPackage(PackageName,pkgpkInstalled)) or
Assigned(FFPpkg.FindPackage(PackageName,pkgpkAvailable)) or
Assigned(FFPpkg.FindPackage(PackageName,pkgpkBoth));
end;
{$ELSE }
Result := True;
{$ENDIF VER3_0}
end;
procedure TFppkgHelper.ListPackages(AList: TStringList);
{$IFNDEF VER3_0}
var
I, J: Integer;
Repository: TFPRepository;
{$ENDIF VER3_0}
begin
{$IFNDEF VER3_0}
for I := 0 to FFPpkg.RepositoryList.Count -1 do
begin
Repository := FFPpkg.RepositoryList.Items[I] as TFPRepository;
for J := 0 to Repository.PackageCount -1 do
begin
AList.AddObject(Repository.Packages[J].Name, Repository.Packages[J]);
end;
end;
{$ENDIF VER3_0}
end;
finalization
GFppkgHelper.Free;
end.
|
