1 2 3 4 5 6 7 8 9 10 11 12 13 14 15 16 17 18 19 20 21 22 23 24 25 26 27 28 29 30 31 32 33 34 35 36 37 38 39 40 41 42 43 44 45 46 47 48 49 50 51 52 53 54 55 56 57 58 59 60 61 62 63 64 65 66 67 68 69 70 71 72 73 74 75 76 77 78 79 80 81 82 83 84 85 86 87 88 89 90 91 92 93 94 95 96 97 98 99 100 101 102 103 104 105 106 107 108 109 110 111 112 113 114 115 116 117 118 119 120 121 122 123 124 125 126 127 128 129 130 131 132 133 134 135 136 137 138 139 140 141 142 143 144 145 146 147 148 149 150 151 152 153 154 155 156 157 158 159 160 161 162 163 164 165 166 167 168 169 170 171 172 173 174 175 176 177 178 179 180 181 182 183 184 185 186 187 188 189 190 191 192 193 194 195 196 197 198 199 200 201 202 203 204 205 206 207 208 209 210 211 212 213 214 215 216 217 218 219 220 221 222 223 224 225
|
{ $Id: win32wscalendar.pp 52117 2016-04-06 17:08:54Z bart $}
{
*****************************************************************************
* Win32WSCalendar.pp *
* ------------------ *
* *
* *
*****************************************************************************
*****************************************************************************
This file is part of the Lazarus Component Library (LCL)
See the file COPYING.modifiedLGPL.txt, included in this distribution,
for details about the license.
*****************************************************************************
}
unit Win32WSCalendar;
{$mode objfpc}{$H+}
{.$define debug_win32calendar}
interface
uses
////////////////////////////////////////////////////
// I M P O R T A N T
////////////////////////////////////////////////////
// To get as little as posible circles,
// uncomment only when needed for registration
////////////////////////////////////////////////////
CommCtrl, SysUtils, Controls, LCLType, Calendar,
////////////////////////////////////////////////////
WSCalendar, WSLCLClasses, WSProc, Windows, Win32WSControls,
win32proc, win32extra;
type
{ TWin32WSCustomCalendar }
TWin32WSCustomCalendar = class(TWSCustomCalendar)
published
class function CreateHandle(const AWinControl: TWinControl;
const AParams: TCreateParams): HWND; override;
class procedure AdaptBounds(const AWinControl: TWinControl;
var Left, Top, Width, Height: integer; var SuppressMove: boolean); override;
class function GetConstraints(const AControl: TControl;
const AConstraints: TObject): Boolean; override;
class function GetDateTime(const ACalendar: TCustomCalendar): TDateTime; override;
class function HitTest(const ACalendar: TCustomCalendar; const APoint: TPoint): TCalendarPart; override;
class function GetCurrentView(const ACalendar: TCustomCalendar): TCalendarView; override;
class procedure SetDateTime(const ACalendar: TCustomCalendar; const ADateTime: TDateTime); override;
class procedure SetDisplaySettings(const ACalendar: TCustomCalendar; const ASettings: TDisplaySettings); override;
end;
implementation
uses
Win32Int, InterfaceBase;
{ TWin32WSCustomCalendar }
class function TWin32WSCustomCalendar.CreateHandle(const AWinControl: TWinControl;
const AParams: TCreateParams): HWND;
var
Params: TCreateWindowExParams;
begin
// general initialization of Params
PrepareCreateWindow(AWinControl, AParams, Params);
// customization of Params
with Params do
begin
pClassName := 'SysMonthCal32';
WindowTitle := StrCaption;
if dsShowWeekNumbers in TCustomCalendar(AWinControl).DisplaySettings then
Flags := Flags or MCS_WEEKNUMBERS;
SubClassWndProc := @WindowProc;
end;
// create window
FinishCreateWindow(AWinControl, Params, False);
Result := Params.Window;
SetClassLongPtr(Result, GCL_STYLE, GetClassLongPtr(Result, GCL_STYLE) or CS_DBLCLKS);
// resize to proper size
SetBounds(AWinControl, Params.Left, Params.Top, 0, 0);
end;
class procedure TWin32WSCustomCalendar.AdaptBounds(const AWinControl: TWinControl;
var Left, Top, Width, Height: integer; var SuppressMove: boolean);
var
WinHandle: HWND;
lRect: TRect;
TodayWidth: integer;
begin
WinHandle := AWinControl.Handle;
Windows.SendMessage(WinHandle, MCM_GETMINREQRECT, 0, LPARAM(@lRect));
Width := lRect.Right;
Height := lRect.Bottom;
// according to msdn to ensure that today string is not clipped we need to choose
// maximal width between that rectangle and today string width
// this needs to be done only if we are showing today string
if (GetWindowLong(WinHandle, GWL_STYLE) and MCS_NOTODAY) = 0 then
begin
TodayWidth := Windows.SendMessage(WinHandle, MCM_GETMAXTODAYWIDTH, 0, 0);
if Width < TodayWidth then
Width := TodayWidth;
end;
end;
class function TWin32WSCustomCalendar.GetConstraints(const AControl: TControl;
const AConstraints: TObject): Boolean;
var
SizeConstraints: TSizeConstraints absolute AConstraints;
SizeRect: TRect;
Height, Width: Integer;
begin
Result := True;
if (AConstraints is TSizeConstraints) and TWinControl(AControl).HandleAllocated then
begin
Windows.GetWindowRect(TWinControl(AControl).Handle, @SizeRect);
Height := SizeRect.Bottom - SizeRect.Top;
Width := SizeRect.Right - SizeRect.Left;
SizeConstraints.SetInterfaceConstraints(Width, Height, Width, Height);
end;
end;
class function TWin32WSCustomCalendar.GetDateTime(const ACalendar: TCustomCalendar): TDateTime;
var
ST: SystemTime;
begin
SendMessage(ACalendar.Handle, MCM_GETCURSEL, 0, LPARAM(@ST));
Result := EncodeDate(ST.WYear,ST.WMonth,ST.WDay);
end;
class function TWin32WSCustomCalendar.HitTest(const ACalendar: TCustomCalendar;
const APoint: TPoint): TCalendarPart;
var
HitTestInfo: MCHITTESTINFO;
HitPart: DWord;
begin
{$ifdef debug_win32calendar}
writeln('TWin32WSCustomCalendar.HitTest:');
writeln(' ComCtlVersion = ',IntToHex(ComCtlVersion,8),' [ComCtlVersionIE6=',IntToHex(ComCtlVersionIE6,8),']');
writeln(' HasManifest = ',HasManifest);
writeln(' SizeOf(HitTestInfo) = ',SizeOf(HitTestInfo));
{$endif}
Result := cpNoWhere;
if not WSCheckHandleAllocated(ACalendar, 'TWin32WSCustomCalendar.HitTest') then
Exit;
FillChar(HitTestInfo, SizeOf(HitTestInfo), 0);
//the MCHITTESTINFO structure not only depends on Windows version but also on wether or not
//the application has a Manifest (Issue #0029975)
if (WindowsVersion >= wvVista) and HasManifest then
HitTestInfo.cbSize := SizeOf(HitTestInfo)
else
HitTestInfo.cbSize := 32;
HitTestInfo.pt := APoint;
{$ifdef debug_win32calendar}
if IsConsole then writeln(' HitTestInfo.cbSize = ',HitTestInfo.cbSize);
{$endif}
HitPart := SendMessage(ACalendar.Handle, MCM_HITTEST, 0, LPARAM(@HitTestInfo));
{$ifdef debug_win32calendar}
//if IsConsole then writeln('TWin32WSCustomCalendar.HitTest: Handle = ',IntToHex(ACalendar.Handle,8));
if IsConsole then writeln(' APoint = (',APoint.x,',',APoint.y,'), pt = (',HitTestInfo.pt.x,',',HitTestInfo.pt.y,')');
if IsConsole then writeln(' HitPart = ',IntToHex(HitPart,8),', uHit = ',IntToHex(Hittestinfo.uHit,8));
{$endif}
case HitPart of
MCHT_CALENDARDATE,
MCHT_CALENDARDATENEXT,
MCHT_CALENDARDATEPREV,
MCHT_TODAYLINK: Result := cpDate;
MCHT_CALENDARWEEKNUM : Result := cpWeekNumber;
MCHT_TITLEBK: Result := cpTitle;
MCHT_TITLEMONTH: Result := cpTitleMonth;
MCHT_TITLEYEAR: Result := cpTitleYear;
MCHT_TITLEBTNNEXT,
MCHT_TITLEBTNPREV: Result := cpTitleBtn;
end;
end;
class function TWin32WSCustomCalendar.GetCurrentView(
const ACalendar: TCustomCalendar): TCalendarView;
var
CurrentView: LRESULT;
begin
Result := inherited GetCurrentView(ACalendar);
if WindowsVersion >= wvVista then begin
if not WSCheckHandleAllocated(ACalendar, 'TWin32WSCustomCalendar.GetCurrentView') then
Exit;
CurrentView := SendMessage(ACalendar.Handle, MCM_GETCURRENTVIEW, 0, 0);
case CurrentView of
MCMV_MONTH: Result := cvMonth;
MCMV_YEAR: Result := cvYear;
MCMV_DECADE: Result := cvDecade;
MCMV_CENTURY: Result := cvCentury;
end;
end;
end;
class procedure TWin32WSCustomCalendar.SetDateTime(const ACalendar: TCustomCalendar; const ADateTime: TDateTime);
var
ST: SystemTime;
begin
DecodeDate(ADateTime, ST.WYear, ST.WMonth, ST.WDay);
SendMessage(ACalendar.Handle, MCM_SETCURSEL, 0, Windows.LParam(@ST));
end;
class procedure TWin32WSCustomCalendar.SetDisplaySettings(const ACalendar: TCustomCalendar; const ASettings: TDisplaySettings);
var
Style: LongInt;
begin
if not WSCheckHandleAllocated(ACalendar, 'TWin32WSCustomCalendar.SetDisplaySettings') then
Exit;
Style := GetWindowLong(ACalendar.Handle, GWL_STYLE);
if dsShowWeekNumbers in ASettings then
Style := Style or MCS_WEEKNUMBERS
else
Style := Style and not MCS_WEEKNUMBERS;
SetWindowLong(ACalendar.Handle, GWL_STYLE, Style);
end;
end.
|