1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162
163
164
165
166
167
168
169
170
171
172
173
174
175
176
177
178
179
180
181
182
|
{%MainUnit ../graphics.pp}
{******************************************************************************
TFPImageBitmap
******************************************************************************
*****************************************************************************
This file is part of the Lazarus Component Library (LCL)
See the file COPYING.modifiedLGPL.txt, included in this distribution,
for details about the license.
*****************************************************************************
}
{ TFPImageBitmap }
class function TFPImageBitmap.GetFileExtensions: string;
begin
Result:='';
end;
class function TFPImageBitmap.IsStreamFormatSupported(Stream: TStream): Boolean;
var
Pos: Int64;
Reader: TFPCustomImageReader;
begin
Pos := Stream.Position;
Reader := GetReaderClass.Create;
try
Result := Reader.CheckContents(Stream);
finally
Reader.Free;
Stream.Position := Pos;
end;
end;
procedure TFPImageBitmap.FinalizeReader(AReader: TFPCustomImageReader);
begin
end;
procedure TFPImageBitmap.FinalizeWriter(AWriter: TFPCustomImageWriter);
var
LazWriter: ILazImageWriter;
begin
if Supports(AWriter, ILazImageWriter, LazWriter)
then LazWriter.Finalize;
end;
function TFPImageBitmap.GetMimeType: string;
{$IFDEF VerboseLCLTodos}{$note implement}{$ENDIF}
var
DefaultFileExt: String;
i: Integer;
begin
DefaultFileExt := GetFileExtensions;
i := 1;
while (i <= Length(DefaultFileExt)) and (DefaultFileExt[i] <> ';') do
inc(i);
if i <= Length(DefaultFileExt) then
DefaultFileExt := copy(DefaultFileExt, 1, i - 1);
Result := 'image/' + DefaultFileExt;
end;
procedure TFPImageBitmap.InitializeReader(AImage: TLazIntfImage; AReader: TFPCustomImageReader);
begin
AReader.OnProgress := @Progress;
end;
procedure TFPImageBitmap.InitializeWriter(AImage: TLazIntfImage; AWriter: TFPCustomImageWriter);
var
LazWriter: ILazImageWriter;
begin
AWriter.OnProgress := @Progress;
if Supports(AWriter, ILazImageWriter, LazWriter)
then LazWriter.Initialize(AImage);
end;
class function TFPImageBitmap.IsFileExtensionSupported(
const FileExtension: string): boolean;
var
Extensions: String;
StartPos: Integer;
EndPos: Integer;
i: Integer;
Ext: String;
begin
Result:=false;
if FileExtension='' then exit;
Extensions:=GetFileExtensions;
if Extensions='' then exit;
Ext:=FileExtension;
if Ext[1]='.' then begin
delete(Ext,1,1);
if Ext='' then exit;
end;
StartPos:=1;
while StartPos<=length(Extensions) do begin
if not (Extensions[StartPos] in [';',' ']) then begin
EndPos:=StartPos;
while (EndPos<=length(Extensions)) and (Extensions[EndPos]<>';') do
inc(EndPos);
if EndPos-StartPos=length(Ext) then begin
i:=1;
while (i<=length(Ext))
and (upcase(Extensions[StartPos+i-1])=upcase(Ext[i])) do
inc(i);
if i>length(Ext) then begin
Result:=true;
exit;
end;
end;
StartPos:=EndPos;
end else
inc(StartPos);
end;
end;
function TFPImageBitmap.LazarusResourceTypeValid(const ResourceType: string): boolean;
begin
Result:=IsFileExtensionSupported(ResourceType);
end;
procedure TFPImageBitmap.ReadStream(AStream: TMemoryStream; ASize: Longint);
var
SCB: TSharedCustomBitmap;
IntfImg: TLazIntfImage;
ImgReader: TFPCustomImageReader;
LazReader: ILazImageReader;
begin
IntfImg := nil;
ImgReader := nil;
try
// read image
ImgReader := GetReaderClass.Create;
ImgReader.OnProgress := Self.OnProgress;
IntfImg := TLazIntfImage.Create(0,0,[]);
InitializeReader(IntfImg, ImgReader);
if Supports(ImgReader, ILazImageReader, LazReader)
then LazReader.UpdateDescription := True
else IntfImg.DataDescription := GetDescriptionFromDevice(0, 0, 0); // fallback to default
ImgReader.ImageRead(AStream, IntfImg);
FinalizeReader(ImgReader);
// no need to care about unsharing image, thats done by calling proc
SCB := TSharedCustomBitmap(FSharedImage);
SCB.FImage.FreeData;
IntfImg.GetRawImage(SCB.FImage, True);
SCB.FHasMask := IntfImg.HasMask;
if not SCB.FHasMask
then SCB.FImage.Description.MaskBitsPerPixel := 0;
FPixelFormatNeedsUpdate := True;
finally
LazReader := nil;
IntfImg.Free;
ImgReader.Free;
end;
end;
procedure TFPImageBitmap.WriteStream(AStream: TMemoryStream);
var
IntfImg: TLazIntfImage;
ImgWriter: TFPCustomImageWriter;
RawImg: PRawImage;
begin
// write image to temporary stream
ImgWriter := nil;
RawImg:=GetRawImagePtr;
if RawImg^.DataSize > 0 then begin
IntfImg := TLazIntfImage.Create(0,0,[]);
try
ImgWriter := GetWriterClass.Create;
IntfImg.SetRawImage(RawImg^, False);
InitializeWriter(IntfImg, ImgWriter);
IntfImg.SaveToStream(AStream, ImgWriter);
FinalizeWriter(ImgWriter);
finally
IntfImg.Free;
ImgWriter.Free;
end;
end;
end;
|
