1 2 3 4 5 6 7 8 9 10 11 12 13 14 15 16 17 18 19 20 21 22 23 24 25 26 27 28 29 30 31 32 33 34 35 36 37 38 39 40 41 42 43 44 45 46 47 48 49 50 51 52 53 54 55 56 57 58 59 60 61 62 63 64 65 66 67 68 69 70 71 72 73 74 75 76 77 78 79 80 81 82 83 84 85 86 87 88 89 90 91 92 93 94 95 96 97 98 99 100 101 102 103 104 105 106 107 108 109 110 111 112 113 114 115 116 117 118 119 120 121 122 123 124 125 126 127 128 129 130 131 132 133 134 135 136 137 138 139 140 141 142 143 144 145 146 147 148 149 150 151 152 153 154 155 156 157 158 159 160 161 162 163 164 165 166 167 168 169 170 171 172 173 174 175 176 177 178 179 180 181 182 183 184 185 186 187 188 189 190 191 192 193 194 195 196 197 198 199 200 201 202 203 204 205 206 207 208 209 210 211 212 213 214 215 216 217 218 219 220 221 222 223 224 225 226 227 228 229 230 231 232 233 234 235 236 237 238 239 240 241 242 243 244 245 246 247 248 249 250 251 252 253 254 255 256 257 258 259 260 261 262 263 264 265 266 267 268 269 270 271 272 273 274 275 276 277 278 279 280 281 282 283 284 285 286 287 288 289 290 291 292 293 294 295 296 297 298 299 300 301 302 303 304 305 306 307 308 309 310 311 312 313 314 315 316 317 318 319 320 321 322 323 324 325 326 327 328 329 330 331 332 333 334 335 336 337 338 339 340 341 342 343 344 345 346 347 348 349 350 351 352 353 354 355 356 357 358 359 360 361 362 363 364 365 366 367 368 369 370 371 372 373 374 375 376 377 378 379 380 381 382 383 384 385 386 387 388 389 390 391 392 393 394 395 396 397 398 399 400 401 402 403 404 405 406 407 408 409 410 411 412 413 414 415 416 417 418 419 420 421 422 423 424 425 426 427 428 429 430 431 432 433 434 435 436 437 438 439 440 441 442 443 444 445 446 447 448 449 450 451 452 453 454 455 456 457 458 459 460 461 462 463 464 465 466 467 468 469 470 471 472 473 474 475 476 477 478 479 480 481 482 483 484 485 486 487 488 489 490 491 492 493 494 495 496 497 498 499 500 501 502 503 504 505 506 507 508 509 510 511 512 513 514 515 516 517 518 519 520 521 522 523 524 525 526 527 528 529 530 531 532 533 534 535 536 537 538 539 540 541 542 543 544 545 546 547 548 549 550 551 552 553 554 555 556 557 558 559 560 561 562 563 564 565 566 567 568 569 570 571 572 573 574 575 576 577 578 579 580 581 582 583 584 585 586 587 588 589 590 591 592 593 594 595 596 597 598 599 600 601 602 603 604 605 606 607 608 609 610 611 612 613 614 615 616 617 618 619 620 621 622 623 624 625 626 627 628 629 630 631 632 633 634 635 636 637 638 639 640 641 642 643 644 645 646 647 648 649 650 651 652 653 654 655 656 657 658 659 660 661 662 663 664 665 666 667 668 669 670 671 672 673 674 675 676 677 678 679 680 681 682 683 684 685 686 687 688 689 690 691 692 693 694 695 696 697 698 699 700 701 702 703 704 705 706 707 708 709 710 711 712 713 714 715 716 717 718 719 720 721 722 723 724 725 726 727 728 729 730 731 732 733 734 735 736 737 738 739 740 741 742 743 744 745 746 747 748 749 750 751 752 753 754 755 756 757 758 759 760 761 762 763 764 765 766 767 768 769 770 771 772 773 774 775 776 777 778 779 780 781 782 783 784 785 786 787 788 789 790 791 792 793 794 795 796 797 798 799 800 801 802 803 804 805 806 807 808 809 810 811 812 813 814 815 816 817 818 819 820 821 822 823 824 825 826 827 828 829 830 831 832 833 834 835 836 837 838 839 840 841 842 843 844 845 846 847 848 849 850 851 852 853 854 855 856 857 858 859 860 861 862 863 864 865 866 867 868 869 870 871 872 873 874 875 876 877 878 879 880 881 882 883 884 885 886 887 888 889 890 891 892 893 894 895 896 897 898 899 900 901 902 903 904 905 906 907 908 909 910 911 912 913 914 915 916 917 918 919 920 921 922 923 924 925 926 927 928 929 930 931 932 933 934 935 936 937 938 939 940 941 942 943 944 945 946 947 948 949 950 951 952 953 954 955 956 957 958 959 960 961 962 963 964 965 966 967 968 969 970 971 972 973 974 975 976 977 978 979 980 981 982 983 984 985 986 987 988 989 990 991 992 993 994
|
project(runtime C)
cmake_minimum_required(VERSION 2.8.12)
set(CMAKE_MODULE_PATH ${CMAKE_MODULE_PATH} ${CMAKE_CURRENT_SOURCE_DIR})
include(CheckIncludeFile)
# Verify required variables if this CMake project is NOT embedded in the LDC CMake project.
if(NOT LDC_EXE)
if(NOT LDC_EXE_FULL)
message(FATAL_ERROR "Please define the path to the LDC executable via -DLDC_EXE_FULL=...")
endif()
if(NOT DEFINED D_VERSION OR NOT DEFINED DMDFE_MINOR_VERSION OR NOT DEFINED DMDFE_PATCH_VERSION)
message(FATAL_ERROR "Please define the CMake variables D_VERSION, DMDFE_MINOR_VERSION and DMDFE_PATCH_VERSION.")
endif()
# Helper function
function(append value)
foreach(variable ${ARGN})
if(${variable} STREQUAL "")
set(${variable} "${value}" PARENT_SCOPE)
else()
set(${variable} "${${variable}} ${value}" PARENT_SCOPE)
endif()
endforeach(variable)
endfunction()
endif()
#
# Main configuration.
#
set(DMDFE_VERSION ${D_VERSION}.${DMDFE_MINOR_VERSION}.${DMDFE_PATCH_VERSION})
set(MULTILIB OFF CACHE BOOL "Build both 32/64 bit runtime libraries")
set(BUILD_LTO_LIBS OFF CACHE BOOL "Also build the runtime as LLVM bitcode libraries for LTO")
set(INCLUDE_INSTALL_DIR ${CMAKE_INSTALL_PREFIX}/include/d CACHE PATH "Path to install D modules to")
set(BUILD_SHARED_LIBS AUTO CACHE STRING "Whether to build the runtime as a shared library (ON|OFF|BOTH)")
set(D_FLAGS ${D_COMPILER_FLAGS} CACHE STRING "Runtime D compiler flags, separated by ';'")
set(D_FLAGS_DEBUG -g;-link-defaultlib-debug CACHE STRING "Runtime D compiler flags (debug libraries), separated by ';'")
set(D_FLAGS_RELEASE -O3;-release CACHE STRING "Runtime D compiler flags (release libraries), separated by ';'")
set(COMPILE_ALL_D_FILES_AT_ONCE ON CACHE BOOL "Compile all D files for a lib in a single command line instead of separately")
set(RT_ARCHIVE_WITH_LDC ON CACHE STRING "Whether to archive the static runtime libs via LDC instead of CMake archiver")
set(RT_CFLAGS "" CACHE STRING "Runtime extra C compiler flags, separated by ' '")
set(LD_FLAGS "" CACHE STRING "Runtime extra C linker flags, separated by ' '")
set(C_SYSTEM_LIBS AUTO CACHE STRING "C system libraries for linking shared libraries and test runners, separated by ';'")
set(TARGET_SYSTEM AUTO CACHE STRING "Target OS/toolchain for cross-compilation (e.g., 'Linux;UNIX', 'Darwin;APPLE;UNIX', 'Windows;MSVC')")
set(LDC_TARGET_PRESET "" CACHE STRING "Use a preset target configuration for cross-compilation, by passing format OS-arch (e.g., 'Linux-arm', 'Mac-x64', 'Windows-aarch64', 'Android-x86')")
set(CMAKE_INSTALL_LIBDIR ${CMAKE_INSTALL_PREFIX}/lib${LIB_SUFFIX})
# Find gnu make, use specific version first (BSD) and fall back to default 'make' (LINUX)
find_program(GNU_MAKE_BIN NAMES gmake gnumake make)
if ("${GNU_MAKE_BIN}" STREQUAL "")
message(FATAL_ERROR "GNU make could not be found. Please install gmake/gnumake/make using your (platform) package installer")
endif()
# Use LDC_TARGET_PRESET to configure target runtime
include(PresetRuntimeConfiguration)
# Auto-detect TARGET_SYSTEM from host
if("${TARGET_SYSTEM}" STREQUAL "AUTO")
set(TARGET_SYSTEM ${CMAKE_SYSTEM_NAME})
# Additionally add MSVC, APPLE and/or UNIX
if(MSVC)
list(APPEND TARGET_SYSTEM "MSVC")
endif()
if(APPLE)
list(APPEND TARGET_SYSTEM "APPLE")
endif()
if(UNIX)
list(APPEND TARGET_SYSTEM "UNIX")
endif()
endif()
if("${TARGET_SYSTEM}" MATCHES "UNIX")
ENABLE_LANGUAGE(ASM)
elseif("${TARGET_SYSTEM}" MATCHES "MSVC")
ENABLE_LANGUAGE(ASM_MASM)
endif()
include(CheckTypeSize)
check_type_size(void* ptr_size)
if(${ptr_size} MATCHES "^8$") ## if it's 64-bit OS
set(HOST_BITNESS 64)
set(MULTILIB_SUFFIX 32)
else()
set(HOST_BITNESS 32)
set(MULTILIB_SUFFIX 64)
endif()
set(SHARED_LIBS_SUPPORTED OFF)
if("${TARGET_SYSTEM}" MATCHES "Linux|FreeBSD|DragonFly|APPLE"
AND (NOT "${TARGET_SYSTEM}" MATCHES "Android"))
set(SHARED_LIBS_SUPPORTED ON)
endif()
if(${BUILD_SHARED_LIBS} STREQUAL "AUTO")
if(SHARED_LIBS_SUPPORTED)
set(BUILD_SHARED_LIBS BOTH)
else()
set(BUILD_SHARED_LIBS OFF)
endif()
endif()
set(SHARED_LIB_SUFFIX "")
if(NOT ${BUILD_SHARED_LIBS} STREQUAL "OFF")
if(NOT SHARED_LIBS_SUPPORTED)
message(FATAL_ERROR "Shared libraries (BUILD_SHARED_LIBS) are only supported on Linux, macOS, FreeBSD and DragonFly for the time being.")
endif()
set(SHARED_LIB_SUFFIX "-shared")
endif()
# Auto-detect C system libraries
if("${C_SYSTEM_LIBS}" STREQUAL "AUTO")
if("${TARGET_SYSTEM}" MATCHES "Android")
set(C_SYSTEM_LIBS m c)
elseif("${TARGET_SYSTEM}" MATCHES "Linux")
set(C_SYSTEM_LIBS m pthread rt dl z)
else()
set(C_SYSTEM_LIBS m pthread z)
endif()
endif()
get_directory_property(PROJECT_PARENT_DIR DIRECTORY ${PROJECT_SOURCE_DIR} PARENT_DIRECTORY)
set(RUNTIME_DIR ${PROJECT_SOURCE_DIR}/druntime CACHE PATH "druntime root directory")
set(PHOBOS2_DIR ${PROJECT_SOURCE_DIR}/phobos CACHE PATH "Phobos root directory")
set(JITRT_DIR ${PROJECT_SOURCE_DIR}/jit-rt CACHE PATH "jit runtime root directory")
#
# Gather source files.
#
# druntime D parts
file(GLOB_RECURSE DRUNTIME_D ${RUNTIME_DIR}/src/*.d)
list(REMOVE_ITEM DRUNTIME_D ${RUNTIME_DIR}/src/test_runner.d)
# remove unsupported etc/linux/memoryerror.d (see issue #1915)
list(REMOVE_ITEM DRUNTIME_D ${RUNTIME_DIR}/src/etc/linux/memoryerror.d)
# FIXME: Remove all modules in core/stdcpp/ due to alpha quality.
# See PR #1917; partly fixed upstream.
file(GLOB_RECURSE DRUNTIME_D_STDCPP ${RUNTIME_DIR}/src/core/stdcpp/*.d)
list(REMOVE_ITEM DRUNTIME_D ${DRUNTIME_D_STDCPP})
# remove some modules in rt/
list(REMOVE_ITEM DRUNTIME_D
${RUNTIME_DIR}/src/rt/alloca.d
${RUNTIME_DIR}/src/rt/llmath.d
)
# only include core/sys/ modules matching the platform
file(GLOB_RECURSE DRUNTIME_D_BIONIC ${RUNTIME_DIR}/src/core/sys/bionic/*.d)
file(GLOB_RECURSE DRUNTIME_D_DARWIN ${RUNTIME_DIR}/src/core/sys/darwin/*.d)
file(GLOB_RECURSE DRUNTIME_D_DRAGONFLYBSD ${RUNTIME_DIR}/src/core/sys/dragonflybsd/*.d)
file(GLOB_RECURSE DRUNTIME_D_FREEBSD ${RUNTIME_DIR}/src/core/sys/freebsd/*.d)
file(GLOB_RECURSE DRUNTIME_D_LINUX ${RUNTIME_DIR}/src/core/sys/linux/*.d)
file(GLOB_RECURSE DRUNTIME_D_NETBSD ${RUNTIME_DIR}/src/core/sys/netbsd/*.d)
file(GLOB_RECURSE DRUNTIME_D_OPENBSD ${RUNTIME_DIR}/src/core/sys/openbsd/*.d)
file(GLOB_RECURSE DRUNTIME_D_OSX ${RUNTIME_DIR}/src/core/sys/osx/*.d)
file(GLOB_RECURSE DRUNTIME_D_POSIX ${RUNTIME_DIR}/src/core/sys/posix/*.d)
file(GLOB_RECURSE DRUNTIME_D_SOLARIS ${RUNTIME_DIR}/src/core/sys/solaris/*.d)
file(GLOB_RECURSE DRUNTIME_D_WINDOWS ${RUNTIME_DIR}/src/core/sys/windows/*.d)
list(REMOVE_ITEM DRUNTIME_D
${DRUNTIME_D_BIONIC} ${DRUNTIME_D_DARWIN} ${DRUNTIME_D_DRAGONFLYBSD}
${DRUNTIME_D_FREEBSD} ${DRUNTIME_D_LINUX} ${DRUNTIME_D_NETBSD}
${DRUNTIME_D_OPENBSD} ${DRUNTIME_D_OSX} ${DRUNTIME_D_POSIX}
${DRUNTIME_D_SOLARIS} ${DRUNTIME_D_WINDOWS}
)
if("${TARGET_SYSTEM}" MATCHES "Windows")
list(APPEND DRUNTIME_D ${DRUNTIME_D_WINDOWS})
elseif("${TARGET_SYSTEM}" MATCHES "UNIX")
list(APPEND DRUNTIME_D ${DRUNTIME_D_POSIX})
if("${TARGET_SYSTEM}" MATCHES "APPLE")
list(APPEND DRUNTIME_D ${DRUNTIME_D_DARWIN})
list(APPEND DRUNTIME_D ${DRUNTIME_D_OSX})
elseif("${TARGET_SYSTEM}" MATCHES "DragonFly")
list(APPEND DRUNTIME_D ${DRUNTIME_D_DRAGONFLYBSD})
elseif("${TARGET_SYSTEM}" MATCHES "FreeBSD")
list(APPEND DRUNTIME_D ${DRUNTIME_D_FREEBSD})
elseif("${TARGET_SYSTEM}" MATCHES "Linux")
list(APPEND DRUNTIME_D ${DRUNTIME_D_LINUX})
list(APPEND DRUNTIME_D ${DRUNTIME_D_BIONIC})
elseif("${TARGET_SYSTEM}" MATCHES "NetBSD")
list(APPEND DRUNTIME_D ${DRUNTIME_D_NETBSD})
elseif("${TARGET_SYSTEM}" MATCHES "OpenBSD")
list(APPEND DRUNTIME_D ${DRUNTIME_D_OPENBSD})
elseif("${TARGET_SYSTEM}" MATCHES "SunOS")
list(APPEND DRUNTIME_D ${DRUNTIME_D_SOLARIS})
endif()
endif()
# druntime C parts
file(GLOB_RECURSE DRUNTIME_C ${RUNTIME_DIR}/src/*.c)
list(REMOVE_ITEM DRUNTIME_C ${RUNTIME_DIR}/src/rt/dylib_fixes.c)
if(NOT "${TARGET_SYSTEM}" MATCHES "APPLE")
list(REMOVE_ITEM DRUNTIME_C ${RUNTIME_DIR}/src/rt/osx_tls.c)
endif()
if(NOT "${TARGET_SYSTEM}" MATCHES "MSVC")
list(REMOVE_ITEM DRUNTIME_C ${RUNTIME_DIR}/src/rt/msvc.c ${RUNTIME_DIR}/src/rt/msvc_math.c)
endif()
# druntime ASM parts
set(DRUNTIME_ASM)
if("${TARGET_SYSTEM}" MATCHES "UNIX")
list(APPEND DRUNTIME_ASM ${RUNTIME_DIR}/src/core/threadasm.S ${RUNTIME_DIR}/src/ldc/eh_asm.S)
endif()
if(PHOBOS2_DIR)
# Phobos D parts
file(GLOB_RECURSE PHOBOS2_D ${PHOBOS2_DIR}/*.d)
# remove top-level modules index.d and unittest.d
list(REMOVE_ITEM PHOBOS2_D ${PHOBOS2_DIR}/index.d ${PHOBOS2_DIR}/unittest.d)
# remove D files in test/
file(GLOB_RECURSE PHOBOS2_D_TEST ${PHOBOS2_DIR}/test/*.d)
list(REMOVE_ITEM PHOBOS2_D ${PHOBOS2_D_TEST})
# only include std/windows/ modules on Windows
if(NOT "${TARGET_SYSTEM}" MATCHES "Windows")
file(GLOB_RECURSE PHOBOS2_D_WINDOWS ${PHOBOS2_DIR}/std/windows/*.d)
list(REMOVE_ITEM PHOBOS2_D ${PHOBOS2_D_WINDOWS})
endif()
# Phobos C parts
file(GLOB_RECURSE PHOBOS2_C ${PHOBOS2_DIR}/*.c)
# remove some obsolete zlib modules
list(REMOVE_ITEM PHOBOS2_C ${PHOBOS2_DIR}/etc/c/zlib/minigzip.c ${PHOBOS2_DIR}/etc/c/zlib/example.c)
# don't embed zlib
foreach(item ${PHOBOS2_C})
if(${item} MATCHES ".*/c/zlib/.*.c")
list(REMOVE_ITEM PHOBOS2_C ${item})
endif()
endforeach()
endif()
#
# Create configuration files.
#
# Add extra paths on Linux and disable linker arch mismatch warnings (like
# DMD and GDC do). OS X doesn't need extra configuration due to the use of
# fat binaries. Other Posixen might need to be added here.
if(MULTILIB AND NOT "${TARGET_SYSTEM}" MATCHES "APPLE")
set(ADDITIONAL_DEFAULT_LDC_SWITCHES "${ADDITIONAL_DEFAULT_LDC_SWITCHES}\n \"-L--no-warn-search-mismatch\",")
set(MULTILIB_ADDITIONAL_PATH "\n \"${CMAKE_BINARY_DIR}/lib${MULTILIB_SUFFIX}\",")
set(MULTILIB_ADDITIONAL_INSTALL_PATH "\n \"${CMAKE_INSTALL_PREFIX}/lib${MULTILIB_SUFFIX}\",")
endif()
# Default -rpath linker option when linking against shared libraries.
if(SHARED_LIBS_SUPPORTED)
if(MULTILIB AND NOT "${TARGET_SYSTEM}" MATCHES "APPLE")
set(SHARED_LIBS_RPATH "${CMAKE_BINARY_DIR}/lib${LIB_SUFFIX}:${CMAKE_BINARY_DIR}/lib${MULTILIB_SUFFIX}")
set(SHARED_LIBS_INSTALL_RPATH "${CMAKE_INSTALL_LIBDIR}:${CMAKE_INSTALL_PREFIX}/lib${MULTILIB_SUFFIX}")
else()
set(SHARED_LIBS_RPATH "${CMAKE_BINARY_DIR}/lib${LIB_SUFFIX}")
set(SHARED_LIBS_INSTALL_RPATH "${CMAKE_INSTALL_LIBDIR}")
endif()
endif()
# Only have either shared or static libs?
# Then explicitly default to linking against them via default LDC switch.
if(${BUILD_SHARED_LIBS} STREQUAL "ON")
set(ADDITIONAL_DEFAULT_LDC_SWITCHES "${ADDITIONAL_DEFAULT_LDC_SWITCHES}\n \"-link-defaultlib-shared\",")
elseif(${BUILD_SHARED_LIBS} STREQUAL "OFF")
set(ADDITIONAL_DEFAULT_LDC_SWITCHES "${ADDITIONAL_DEFAULT_LDC_SWITCHES}\n \"-link-defaultlib-shared=false\",")
endif()
if(LDC_WITH_LLD)
set(WASM_DEFAULT_LDC_SWITCHES "\n \"-link-internally\",")
endif()
# Only generate the config files if this CMake project is embedded in the LDC CMake project.
if(LDC_EXE)
if(PHOBOS2_DIR)
set(CONFIG_NAME ${LDC_EXE}_phobos)
else()
set(CONFIG_NAME ${LDC_EXE})
endif()
configure_file(${PROJECT_PARENT_DIR}/${CONFIG_NAME}.conf.in ${PROJECT_BINARY_DIR}/../bin/${LDC_EXE}.conf @ONLY)
configure_file(${PROJECT_PARENT_DIR}/${LDC_EXE}_install.conf.in ${PROJECT_BINARY_DIR}/../bin/${LDC_EXE}_install.conf @ONLY)
endif()
#
# druntime/Phobos compilation helpers.
#
set(GCCBUILTINS "")
function(gen_gccbuiltins name)
set(module "${PROJECT_BINARY_DIR}/gccbuiltins_${name}.di")
if (GCCBUILTINS STREQUAL "")
set(GCCBUILTINS "${module}" PARENT_SCOPE)
else()
set(GCCBUILTINS "${GCCBUILTINS};${module}" PARENT_SCOPE)
endif()
add_custom_command(
OUTPUT ${module}
COMMAND gen_gccbuiltins ${module} "${name}"
)
endfunction()
set(target_arch "AArch64;ARM;Mips;PowerPC;SystemZ;X86")
set(target_name "aarch64;arm;mips;ppc;s390;x86")
foreach(target ${LLVM_TARGETS_TO_BUILD})
list(FIND target_arch ${target} idx)
if(idx GREATER -1)
list(GET target_name ${idx} name)
gen_gccbuiltins(${name})
endif()
endforeach()
# Always build zlib and other C parts of the runtime in release mode, regardless
# of what the user chose for LDC itself. Also add other C_FLAGS here.
# 1) Set up CMAKE_C_FLAGS_RELEASE
if("${TARGET_SYSTEM}" MATCHES "MSVC")
# Omit all references to the default C runtime libs.
# We want to be able to link against all 4 C runtime variants (libcmt[d] / msvcrt[d]).
string(REGEX REPLACE "(^| )[/-]M[TD]d?( |$)" "\\2" CMAKE_C_FLAGS_RELEASE "${CMAKE_C_FLAGS_RELEASE}")
append("/MT /Zl" CMAKE_C_FLAGS_RELEASE)
# warning C4100: unreferenced formal parameter
# warning C4127: conditional expression is constant
# warning C4131: uses old-style declarator
# warning C4206: nonstandard extension used: translation unit is empty
# warnings C42{44,67}: conversion from '...' to '...', possible loss of data
# warning C4245: conversion from '...' to '...', signed/unsigned mismatch
# warning C4996: zlib uses 'deprecated' POSIX names
append("/wd4100 /wd4127 /wd4131 /wd4206 /wd4244 /wd4245 /wd4267 /wd4996" CMAKE_C_FLAGS_RELEASE)
endif()
CHECK_INCLUDE_FILE(unistd.h HAVE_UNISTD_H)
if (HAVE_UNISTD_H)
# Needed for zlib
append("-DHAVE_UNISTD_H" CMAKE_C_FLAGS)
endif()
# 2) Set all other CMAKE_C_FLAGS variants to CMAKE_C_FLAGS_RELEASE
set(variables
CMAKE_C_FLAGS_DEBUG
CMAKE_C_FLAGS_MINSIZEREL
CMAKE_C_FLAGS_RELWITHDEBINFO
)
foreach(variable ${variables})
set(${variable} "${CMAKE_C_FLAGS_RELEASE}")
endforeach()
# Compiles the given D modules to object files, and if enabled, bitcode files.
# The paths of the output files are appended to outlist_o and outlist_bc, respectively.
macro(dc src_files src_basedir d_flags output_basedir emit_bc all_at_once outlist_o outlist_bc)
set(dc_flags -c --output-o ${d_flags})
if(${emit_bc})
list(APPEND dc_flags -flto=thin --output-bc)
endif()
set(dc_deps ${LDC_EXE}
${LDC_EXE_FULL}
${GCCBUILTINS}
)
set(relative_src_files "")
foreach(f ${src_files})
file(RELATIVE_PATH relative_src_file ${src_basedir} ${f})
get_filename_component(name ${relative_src_file} NAME_WE)
get_filename_component(path ${relative_src_file} PATH)
if("${path}" STREQUAL "")
set(output_root ${name})
else()
set(output_root ${path}/${name})
endif()
set(output_o ${output_basedir}/${output_root}${CMAKE_C_OUTPUT_EXTENSION})
set(output_bc ${output_basedir}/${output_root}.bc${CMAKE_C_OUTPUT_EXTENSION})
list(APPEND ${outlist_o} ${output_o})
if(${emit_bc})
list(APPEND ${outlist_bc} ${output_bc})
endif()
if(${all_at_once})
list(APPEND relative_src_files ${relative_src_file})
else()
set(outfiles ${output_o})
set(renameCommand "")
if(${emit_bc})
set(renameCommand mv ${output_basedir}/${output_root}.bc ${output_bc})
list(APPEND outfiles ${output_bc})
endif()
add_custom_command(
OUTPUT ${outfiles}
COMMAND ${LDC_EXE_FULL} ${dc_flags} -of=${output_o} ${relative_src_file}
COMMAND ${renameCommand}
WORKING_DIRECTORY ${src_basedir}
DEPENDS ${f} ${dc_deps}
)
endif()
endforeach()
if(${all_at_once})
set(renameCommand "")
if(${emit_bc})
if(WIN32)
set(renameCommand find ${output_basedir} -iname '*.bc' -exec mv '{}' '{}${CMAKE_C_OUTPUT_EXTENSION}' "\;")
else()
set(renameCommand find ${output_basedir} -iname '*.bc' -exec mv '{}' '{}${CMAKE_C_OUTPUT_EXTENSION}' "\\\\;")
endif()
endif()
add_custom_command(
OUTPUT ${${outlist_o}} ${${outlist_bc}}
COMMAND ${LDC_EXE_FULL} ${dc_flags} -od=${output_basedir} -op ${relative_src_files}
COMMAND ${renameCommand}
WORKING_DIRECTORY ${src_basedir}
DEPENDS ${src_files} ${dc_deps}
)
endif()
endmacro()
# Sets target_suffix to a purely cosmetical suffix for the CMake target names
# from the given suffixes on the library name and the target path. We could use
# any string that resolves the ambiguities between the different variants.
macro(get_target_suffix lib_suffix path_suffix target_suffix)
set(${target_suffix} "")
if(NOT "${lib_suffix}" STREQUAL "")
set(${target_suffix} "${lib_suffix}")
endif()
# If LIB_SUFFIX is set there is always a suffix; leave it off for simplicity.
if(NOT "${path_suffix}" STREQUAL "" AND NOT "${path_suffix}" STREQUAL "${LIB_SUFFIX}")
set(${target_suffix} "${${target_suffix}}_${path_suffix}")
endif()
endmacro()
# Sets up the target(s) for building the druntime D object files, appending the
# names of the (bitcode) files to link into the library to outlist_o (outlist_bc).
macro(compile_druntime d_flags lib_suffix path_suffix emit_bc all_at_once outlist_o outlist_bc)
get_target_suffix("${lib_suffix}" "${path_suffix}" target_suffix)
dc("${DRUNTIME_D}"
"${RUNTIME_DIR}/src"
"-conf=;${d_flags};-I${RUNTIME_DIR}/src"
"${PROJECT_BINARY_DIR}/objects${target_suffix}"
"${emit_bc}"
"${all_at_once}"
${outlist_o}
${outlist_bc}
)
endmacro()
# Sets up the targets for building the Phobos D object files, appending the
# names of the (bitcode) files to link into the library to outlist_o (outlist_bc).
macro(compile_phobos2 d_flags lib_suffix path_suffix emit_bc all_at_once outlist_o outlist_bc)
get_target_suffix("${lib_suffix}" "${path_suffix}" target_suffix)
dc("${PHOBOS2_D}"
"${PHOBOS2_DIR}"
"-conf=;${d_flags};-I${RUNTIME_DIR}/src;-I${PHOBOS2_DIR}"
"${PROJECT_BINARY_DIR}/objects${target_suffix}"
"${emit_bc}"
"${all_at_once}"
${outlist_o}
${outlist_bc}
)
endmacro()
# Define an optional 'D' CMake linker language for the static runtime libs,
# using LDC as archiver. LDC handles (cross-)archiving internally via LLVM
# and supports LTO objects.
set(CMAKE_D_CREATE_STATIC_LIBRARY "${LDC_EXE_FULL} -lib -of=<TARGET> <OBJECTS>")
foreach(f ${D_FLAGS})
append("\"${f}\"" CMAKE_D_CREATE_STATIC_LIBRARY)
endforeach()
# Sets the common properties for all library targets.
function(set_common_library_properties target name output_dir c_flags ld_flags is_shared)
set_target_properties(${target} PROPERTIES
OUTPUT_NAME ${name}
ARCHIVE_OUTPUT_DIRECTORY ${output_dir}
LIBRARY_OUTPUT_DIRECTORY ${output_dir}
RUNTIME_OUTPUT_DIRECTORY ${output_dir}
COMPILE_FLAGS "${c_flags}"
LINK_FLAGS "${ld_flags}"
VERSION ${DMDFE_VERSION}
SOVERSION ${DMDFE_PATCH_VERSION}
LINKER_LANGUAGE C
MACOSX_RPATH ON
)
if(RT_ARCHIVE_WITH_LDC AND NOT is_shared)
set_target_properties(${target} PROPERTIES LINKER_LANGUAGE D)
endif()
# ldc2 defaults to position-independent code on Linux to match the implicit
# linker default on Ubuntu 16.10 and above. As we might be building on an
# older system (e.g. binary packages), we need to make sure the C parts are
# built as PIC as well.
if("${TARGET_SYSTEM}" MATCHES "Linux")
set_target_properties(${target} PROPERTIES
POSITION_INDEPENDENT_CODE ON)
endif()
endfunction()
# Builds a copy of druntime/Phobos from the specified object (bitcode) files.
# The names of the added library targets are appended to outlist_targets.
macro(build_runtime_libs druntime_o druntime_bc phobos2_o phobos2_bc c_flags ld_flags
lib_suffix path_suffix is_shared emit_bc outlist_targets)
set(output_path ${CMAKE_BINARY_DIR}/lib${path_suffix})
set(library_type STATIC)
if("${is_shared}" STREQUAL "ON")
set(library_type SHARED)
endif()
get_target_suffix("${lib_suffix}" "${path_suffix}" target_suffix)
add_library(druntime-ldc${target_suffix} ${library_type}
${druntime_o} ${DRUNTIME_C} ${DRUNTIME_ASM})
set_common_library_properties(druntime-ldc${target_suffix}
druntime-ldc${lib_suffix} ${output_path}
"${c_flags}" "${ld_flags}" ${is_shared}
)
# When building a shared library, we need to link in all the default
# libraries otherwise implicitly added by LDC to make it loadable from
# C executables.
if("${is_shared}" STREQUAL "ON")
target_link_libraries(druntime-ldc${target_suffix} ${C_SYSTEM_LIBS})
endif()
list(APPEND ${outlist_targets} druntime-ldc${target_suffix})
if(PHOBOS2_DIR)
add_library(phobos2-ldc${target_suffix} ${library_type}
${phobos2_o} ${PHOBOS2_C})
set_common_library_properties(phobos2-ldc${target_suffix}
phobos2-ldc${lib_suffix} ${output_path}
"${c_flags}" "${ld_flags}" ${is_shared}
)
if("${is_shared}" STREQUAL "ON")
# Make sure to link shared unittest-Phobos against shared NON-unittest-druntime
# in order to exclude the druntime tests for the Phobos test runner.
string(REPLACE "-unittest" "" target_suffix_without_unittest "${target_suffix}")
target_link_libraries(phobos2-ldc${target_suffix}
druntime-ldc${target_suffix_without_unittest} ${C_SYSTEM_LIBS})
endif()
list(APPEND ${outlist_targets} phobos2-ldc${target_suffix})
endif()
if("${emit_bc}")
add_library(druntime-ldc-lto${target_suffix} STATIC
${druntime_bc} ${DRUNTIME_C} ${DRUNTIME_ASM})
set_common_library_properties(druntime-ldc-lto${target_suffix}
druntime-ldc-lto${lib_suffix} ${output_path}
"${c_flags}" "${ld_flags}" OFF
)
add_library(phobos2-ldc-lto${target_suffix} STATIC
${phobos2_bc} ${PHOBOS2_C})
set_common_library_properties(phobos2-ldc-lto${target_suffix}
phobos2-ldc-lto${lib_suffix} ${output_path}
"${c_flags}" "${ld_flags}" OFF
)
endif()
endmacro()
# Builds a static and/or shared copy of druntime/Phobos.
macro(build_runtime_variant d_flags c_flags ld_flags lib_suffix path_suffix all_d_files_at_once outlist_targets)
set(emit_bc OFF)
if(BUILD_LTO_LIBS AND NOT "${lib_suffix}" MATCHES "-unittest")
set(emit_bc ON)
endif()
# Only compile Phobos modules once for static+shared libs.
# If a shared Phobos lib is generated (too), compile explicitly with `-relocation-model=pic`.
set(phobos2_d_flags "${d_flags}")
if(NOT ${BUILD_SHARED_LIBS} STREQUAL "OFF")
list(APPEND ${phobos2_d_flags} -relocation-model=pic)
endif()
set(phobos2_o "")
set(phobos2_bc "")
compile_phobos2("${phobos2_d_flags}" "${lib_suffix}" "${path_suffix}" "${emit_bc}" "${all_d_files_at_once}" phobos2_o phobos2_bc)
# Use a dummy custom target ('phobos2-ldc…-common') depending solely on the Phobos D objects
# (custom commands) as dependency for static+shared Phobos libs.
# Otherwise building both libs in parallel may result in conflicting Phobos module compilations
# (at least with the make generator), a known CMake issue.
set(phobos2_common phobos2-ldc${target_suffix}-common)
add_custom_target(${phobos2_common} DEPENDS ${phobos2_o} ${phobos2_bc})
# static druntime/Phobos
if(NOT ${BUILD_SHARED_LIBS} STREQUAL "ON")
set(druntime_o "")
set(druntime_bc "")
compile_druntime("${d_flags}" "${lib_suffix}"
"${path_suffix}" "${emit_bc}" "${all_d_files_at_once}" druntime_o druntime_bc)
build_runtime_libs("${druntime_o}" "${druntime_bc}" "${phobos2_o}" "${phobos2_bc}"
"${c_flags}" "${ld_flags}" "${lib_suffix}" "${path_suffix}"
"OFF" "${emit_bc}" ${outlist_targets})
add_dependencies(phobos2-ldc${target_suffix} ${phobos2_common})
endif()
# shared druntime/Phobos
if(NOT ${BUILD_SHARED_LIBS} STREQUAL "OFF")
set(druntime_o "")
set(druntime_bc "")
compile_druntime("${d_flags};-relocation-model=pic;-d-version=Shared" "${lib_suffix}${SHARED_LIB_SUFFIX}"
"${path_suffix}" "OFF" "${all_d_files_at_once}" druntime_o druntime_bc)
build_runtime_libs("${druntime_o}" "${druntime_bc}" "${phobos2_o}" "${phobos2_bc}"
"${c_flags}" "${ld_flags}" "${lib_suffix}${SHARED_LIB_SUFFIX}" "${path_suffix}"
"ON" "OFF" ${outlist_targets})
add_dependencies(phobos2-ldc${target_suffix} ${phobos2_common})
endif()
endmacro()
# Builds static and/or shared pairs of debug+release copies of druntime/Phobos.
macro(build_runtime_variants d_flags c_flags ld_flags path_suffix outlist_targets)
# static and/or shared release druntime/Phobos
build_runtime_variant(
"${d_flags};${D_FLAGS};${D_FLAGS_RELEASE}"
"${c_flags}"
"${ld_flags}"
""
"${path_suffix}"
"${COMPILE_ALL_D_FILES_AT_ONCE}"
${outlist_targets}
)
# static and/or shared debug druntime/Phobos
build_runtime_variant(
"${d_flags};${D_FLAGS};${D_FLAGS_DEBUG}"
"${c_flags}"
"${ld_flags}"
"-debug"
"${path_suffix}"
"${COMPILE_ALL_D_FILES_AT_ONCE}"
${outlist_targets}
)
endmacro()
# Setup the build of jit runtime
include(jit-rt/DefineBuildJitRT.cmake)
#
# Set up build and install targets
#
if(MULTILIB AND "${TARGET_SYSTEM}" MATCHES "APPLE")
# On OS X, build "fat" libraries containing code for both architectures.
# Some suffix for the target/file names of the host-native arch so
# that they don't collide with the final combined ones.
set(hostsuffix "${LIB_SUFFIX}${HOST_BITNESS}")
set(libtargets)
build_runtime_variants("" "${RT_CFLAGS}" "${LD_FLAGS}" "${hostsuffix}" libtargets)
build_runtime_variants("-m${MULTILIB_SUFFIX}" "-m${MULTILIB_SUFFIX} ${RT_CFLAGS}" "-m${MULTILIB_SUFFIX} ${LD_FLAGS}" "${MULTILIB_SUFFIX}" libtargets)
# Only build the host version of the jit runtime due to LLVM dependency.
set(libtargets_jit)
build_jit_runtime("${D_FLAGS};${D_FLAGS_RELEASE}" "${RT_CFLAGS}" "${LD_FLAGS}" "${LIB_SUFFIX}" libtargets_jit)
# Install separately; also manually copy libldc-jit-rt.a to prevent ranlib from
# potentially corrupting the file during installation.
if(LDC_DYNAMIC_COMPILE)
install(FILES $<TARGET_FILE:ldc-jit-rt>
DESTINATION ${CMAKE_INSTALL_PREFIX}/lib${LIB_SUFFIX})
list(REMOVE_ITEM libtargets_jit ldc-jit-rt)
endif()
install(TARGETS ${libtargets_jit}
DESTINATION ${CMAKE_INSTALL_PREFIX}/lib${LIB_SUFFIX})
# KLUDGE: Cannot use `$<TARGET_LINKER_FILE:target>` in custom command.
# Set up the list of generated libs (without 'lib' prefix) to be merged manually.
set(libs_to_merge)
if(NOT ${BUILD_SHARED_LIBS} STREQUAL "ON")
list(APPEND libs_to_merge druntime-ldc.a druntime-ldc-debug.a
phobos2-ldc.a phobos2-ldc-debug.a
)
# Only install the release versions of the (static-only) bitcode libraries.
if(BUILD_LTO_LIBS)
list(APPEND libs_to_merge druntime-ldc-lto.a phobos2-ldc-lto.a)
endif()
endif()
if(NOT ${BUILD_SHARED_LIBS} STREQUAL "OFF")
set(suffix ${SHARED_LIB_SUFFIX}.dylib)
list(APPEND libs_to_merge druntime-ldc${suffix} druntime-ldc-debug${suffix}
phobos2-ldc${suffix} phobos2-ldc-debug${suffix}
)
endif()
foreach(lib ${libs_to_merge})
set(target_name "")
set(lib_extension "")
get_filename_component(target_name ${lib} NAME_WE)
get_filename_component(lib_extension ${lib} EXT)
set(host_path ${CMAKE_BINARY_DIR}/lib${hostsuffix}/lib${lib})
set(multi_path ${CMAKE_BINARY_DIR}/lib${MULTILIB_SUFFIX}/lib${lib})
# Create (& later install) symbolic links for merged dylibs.
set(final_files_to_install)
if(${lib_extension} STREQUAL ".dylib")
set(final_path ${CMAKE_BINARY_DIR}/lib${LIB_SUFFIX}/lib${target_name}.${DMDFE_VERSION}.dylib)
set(dylib_symlink1 ${CMAKE_BINARY_DIR}/lib${LIB_SUFFIX}/lib${target_name}.${DMDFE_PATCH_VERSION}.dylib)
set(dylib_symlink2 ${CMAKE_BINARY_DIR}/lib${LIB_SUFFIX}/lib${target_name}.dylib)
set(final_files_to_install ${final_path} ${dylib_symlink1} ${dylib_symlink2})
add_custom_command(
OUTPUT ${final_files_to_install}
COMMAND ${CMAKE_COMMAND} -E make_directory ${CMAKE_BINARY_DIR}/lib${LIB_SUFFIX}
COMMAND lipo ${multi_path} ${host_path} -create -output ${final_path}
COMMAND ln -s lib${target_name}.${DMDFE_VERSION}.dylib ${dylib_symlink1}
COMMAND ln -s lib${target_name}.${DMDFE_PATCH_VERSION}.dylib ${dylib_symlink2}
DEPENDS ${libtargets}
)
else()
set(final_path ${CMAKE_BINARY_DIR}/lib${LIB_SUFFIX}/lib${lib})
set(final_files_to_install ${final_path})
add_custom_command(
OUTPUT ${final_path}
COMMAND ${CMAKE_COMMAND} -E make_directory ${CMAKE_BINARY_DIR}/lib${LIB_SUFFIX}
COMMAND lipo ${multi_path} ${host_path} -create -output ${final_path}
DEPENDS ${libtargets}
)
endif()
add_custom_target(${target_name} ALL DEPENDS ${final_files_to_install})
install(FILES ${final_files_to_install}
DESTINATION ${CMAKE_INSTALL_PREFIX}/lib${LIB_SUFFIX})
endforeach()
else()
set(libs_to_install)
# build host versions
build_runtime_variants("" "${RT_CFLAGS}" "${LD_FLAGS}" "${LIB_SUFFIX}" libs_to_install)
if(MULTILIB)
# build multi versions
build_runtime_variants("-m${MULTILIB_SUFFIX}" "-m${MULTILIB_SUFFIX} ${RT_CFLAGS}" "-m${MULTILIB_SUFFIX} ${LD_FLAGS}" "${MULTILIB_SUFFIX}" libs_to_install)
endif()
# Only build the host version of the jit runtime due to LLVM dependency.
build_jit_runtime("${D_FLAGS};${D_FLAGS_RELEASE}" "${RT_CFLAGS}" "${LD_FLAGS}" "${LIB_SUFFIX}" libs_to_install)
# Only install the release versions of the (static-only) bitcode libraries.
if(BUILD_LTO_LIBS AND (NOT ${BUILD_SHARED_LIBS} STREQUAL "ON"))
list(APPEND libs_to_install druntime-ldc-lto phobos2-ldc-lto)
endif()
foreach(libname ${libs_to_install})
# On Mac, manually copy static libraries to prevent ranlib from
# potentially corrupting the file during installation.
# See https://bugs.llvm.org/show_bug.cgi?id=34808.
set(copy_manually OFF)
if("${TARGET_SYSTEM}" MATCHES "APPLE")
set(target_type)
get_target_property(target_type ${libname} TYPE)
if("${target_type}" STREQUAL "STATIC_LIBRARY")
set(copy_manually ON)
endif()
endif()
set(destination_dir ${CMAKE_INSTALL_PREFIX}/lib${LIB_SUFFIX})
if(${libname} MATCHES "_${MULTILIB_SUFFIX}$")
set(destination_dir ${CMAKE_INSTALL_PREFIX}/lib${MULTILIB_SUFFIX})
endif()
if(copy_manually)
install(FILES $<TARGET_FILE:${libname}>
DESTINATION ${destination_dir})
else()
install(TARGETS ${libname}
DESTINATION ${destination_dir})
endif()
endforeach()
endif()
set(DRUNTIME_PACKAGES core etc ldc)
install(FILES ${RUNTIME_DIR}/src/object.d DESTINATION ${INCLUDE_INSTALL_DIR}/ldc)
foreach(p ${DRUNTIME_PACKAGES})
install(DIRECTORY ${RUNTIME_DIR}/src/${p} DESTINATION ${INCLUDE_INSTALL_DIR})
endforeach()
if(PHOBOS2_DIR)
install(DIRECTORY ${PHOBOS2_DIR}/std DESTINATION ${INCLUDE_INSTALL_DIR} FILES_MATCHING PATTERN "*.d")
install(DIRECTORY ${PHOBOS2_DIR}/etc DESTINATION ${INCLUDE_INSTALL_DIR} FILES_MATCHING PATTERN "*.d")
endif()
install(FILES ${GCCBUILTINS} DESTINATION ${INCLUDE_INSTALL_DIR}/ldc)
#
# Test targets.
#
# Build the "test runner" executables containing the druntime and Phobos unit
# tests. They are invoked with the modules to test later.
# We just build another copy of the two libraries with -unittest enabled and
# link the test runners against those. Some linker command-line magic is
# required to make sure all objects are pulled in.
macro(append_testrunner_linkflags libname path_suffix is_shared output_flags)
# (Re)set variable 'tested_lib_path', initialize to directory containing the tested lib.
# It'll contain the full path to the linked-in library when 'returning' to calling build_test_runners().
set(tested_lib_path "${CMAKE_BINARY_DIR}/lib${path_suffix}")
if("${TARGET_SYSTEM}" MATCHES "MSVC")
set(tested_lib_path "${tested_lib_path}/${libname}.lib")
if("${is_shared}" STREQUAL "ON")
append("${tested_lib_path}" ${output_flags})
append("msvcrt.lib vcruntime.lib" ${output_flags})
else()
# the MS linker supports /WHOLEARCHIVE since VS 2015 Update 2
string(REPLACE "/" "\\" tested_lib_winpath ${tested_lib_path})
append("/WHOLEARCHIVE:${tested_lib_winpath}" ${output_flags})
append("libcmt.lib libvcruntime.lib" ${output_flags})
endif()
else()
if("${is_shared}" STREQUAL "ON")
append("-Wl,-rpath,${tested_lib_path}" ${output_flags})
if("${TARGET_SYSTEM}" MATCHES "APPLE")
set(tested_lib_path "${tested_lib_path}/lib${libname}.dylib")
append("${tested_lib_path}" ${output_flags})
else()
set(tested_lib_path "${tested_lib_path}/lib${libname}.so")
append("-Wl,--no-as-needed,${tested_lib_path},--as-needed" ${output_flags})
endif()
else()
set(tested_lib_path "${tested_lib_path}/lib${libname}.a")
if("${TARGET_SYSTEM}" MATCHES "APPLE")
append("-Wl,-force_load,${tested_lib_path}" ${output_flags})
else()
append("-Wl,--whole-archive,${tested_lib_path},--no-whole-archive" ${output_flags})
endif()
foreach(l ${C_SYSTEM_LIBS})
append("-l${l}" ${output_flags})
endforeach()
endif()
endif()
endmacro()
set(_GLOBAL_TESTRUNNERS "" CACHE INTERNAL "List of all test runner build targets")
file(WRITE ${PROJECT_BINARY_DIR}/dummy.c "")
# Generates targets for a pair of druntime/Phobos test runners.
# The build targets are also appended to the _GLOBAL_TESTRUNNERS list.
function(build_test_runners name_suffix path_suffix d_flags c_flags linkflags is_shared)
set(target_suffix)
get_target_suffix("${name_suffix}" "${path_suffix}" target_suffix)
set(test_runner_o "")
set(test_runner_bc "")
dc("${RUNTIME_DIR}/src/test_runner.d"
"${RUNTIME_DIR}/src"
"${d_flags}"
"${PROJECT_BINARY_DIR}/objects-unittest${target_suffix}"
"OFF"
"OFF"
test_runner_o
test_runner_bc
)
add_custom_target(test_runner${target_suffix} DEPENDS ${test_runner_o})
set(druntime_name druntime-test-runner${target_suffix})
add_executable(${druntime_name} EXCLUDE_FROM_ALL ${PROJECT_BINARY_DIR}/dummy.c)
set(full_linkflags "${test_runner_o} ${linkflags}")
append_testrunner_linkflags("druntime-ldc-unittest${name_suffix}" "${path_suffix}" "${is_shared}" full_linkflags)
add_dependencies(${druntime_name} test_runner${target_suffix} druntime-ldc-unittest${target_suffix})
set_target_properties(${druntime_name} PROPERTIES
COMPILE_FLAGS ${c_flags}
LINK_FLAGS ${full_linkflags}
LINK_DEPENDS "${test_runner_o};${tested_lib_path}"
)
add_test(build-${druntime_name} "${CMAKE_COMMAND}" --build ${CMAKE_BINARY_DIR} --target ${druntime_name})
set(_GLOBAL_TESTRUNNERS "${_GLOBAL_TESTRUNNERS};${druntime_name}" CACHE INTERNAL "")
if(PHOBOS2_DIR)
set(phobos_name phobos2-test-runner${target_suffix})
add_executable(${phobos_name} EXCLUDE_FROM_ALL ${PROJECT_BINARY_DIR}/dummy.c)
target_link_libraries(${phobos_name} druntime-ldc${target_suffix})
set(full_linkflags "${test_runner_o} ${linkflags}")
append_testrunner_linkflags("phobos2-ldc-unittest${name_suffix}" "${path_suffix}" "${is_shared}" full_linkflags)
add_dependencies(${phobos_name} test_runner${target_suffix} phobos2-ldc-unittest${target_suffix})
set_target_properties(${phobos_name} PROPERTIES
COMPILE_FLAGS ${c_flags}
LINK_FLAGS ${full_linkflags}
LINK_DEPENDS "${test_runner_o};${tested_lib_path}"
)
add_test(build-${phobos_name} "${CMAKE_COMMAND}" --build ${CMAKE_BINARY_DIR} --target ${phobos_name})
set(_GLOBAL_TESTRUNNERS "${_GLOBAL_TESTRUNNERS};${phobos_name}" CACHE INTERNAL "")
endif()
endfunction()
# Generates targets for static and/or shared pairs of druntime/Phobos test runners.
function(build_test_runner_variant name_suffix path_suffix d_flags c_flags)
set(full_d_flags ${D_FLAGS} ${d_flags} -unittest -d-version=StdUnittest)
set(full_c_flags "${RT_CFLAGS} ${c_flags}")
set(linkflags "${LD_FLAGS} ${c_flags}")
if("${TARGET_SYSTEM}" MATCHES "MSVC")
# enforce identical COMDAT folding, apparently needed for std.variant
set(linkflags "/OPT:ICF ${linkflags}")
endif()
# static and/or shared pair(s) of druntime/Phobos unittest libs
set(unittest_libs "")
build_runtime_variant(
"${full_d_flags}"
"${full_c_flags}"
"${linkflags}"
"-unittest${name_suffix}"
"${path_suffix}"
"OFF" # compile separately
unittest_libs
)
# Only build the unittest libraries when running the tests.
set_target_properties(${unittest_libs} PROPERTIES EXCLUDE_FROM_ALL ON EXCLUDE_FROM_DEFAULT_BUILD ON)
# static druntime/Phobos test runners
if(NOT ${BUILD_SHARED_LIBS} STREQUAL "ON")
build_test_runners("${name_suffix}" "${path_suffix}" "${full_d_flags}" "${full_c_flags}" "${linkflags}" "OFF")
endif()
# shared druntime/Phobos test runners
if(NOT ${BUILD_SHARED_LIBS} STREQUAL "OFF")
build_test_runners("${name_suffix}${SHARED_LIB_SUFFIX}" "${path_suffix}" "${full_d_flags}" "${full_c_flags}" "${linkflags}" "ON")
endif()
endfunction()
# Generates targets for static and/or shared debug+release druntime/Phobos test runners.
function(build_test_runner_variants path_suffix d_flags c_flags)
build_test_runner_variant("" "${path_suffix}" "${D_FLAGS_RELEASE};${d_flags}" "${c_flags}")
build_test_runner_variant("-debug" "${path_suffix}" "${D_FLAGS_DEBUG};${d_flags}" "${c_flags}")
endfunction()
set(TESTLIB_SUFFIX "${LIB_SUFFIX}")
if(MULTILIB AND "${TARGET_SYSTEM}" MATCHES "APPLE")
# match `hostsuffix` used for building the normal libs
set(TESTLIB_SUFFIX "${LIB_SUFFIX}${HOST_BITNESS}")
endif()
# Now generate all test runner targets.
build_test_runner_variants("${TESTLIB_SUFFIX}" "" "")
if(MULTILIB AND ${HOST_BITNESS} EQUAL 64)
build_test_runner_variants("${MULTILIB_SUFFIX}" "-m32" "-m32")
endif()
# Let's add a meta build target for all test runners.
add_custom_target(all-test-runners DEPENDS ${_GLOBAL_TESTRUNNERS})
# Add the druntime/Phobos test runner invocations for all the different modules.
macro(file_to_module_name file_name out_module_name)
string(REPLACE ${PROJECT_SOURCE_DIR}/ "" stripped ${file_name})
string(REPLACE "druntime/src/" "" stripped ${stripped})
string(REPLACE "phobos/" "" stripped ${stripped})
string(REPLACE ".d" "" stripped ${stripped})
string(REPLACE "/" "." module ${stripped})
# The logical module name for package.d files doesn't include the
# trailing .package part.
string(REPLACE ".package" "" module ${module})
# rt.invariant doesn't have a module declaration, presumably because
# invariant is a keyword.
string(REPLACE "rt.invariant" "invariant" ${out_module_name} ${module})
endmacro()
function(add_tests d_files runner target_suffix)
foreach(file ${d_files})
file_to_module_name(${file} module)
add_test(NAME "${module}${target_suffix}"
WORKING_DIRECTORY "${PROJECT_BINARY_DIR}"
COMMAND ${runner}-test-runner${target_suffix} ${module}
)
set_tests_properties("${module}${target_suffix}" PROPERTIES
DEPENDS build-${runner}-test-runner${target_suffix}
)
endforeach()
endfunction()
function(add_runtime_tests name_suffix path_suffix)
get_target_suffix("${name_suffix}" "${path_suffix}" target_suffix)
add_tests("${DRUNTIME_D}" "druntime" "${target_suffix}")
if(PHOBOS2_DIR)
add_tests("${PHOBOS2_D}" "phobos2" "${target_suffix}")
endif()
endfunction()
function(add_runtime_tests_variants path_suffix)
if(NOT ${BUILD_SHARED_LIBS} STREQUAL "ON")
add_runtime_tests("" "${path_suffix}")
add_runtime_tests("-debug" "${path_suffix}")
endif()
if(NOT ${BUILD_SHARED_LIBS} STREQUAL "OFF")
add_runtime_tests("${SHARED_LIB_SUFFIX}" "${path_suffix}")
add_runtime_tests("-debug${SHARED_LIB_SUFFIX}" "${path_suffix}")
endif()
endfunction()
add_runtime_tests_variants("${TESTLIB_SUFFIX}")
if(MULTILIB AND ${HOST_BITNESS} EQUAL 64)
add_runtime_tests_variants("${MULTILIB_SUFFIX}")
endif()
# Add the standalone druntime tests.
include(StandaloneDRuntimeTests)
|