1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162
163
164
165
166
167
168
169
170
171
172
173
174
175
176
177
178
179
180
181
182
183
184
185
186
187
188
189
190
191
192
193
194
|
package Catmandu::Exporter::CSV;
use Catmandu::Sane;
our $VERSION = '1.2024';
use Text::CSV;
use Moo;
use namespace::clean;
with 'Catmandu::TabularExporter';
has csv => (is => 'lazy');
has quote_char => (is => 'ro', default => sub {'"'});
has escape_char => (is => 'ro', default => sub {'"'});
has always_quote => (is => 'ro');
has quote_space => (is => 'ro');
has sep_char => (
is => 'ro',
default => sub {','},
coerce => sub {
my $sep_char = $_[0];
$sep_char =~ s/(\\[abefnrt])/"qq{$1}"/gee;
return $sep_char;
}
);
sub _build_csv {
my ($self) = @_;
Text::CSV->new(
{
binary => 1,
eol => "\n",
sep_char => $self->sep_char,
always_quote => $self->always_quote,
quote_space => $self->quote_space,
quote_char => $self->quote_char ? $self->quote_char : undef,
escape_char => $self->escape_char ? $self->escape_char : undef,
}
);
}
sub add {
my ($self, $data) = @_;
my $fields = $self->fields;
my $row = [
map {
my $val = $data->{$_} // "";
$val =~ s/\t/\\t/g;
$val =~ s/\n/\\n/g;
$val =~ s/\r/\\r/g;
$val;
} @$fields
];
$self->_print_header;
$self->csv->print($self->fh, $row);
}
sub commit {
my ($self) = @_;
# ensure header gets printed even if there are no records
$self->_print_header;
}
sub _print_header {
my ($self) = @_;
if (!$self->count && $self->header) {
my $row = $self->columns || $self->fields;
$self->csv->print($self->fh, $row) if $row && @$row;
}
}
1;
__END__
=pod
=head1 NAME
Catmandu::Exporter::CSV - a CSV exporter
=head1 SYNOPSIS
# On the command line
$ catmandu convert XSL to CSV < data.xls
$ catmandu convert JSON to CSV --fix myfixes.txt --sep_char ';' < data.json
# Provide a hint to the exporter which fields to export from the JSON
# input. By default the CSV exporter will export the fields that are
# found in the first JSON record.
$ catmandu convert JSON to CSV --fields "id,title,year" < data.json
# In a Perl script
use Catmandu;
my $exporter = Catmandu->exporter('CSV',
fix => 'myfix.txt',
quote_char => '"',
sep_char => ',',
escape_char => '"' ,
always_quote => 1,
header => 1);
$exporter->fields("f1,f2,f3");
$exporter->fields([qw(f1 f2 f3)]);
$exporter->add_many($arrayref);
$exporter->add_many($iterator);
$exporter->add_many(sub { });
$exporter->add($hashref);
printf "exported %d items\n" , $exporter->count;
=head1 DESCRIPTION
This C<Catmandu::Exporter> exports items as rows with comma-separated values
(CSV). Serialization is based on L<Text::CSV>. A header line with field names
will be included if option C<header> is set. See L<Catmandu::TabularExporter>
on how to configure the field mapping and column names. Newlines and tabulator
values in field values are escaped as C<\n>, C<\r>, and C<\t>.
Hint: by default, the exporter will output all the fields that are found in the
first record of the data input. This can be changed by setting the C<fields>
option of the exporter.
=head1 CONFIGURATION
=over
=item file
Write output to a local file given by its path or file handle. Alternatively a
scalar reference can be passed to write to a string and a code reference can be
used to write to a callback function.
=item fh
Write the output to an L<IO::Handle>. If not specified,
L<Catmandu::Util::io|Catmandu::Util/IO-functions> is used to create the output
handle from the C<file> argument or by using STDOUT.
=item fix
An ARRAY of one or more fixes or file scripts to be applied to exported items.
=item encoding
Binmode of the output stream C<fh>. Set to "C<:utf8>" by default.
=item sep_char
Column separator (C<,> by default)
=item quote_char
Quotation character (C<"> by default)
=item escape_char
Character for escaping inside quoted field (C<"> by default)
=item fields
See L<Catmandu::TabularExporter>.
=item columns
See L<Catmandu::TabularExporter>.
=item header
Include a header line with column names. Enabled by default.
=back
=head1 METHODS
See L<Catmandu::TabularExporter>, L<Catmandu::Exporter>, L<Catmandu::Addable>,
L<Catmandu::Fixable>, L<Catmandu::Counter>, and L<Catmandu::Logger> for a full
list of methods.
=head1 SEE ALSO
L<Catmandu::Importer::CSV>, L<Catmandu::Exporter::Table>
L<Catmandu::Exporter::XLS>
=cut
|
