File: DistINI.pm

package info (click to toggle)
libdist-zilla-perl 6.012-1
  • links: PTS, VCS
  • area: main
  • in suites: buster, sid
  • size: 1,668 kB
  • sloc: perl: 6,968; makefile: 9; sh: 6
file content (172 lines) | stat: -rw-r--r-- 4,075 bytes parent folder | download
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162
163
164
165
166
167
168
169
170
171
172
package Dist::Zilla::Plugin::DistINI 6.012;
# ABSTRACT: a plugin to add a dist.ini to newly-minted dists

use Moose;
with qw(Dist::Zilla::Role::FileGatherer);

use Dist::Zilla::File::FromCode;

use MooseX::Types::Moose qw(ArrayRef Str);
use Dist::Zilla::Path;

use namespace::autoclean;

#pod =head1 DESCRIPTION
#pod
#pod This plugins produces a F<dist.ini> file in a new dist, specifying the required
#pod core attributes from the dist being minted.
#pod
#pod This plugin is dead simple and pretty stupid, but should get better as dist
#pod minting facilities improve.  For example, it will not specify any plugins.
#pod
#pod In the meantime, you may be happier with a F<dist.ini> template.
#pod
#pod =attr append_file
#pod
#pod This parameter may be a filename in the profile's directory to append to the
#pod generated F<dist.ini> with things like plugins.  In other words, if your make
#pod this file, called F<plugins.ini>:
#pod
#pod   [@Basic]
#pod   [NextRelease]
#pod   [@Git]
#pod
#pod ...and your F<profile.ini> includes:
#pod
#pod   [DistINI]
#pod   append_file = plugins.ini
#pod
#pod ...then the generated C<dist.ini> in a newly-minted dist will look something
#pod like this:
#pod
#pod   name    = My-New-Dist
#pod   author  = E. Xavier Ample <example@example.com>
#pod   license = Perl_5
#pod   copyright_holder = E. Xavier Ample
#pod   copyright_year   = 2010
#pod
#pod   [@Basic]
#pod   [NextRelease]
#pod   [@Git]
#pod
#pod =cut

sub mvp_multivalue_args { qw(append_file) }

has append_file => (
  is  => 'ro',
  isa => ArrayRef[ Str ],
  default => sub { [] },
);

sub gather_files {
  my ($self, $arg) = @_;

  my $zilla = $self->zilla;

  my $postlude = '';

  for (@{ $self->append_file }) {
    my $fn = $self->zilla->root->child($_);

    $postlude .= path($fn)->slurp_utf8;
  }

  my $code = sub {
    my @core_attrs = qw(name authors copyright_holder);

    my $license = ref $zilla->license;
    if ($license =~ /^Software::License::(.+)$/) {
      $license = $1;
    } else {
      $license = "=$license";
    }

    my $content = '';
    $content .= sprintf "name    = %s\n", $zilla->name;
    $content .= sprintf "author  = %s\n", $_ for @{ $zilla->authors };
    $content .= sprintf "license = %s\n", $license;
    $content .= sprintf "copyright_holder = %s\n", $zilla->copyright_holder;
    $content .= sprintf "copyright_year   = %s\n", (localtime($ENV{SOURCE_DATE_EPOCH} || time))[5] + 1900;
    $content .= "\n";

    $content .= $postlude;
  };

  my $file = Dist::Zilla::File::FromCode->new({
    name => 'dist.ini',
    code => $code,
  });

  $self->add_file($file);
}

__PACKAGE__->meta->make_immutable;
1;

__END__

=pod

=encoding UTF-8

=head1 NAME

Dist::Zilla::Plugin::DistINI - a plugin to add a dist.ini to newly-minted dists

=head1 VERSION

version 6.012

=head1 DESCRIPTION

This plugins produces a F<dist.ini> file in a new dist, specifying the required
core attributes from the dist being minted.

This plugin is dead simple and pretty stupid, but should get better as dist
minting facilities improve.  For example, it will not specify any plugins.

In the meantime, you may be happier with a F<dist.ini> template.

=head1 ATTRIBUTES

=head2 append_file

This parameter may be a filename in the profile's directory to append to the
generated F<dist.ini> with things like plugins.  In other words, if your make
this file, called F<plugins.ini>:

  [@Basic]
  [NextRelease]
  [@Git]

...and your F<profile.ini> includes:

  [DistINI]
  append_file = plugins.ini

...then the generated C<dist.ini> in a newly-minted dist will look something
like this:

  name    = My-New-Dist
  author  = E. Xavier Ample <example@example.com>
  license = Perl_5
  copyright_holder = E. Xavier Ample
  copyright_year   = 2010

  [@Basic]
  [NextRelease]
  [@Git]

=head1 AUTHOR

Ricardo SIGNES 😏 <rjbs@cpan.org>

=head1 COPYRIGHT AND LICENSE

This software is copyright (c) 2018 by Ricardo SIGNES.

This is free software; you can redistribute it and/or modify it under
the same terms as the Perl 5 programming language system itself.

=cut