1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
|
TEMPLATE = lib
TARGET = drumstick-widgets
DESTDIR = ../../build/lib
DEPENDPATH += . ../include
INCLUDEPATH += . ../include
include (../../global.pri)
CONFIG += c++11 qt create_pc create_prl no_install_prl lrelease
static {
CONFIG += staticlib
}
LRELEASE_DIR=.
DEFINES += drumstick_widgets_EXPORTS ENABLE_NETWORK
QMAKE_CXXFLAGS += $$QMAKE_CXXFLAGS_HIDESYMS
QMAKE_PKGCONFIG_PREFIX = $$INSTALLBASE
QT += widgets network
LIBS += -L$$OUT_PWD/../../build/lib -ldrumstick-rt
FORMS += \
fluidsettingsdialog.ui \
networksettingsdialog.ui
HEADERS += \
../include/drumstick/pianokeybd.h \
../include/drumstick/pianopalette.h \
../include/drumstick/rtmidiinput.h \
../include/drumstick/rtmidioutput.h \
../include/drumstick/configurationdialogs.h \
../include/drumstick/settingsfactory.h \
pianoscene.h \
pianokey.h \
keylabel.h \
fluidsettingsdialog.h \
networksettingsdialog.h
SOURCES += \
configurationdialogs.cpp \
pianokey.cpp \
pianokeybd.cpp \
pianoscene.cpp \
pianopalette.cpp \
keylabel.cpp \
fluidsettingsdialog.cpp \
networksettingsdialog.cpp \
settingsfactory.cpp
RESOURCES += pianokeybd.qrc
TRANSLATIONS += \
translations/drumstick-widgets_en.ts \
translations/drumstick-widgets_cs.ts \
translations/drumstick-widgets_de.ts \
translations/drumstick-widgets_es.ts \
translations/drumstick-widgets_fr.ts \
translations/drumstick-widgets_gl.ts \
translations/drumstick-widgets_it.ts \
translations/drumstick-widgets_nl.ts \
translations/drumstick-widgets_ru.ts \
translations/drumstick-widgets_sr.ts \
translations/drumstick-widgets_sv.ts \
translations/drumstick-widgets_tr.ts \
translations/drumstick-widgets_zh_CN.ts
macx {
FORMS += macsynthsettingsdialog.ui
HEADERS += macsynthsettingsdialog.h
SOURCES += macsynthsettingsdialog.cpp
}
linux {
FORMS += sonivoxsettingsdialog.ui
HEADERS += sonivoxsettingsdialog.h
SOURCES += sonivoxsettingsdialog.cpp
}
macx:!static {
TARGET = drumstick-widgets
CONFIG += lib_bundle
FRAMEWORK_HEADERS.version = Versions
FRAMEWORK_HEADERS.files = $$HEADERS
FRAMEWORK_HEADERS.path = Headers/drumstick
QMAKE_BUNDLE_DATA += FRAMEWORK_HEADERS
#QMAKE_LFLAGS_SONAME = -Wl,-install_name,@executable_path/../Frameworks/
QMAKE_SONAME_PREFIX = @rpath
QMAKE_TARGET_BUNDLE_PREFIX = net.sourceforge
QMAKE_BUNDLE = drumstick-widgets
QMAKE_INFO_PLIST = ../Info.plist.lib
}
packagesExist(fluidsynth) {
DEFINES += ENABLE_FLUIDSYNTH
}
packagesExist(libpulse-simple):packagesExist(sonivox) {
DEFINES += ENABLE_SONIVOX
}
|
