1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162
163
164
165
166
167
168
169
170
171
172
173
174
175
176
177
178
179
180
181
182
183
184
185
186
187
188
189
190
191
192
193
194
195
196
|
package File::ChangeNotify::Watcher::Default;
{
$File::ChangeNotify::Watcher::Default::VERSION = '0.24';
}
use strict;
use warnings;
use namespace::autoclean;
use File::Find qw( finddepth );
use File::Spec;
use Time::HiRes qw( sleep );
# Trying to import this just blows up on Win32, and checking
# Time::HiRes::d_hires_stat() _also_ blows up on Win32.
BEGIN {
eval { Time::HiRes->import('stat') };
}
use Moose;
use MooseX::SemiAffordanceAccessor;
extends 'File::ChangeNotify::Watcher';
has _map => (
is => 'rw',
isa => 'HashRef',
default => sub { {} },
);
sub sees_all_events {0}
sub BUILD {
my $self = shift;
$self->_set_map( $self->_build_map() );
}
sub _build_map {
my $self = shift;
my %map;
File::Find::find(
{
wanted => sub {
my $path = $File::Find::name;
if ( $self->_path_is_excluded($path) ) {
$File::Find::prune = 1;
return;
}
my $entry = $self->_entry_for_map($path) or return;
$map{$path} = $entry;
},
follow_fast => ( $self->follow_symlinks() ? 1 : 0 ),
no_chdir => 1,
follow_skip => 2,
},
@{ $self->directories() },
);
return \%map;
}
sub _entry_for_map {
my $self = shift;
my $path = shift;
my $is_dir = -d $path ? 1 : 0;
return if -l $path && !$is_dir;
unless ($is_dir) {
my $filter = $self->filter();
return unless ( File::Spec->splitpath($path) )[2] =~ /$filter/;
}
return {
is_dir => $is_dir,
mtime => _mtime(*_),
size => ( $is_dir ? 0 : -s _ ),
};
}
# It seems that Time::HiRes's stat does not act exactly like the
# built-in, so if I do ( stat _ )[9] it will not work (grr).
sub _mtime {
my @stat = stat;
return $stat[9];
}
sub wait_for_events {
my $self = shift;
while (1) {
my @events = $self->_interesting_events();
return @events if @events;
sleep $self->sleep_interval();
}
}
sub _interesting_events {
my $self = shift;
my @interesting;
my $old_map = $self->_map();
my $new_map = $self->_build_map();
for my $path ( sort keys %{$old_map} ) {
if ( !exists $new_map->{$path} ) {
if ( $old_map->{$path}{is_dir} ) {
$self->_remove_directory($path);
}
push @interesting, $self->event_class()->new(
path => $path,
type => 'delete',
);
}
elsif (
!$old_map->{$path}{is_dir}
&& ( $old_map->{$path}{mtime} != $new_map->{$path}{mtime}
|| $old_map->{$path}{size} != $new_map->{$path}{size} )
) {
push @interesting, $self->event_class()->new(
path => $path,
type => 'modify',
);
}
}
for my $path ( sort grep { !exists $old_map->{$_} } keys %{$new_map} ) {
if ( -d $path ) {
push @interesting, $self->event_class()->new(
path => $path,
type => 'create',
),
;
}
else {
push @interesting, $self->event_class()->new(
path => $path,
type => 'create',
);
}
}
$self->_set_map($new_map);
return @interesting;
}
__PACKAGE__->meta()->make_immutable();
1;
# ABSTRACT: Fallback default watcher subclass
__END__
=pod
=head1 NAME
File::ChangeNotify::Watcher::Default - Fallback default watcher subclass
=head1 VERSION
version 0.24
=head1 DESCRIPTION
This class implements watching by comparing two snapshots of the filesystem
tree. It if inefficient and dumb, and so it is the subclass of last resort.
Its C<< $watcher->wait_for_events() >> method sleeps between
comparisons of the filesystem snapshot it takes.
=head1 AUTHOR
Dave Rolsky <autarch@urth.org>
=head1 COPYRIGHT AND LICENSE
This software is Copyright (c) 2013 by Dave Rolsky.
This is free software, licensed under:
The Artistic License 2.0 (GPL Compatible)
=cut
|
