1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162
163
164
165
166
167
168
169
170
171
172
173
174
175
176
177
178
179
180
181
182
183
184
185
186
187
188
189
190
191
192
193
194
195
196
197
198
199
200
201
202
203
204
205
206
207
208
209
210
211
212
213
214
215
216
217
218
219
220
221
222
223
224
225
226
227
228
229
230
231
232
233
234
235
236
237
238
239
240
241
242
243
244
245
246
247
248
249
250
251
252
253
254
255
256
257
258
259
260
261
262
263
264
265
266
267
268
269
270
271
272
273
274
275
276
277
278
279
280
281
282
283
284
285
286
287
288
289
290
291
292
293
294
295
296
297
298
299
300
301
302
|
SUBROUTINE CTIMGB( LINE, NM, MVAL, NK, KVAL, NNS, NSVAL, NNB,
$ NBVAL, NLDA, LDAVAL, TIMMIN, A, B, IWORK,
$ RESLTS, LDR1, LDR2, LDR3, NOUT )
*
* -- LAPACK timing routine (version 3.0) --
* Univ. of Tennessee, Univ. of California Berkeley, NAG Ltd.,
* Courant Institute, Argonne National Lab, and Rice University
* March 31, 1993
*
* .. Scalar Arguments ..
CHARACTER*80 LINE
INTEGER LDR1, LDR2, LDR3, NK, NLDA, NM, NNB, NNS, NOUT
REAL TIMMIN
* ..
* .. Array Arguments ..
INTEGER IWORK( * ), KVAL( * ), LDAVAL( * ), MVAL( * ),
$ NBVAL( * ), NSVAL( * )
REAL RESLTS( LDR1, LDR2, LDR3, * )
COMPLEX A( * ), B( * )
* ..
*
* Purpose
* =======
*
* CTIMGB times CGBTRF and -TRS.
*
* Arguments
* =========
*
* LINE (input) CHARACTER*80
* The input line that requested this routine. The first six
* characters contain either the name of a subroutine or a
* generic path name. The remaining characters may be used to
* specify the individual routines to be timed. See ATIMIN for
* a full description of the format of the input line.
*
* NM (input) INTEGER
* The number of values of M contained in the vector MVAL.
*
* MVAL (input) INTEGER array, dimension (NM)
* The values of the matrix size M.
*
* NK (input) INTEGER
* The number of values of K contained in the vector KVAL.
*
* KVAL (input) INTEGER array, dimension (NK)
* The values of the band width K.
*
* NNS (input) INTEGER
* The number of values of NRHS contained in the vector NSVAL.
*
* NSVAL (input) INTEGER array, dimension (NNS)
* The values of the number of right hand sides NRHS.
*
* NNB (input) INTEGER
* The number of values of NB contained in the vector NBVAL.
*
* NBVAL (input) INTEGER array, dimension (NNB)
* The values of the blocksize NB.
*
* NLDA (input) INTEGER
* The number of values of LDA contained in the vector LDAVAL.
*
* LDAVAL (input) INTEGER array, dimension (NLDA)
* The values of the leading dimension of the array A.
*
* TIMMIN (input) REAL
* The minimum time a subroutine will be timed.
*
* A (workspace) COMPLEX array, dimension (LDAMAX*NMAX)
* where LDAMAX and NMAX are the maximum values permitted
* for LDA and N.
*
* B (workspace) COMPLEX array, dimension (LDAMAX*NMAX)
*
* IWORK (workspace) INTEGER array, dimension (NMAX)
*
* RESLTS (output) REAL array, dimension
* (LDR1,LDR2,LDR3,NSUBS)
* The timing results for each subroutine over the relevant
* values of N, K, NB, and LDA.
*
* LDR1 (input) INTEGER
* The first dimension of RESLTS. LDR1 >= max(4,NNB).
*
* LDR2 (input) INTEGER
* The second dimension of RESLTS. LDR2 >= max(1,NK).
*
* LDR3 (input) INTEGER
* The third dimension of RESLTS. LDR3 >= max(1,NLDA).
*
* NOUT (input) INTEGER
* The unit number for output.
*
* =====================================================================
*
* .. Parameters ..
INTEGER NSUBS
PARAMETER ( NSUBS = 2 )
* ..
* .. Local Scalars ..
CHARACTER*3 PATH
CHARACTER*6 CNAME
INTEGER I, IC, ICL, IK, ILDA, IM, INB, INFO, ISUB, K,
$ KL, KU, LDA, LDB, M, N, NB, NRHS
REAL OPS, S1, S2, TIME, UNTIME
* ..
* .. Local Arrays ..
LOGICAL TIMSUB( NSUBS )
CHARACTER*6 SUBNAM( NSUBS )
* ..
* .. External Functions ..
REAL SECOND, SMFLOP, SOPGB, SOPLA
EXTERNAL SECOND, SMFLOP, SOPGB, SOPLA
* ..
* .. External Subroutines ..
EXTERNAL ATIMCK, ATIMIN, CGBTRF, CGBTRS, CTIMMG, SPRTBL,
$ XLAENV
* ..
* .. Intrinsic Functions ..
INTRINSIC MAX, MIN, REAL
* ..
* .. Data statements ..
DATA SUBNAM / 'CGBTRF', 'CGBTRS' /
* ..
* .. Executable Statements ..
*
* Extract the timing request from the input line.
*
PATH( 1: 1 ) = 'Complex precision'
PATH( 2: 3 ) = 'GB'
CALL ATIMIN( PATH, LINE, NSUBS, SUBNAM, TIMSUB, NOUT, INFO )
IF( INFO.NE.0 )
$ GO TO 120
*
* Check that 3*K+1 <= LDA for the input values.
*
CNAME = LINE( 1: 6 )
CALL ATIMCK( 0, CNAME, NK, KVAL, NLDA, LDAVAL, NOUT, INFO )
IF( INFO.GT.0 ) THEN
WRITE( NOUT, FMT = 9999 )CNAME
GO TO 120
END IF
*
* Do for each value of the matrix size M:
*
DO 110 IM = 1, NM
M = MVAL( IM )
N = M
*
* Do for each value of LDA:
*
DO 80 ILDA = 1, NLDA
LDA = LDAVAL( ILDA )
*
* Do for each value of the band width K:
*
DO 70 IK = 1, NK
K = KVAL( IK )
KL = MAX( 0, MIN( K, M-1 ) )
KU = MAX( 0, MIN( K, N-1 ) )
*
* Time CGBTRF
*
IF( TIMSUB( 1 ) ) THEN
*
* Do for each value of NB in NBVAL. Only CGBTRF is
* timed in this loop since the other routines are
* independent of NB.
*
DO 30 INB = 1, NNB
NB = NBVAL( INB )
CALL XLAENV( 1, NB )
IC = 0
CALL CTIMMG( 2, M, N, A, LDA, KL, KU )
S1 = SECOND( )
10 CONTINUE
CALL CGBTRF( M, N, KL, KU, A, LDA, IWORK, INFO )
S2 = SECOND( )
TIME = S2 - S1
IC = IC + 1
IF( TIME.LT.TIMMIN ) THEN
CALL CTIMMG( 2, M, N, A, LDA, KL, KU )
GO TO 10
END IF
*
* Subtract the time used in CTIMMG.
*
ICL = 1
S1 = SECOND( )
20 CONTINUE
S2 = SECOND( )
UNTIME = S2 - S1
ICL = ICL + 1
IF( ICL.LE.IC ) THEN
CALL CTIMMG( 2, M, N, A, LDA, KL, KU )
GO TO 20
END IF
*
TIME = ( TIME-UNTIME ) / REAL( IC )
OPS = SOPGB( 'CGBTRF', M, N, KL, KU, IWORK )
RESLTS( INB, IK, ILDA, 1 ) = SMFLOP( OPS, TIME,
$ INFO )
30 CONTINUE
ELSE
IC = 0
CALL CTIMMG( 2, M, N, A, LDA, KL, KU )
END IF
*
* Generate another matrix and factor it using CGBTRF so
* that the factored form can be used in timing the other
* routines.
*
NB = 1
CALL XLAENV( 1, NB )
IF( IC.NE.1 )
$ CALL CGBTRF( M, N, KL, KU, A, LDA, IWORK, INFO )
*
* Time CGBTRS
*
IF( TIMSUB( 2 ) ) THEN
DO 60 I = 1, NNS
NRHS = NSVAL( I )
LDB = N
IC = 0
CALL CTIMMG( 0, N, NRHS, B, LDB, 0, 0 )
S1 = SECOND( )
40 CONTINUE
CALL CGBTRS( 'No transpose', N, KL, KU, NRHS, A,
$ LDA, IWORK, B, LDB, INFO )
S2 = SECOND( )
TIME = S2 - S1
IC = IC + 1
IF( TIME.LT.TIMMIN ) THEN
CALL CTIMMG( 0, N, NRHS, B, LDB, 0, 0 )
GO TO 40
END IF
*
* Subtract the time used in CTIMMG.
*
ICL = 1
S1 = SECOND( )
50 CONTINUE
S2 = SECOND( )
UNTIME = S2 - S1
ICL = ICL + 1
IF( ICL.LE.IC ) THEN
CALL CTIMMG( 0, N, NRHS, B, LDB, 0, 0 )
GO TO 50
END IF
*
TIME = ( TIME-UNTIME ) / REAL( IC )
OPS = SOPLA( 'CGBTRS', N, NRHS, KL, KU, 0 )
RESLTS( I, IK, ILDA, 2 ) = SMFLOP( OPS, TIME,
$ INFO )
60 CONTINUE
END IF
70 CONTINUE
80 CONTINUE
*
* Print a table of results for each routine
*
DO 100 ISUB = 1, NSUBS
IF( .NOT.TIMSUB( ISUB ) )
$ GO TO 100
*
* Print header for routine names.
*
IF( IM.EQ.1 .OR. CNAME.EQ.'CGB ' ) THEN
WRITE( NOUT, FMT = 9998 )SUBNAM( ISUB )
IF( NLDA.EQ.1 ) THEN
WRITE( NOUT, FMT = 9997 )LDAVAL( 1 )
ELSE
DO 90 I = 1, NLDA
WRITE( NOUT, FMT = 9996 )I, LDAVAL( I )
90 CONTINUE
END IF
END IF
*
WRITE( NOUT, FMT = 9995 )SUBNAM( ISUB ), N
IF( ISUB.EQ.1 ) THEN
CALL SPRTBL( 'NB', 'K', NNB, NBVAL, NK, KVAL, NLDA,
$ RESLTS( 1, 1, 1, 1 ), LDR1, LDR2, NOUT )
ELSE IF( ISUB.EQ.2 ) THEN
CALL SPRTBL( 'NRHS', 'K', NNS, NSVAL, NK, KVAL, NLDA,
$ RESLTS( 1, 1, 1, 2 ), LDR1, LDR2, NOUT )
END IF
100 CONTINUE
110 CONTINUE
120 CONTINUE
*
9999 FORMAT( 1X, A6, ' timing run not attempted', / )
9998 FORMAT( / ' *** Speed of ', A6, ' in megaflops ***' )
9997 FORMAT( 5X, 'with LDA = ', I5 )
9996 FORMAT( 5X, 'line ', I2, ' with LDA = ', I5 )
9995 FORMAT( / 5X, A6, ' with M =', I6, / )
*
RETURN
*
* End of CTIMGB
*
END
|
