1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162
163
164
165
166
167
168
169
170
171
172
173
174
175
176
177
178
179
180
181
182
183
184
185
186
187
188
189
190
191
192
193
194
195
196
197
198
199
200
201
202
203
204
205
206
207
208
209
210
211
212
213
214
215
216
217
218
219
220
221
222
223
224
225
226
227
228
229
230
231
232
233
234
235
236
237
238
239
240
241
242
243
244
245
246
247
248
249
250
251
252
253
254
255
256
257
258
259
260
261
262
263
264
265
266
267
268
269
270
271
272
273
274
275
276
277
278
279
280
281
282
283
284
285
286
287
288
289
290
291
292
293
294
295
296
297
298
299
300
301
302
303
304
305
306
307
308
309
310
311
312
313
314
315
|
SUBROUTINE DTIMGE( LINE, NM, MVAL, NNS, NSVAL, NNB, NBVAL, NLDA,
$ LDAVAL, TIMMIN, A, B, WORK, IWORK, RESLTS,
$ LDR1, LDR2, LDR3, NOUT )
*
* -- LAPACK timing routine (version 3.0) --
* Univ. of Tennessee, Univ. of California Berkeley, NAG Ltd.,
* Courant Institute, Argonne National Lab, and Rice University
* March 31, 1993
*
* .. Scalar Arguments ..
CHARACTER*80 LINE
INTEGER LDR1, LDR2, LDR3, NLDA, NM, NNB, NNS, NOUT
DOUBLE PRECISION TIMMIN
* ..
* .. Array Arguments ..
INTEGER IWORK( * ), LDAVAL( * ), MVAL( * ), NBVAL( * ),
$ NSVAL( * )
DOUBLE PRECISION A( * ), B( * ), RESLTS( LDR1, LDR2, LDR3, * ),
$ WORK( * )
* ..
*
* Purpose
* =======
*
* DTIMGE times DGETRF, -TRS, and -TRI.
*
* Arguments
* =========
*
* LINE (input) CHARACTER*80
* The input line that requested this routine. The first six
* characters contain either the name of a subroutine or a
* generic path name. The remaining characters may be used to
* specify the individual routines to be timed. See ATIMIN for
* a full description of the format of the input line.
*
* NM (input) INTEGER
* The number of values of M contained in the vector MVAL.
*
* MVAL (input) INTEGER array, dimension (NM)
* The values of the matrix size M.
*
* NNS (input) INTEGER
* The number of values of NRHS contained in the vector NSVAL.
*
* NSVAL (input) INTEGER array, dimension (NNS)
* The values of the number of right hand sides NRHS.
*
* NNB (input) INTEGER
* The number of values of NB contained in the vector NBVAL.
*
* NBVAL (input) INTEGER array, dimension (NNB)
* The values of the blocksize NB.
*
* NLDA (input) INTEGER
* The number of values of LDA contained in the vector LDAVAL.
*
* LDAVAL (input) INTEGER array, dimension (NLDA)
* The values of the leading dimension of the array A.
*
* TIMMIN (input) DOUBLE PRECISION
* The minimum time a subroutine will be timed.
*
* A (workspace) DOUBLE PRECISION array, dimension (LDAMAX*NMAX)
* where LDAMAX and NMAX are the maximum values permitted
* for LDA and N.
*
* B (workspace) DOUBLE PRECISION array, dimension (LDAMAX*NMAX)
*
* WORK (workspace) DOUBLE PRECISION array, dimension (LDAMAX*NBMAX)
* where NBMAX is the maximum value of the block size NB.
*
* IWORK (workspace) INTEGER array, dimension (NMAX)
*
* RESLTS (output) DOUBLE PRECISION array, dimension
* (LDR1,LDR2,LDR3,NSUBS)
* The timing results for each subroutine over the relevant
* values of N and NB.
*
* LDR1 (input) INTEGER
* The first dimension of RESLTS. LDR1 >= max(4,NNB).
*
* LDR2 (input) INTEGER
* The second dimension of RESLTS. LDR2 >= max(1,NM).
*
* LDR3 (input) INTEGER
* The third dimension of RESLTS. LDR3 >= max(1,NLDA).
*
* NOUT (input) INTEGER
* The unit number for output.
*
* =====================================================================
*
* .. Parameters ..
INTEGER NSUBS
PARAMETER ( NSUBS = 3 )
* ..
* .. Local Scalars ..
CHARACTER*3 PATH
CHARACTER*6 CNAME
INTEGER I, IC, ICL, ILDA, IM, INB, INFO, ISUB, LDA,
$ LDB, M, N, NB, NRHS
DOUBLE PRECISION OPS, S1, S2, TIME, UNTIME
* ..
* .. Local Arrays ..
LOGICAL TIMSUB( NSUBS )
CHARACTER*6 SUBNAM( NSUBS )
* ..
* .. External Functions ..
DOUBLE PRECISION DMFLOP, DOPLA, DSECND
EXTERNAL DMFLOP, DOPLA, DSECND
* ..
* .. External Subroutines ..
EXTERNAL ATIMCK, ATIMIN, DGETRF, DGETRI, DGETRS, DLACPY,
$ DPRTBL, DTIMMG, XLAENV
* ..
* .. Intrinsic Functions ..
INTRINSIC DBLE
* ..
* .. Data statements ..
DATA SUBNAM / 'DGETRF', 'DGETRS', 'DGETRI' /
* ..
* .. Executable Statements ..
*
* Extract the timing request from the input line.
*
PATH( 1: 1 ) = 'Double precision'
PATH( 2: 3 ) = 'GE'
CALL ATIMIN( PATH, LINE, NSUBS, SUBNAM, TIMSUB, NOUT, INFO )
IF( INFO.NE.0 )
$ GO TO 130
*
* Check that N <= LDA for the input values.
*
CNAME = LINE( 1: 6 )
CALL ATIMCK( 2, CNAME, NM, MVAL, NLDA, LDAVAL, NOUT, INFO )
IF( INFO.GT.0 ) THEN
WRITE( NOUT, FMT = 9999 )CNAME
GO TO 130
END IF
*
* Do for each value of M:
*
DO 100 IM = 1, NM
*
M = MVAL( IM )
N = M
*
* Do for each value of LDA:
*
DO 90 ILDA = 1, NLDA
LDA = LDAVAL( ILDA )
*
* Do for each value of NB in NBVAL. Only the blocked
* routines are timed in this loop since the other routines
* are independent of NB.
*
DO 50 INB = 1, NNB
NB = NBVAL( INB )
CALL XLAENV( 1, NB )
*
* Time DGETRF
*
IF( TIMSUB( 1 ) ) THEN
CALL DTIMMG( 1, M, N, A, LDA, 0, 0 )
IC = 0
S1 = DSECND( )
10 CONTINUE
CALL DGETRF( M, N, A, LDA, IWORK, INFO )
S2 = DSECND( )
TIME = S2 - S1
IC = IC + 1
IF( TIME.LT.TIMMIN ) THEN
CALL DTIMMG( 1, M, N, A, LDA, 0, 0 )
GO TO 10
END IF
*
* Subtract the time used in DTIMMG.
*
ICL = 1
S1 = DSECND( )
20 CONTINUE
S2 = DSECND( )
UNTIME = S2 - S1
ICL = ICL + 1
IF( ICL.LE.IC ) THEN
CALL DTIMMG( 1, M, N, A, LDA, 0, 0 )
GO TO 20
END IF
*
TIME = ( TIME-UNTIME ) / DBLE( IC )
OPS = DOPLA( 'DGETRF', M, N, 0, 0, NB )
RESLTS( INB, IM, ILDA, 1 ) = DMFLOP( OPS, TIME, INFO )
*
ELSE
IC = 0
CALL DTIMMG( 1, M, N, A, LDA, 0, 0 )
END IF
*
* Generate another matrix and factor it using DGETRF so
* that the factored form can be used in timing the other
* routines.
*
IF( IC.NE.1 )
$ CALL DGETRF( M, N, A, LDA, IWORK, INFO )
*
* Time DGETRI
*
IF( TIMSUB( 3 ) ) THEN
CALL DLACPY( 'Full', M, M, A, LDA, B, LDA )
IC = 0
S1 = DSECND( )
30 CONTINUE
CALL DGETRI( M, B, LDA, IWORK, WORK, LDA*NB, INFO )
S2 = DSECND( )
TIME = S2 - S1
IC = IC + 1
IF( TIME.LT.TIMMIN ) THEN
CALL DLACPY( 'Full', M, M, A, LDA, B, LDA )
GO TO 30
END IF
*
* Subtract the time used in DLACPY.
*
ICL = 1
S1 = DSECND( )
40 CONTINUE
S2 = DSECND( )
UNTIME = S2 - S1
ICL = ICL + 1
IF( ICL.LE.IC ) THEN
CALL DLACPY( 'Full', M, M, A, LDA, B, LDA )
GO TO 40
END IF
*
TIME = ( TIME-UNTIME ) / DBLE( IC )
OPS = DOPLA( 'DGETRI', M, M, 0, 0, NB )
RESLTS( INB, IM, ILDA, 3 ) = DMFLOP( OPS, TIME, INFO )
END IF
50 CONTINUE
*
* Time DGETRS
*
IF( TIMSUB( 2 ) ) THEN
DO 80 I = 1, NNS
NRHS = NSVAL( I )
LDB = LDA
CALL DTIMMG( 0, M, NRHS, B, LDB, 0, 0 )
IC = 0
S1 = DSECND( )
60 CONTINUE
CALL DGETRS( 'No transpose', M, NRHS, A, LDA, IWORK,
$ B, LDB, INFO )
S2 = DSECND( )
TIME = S2 - S1
IC = IC + 1
IF( TIME.LT.TIMMIN ) THEN
CALL DTIMMG( 0, M, NRHS, B, LDB, 0, 0 )
GO TO 60
END IF
*
* Subtract the time used in DTIMMG.
*
ICL = 1
S1 = DSECND( )
70 CONTINUE
S2 = DSECND( )
UNTIME = S2 - S1
ICL = ICL + 1
IF( ICL.LE.IC ) THEN
CALL DTIMMG( 0, M, NRHS, B, LDB, 0, 0 )
GO TO 70
END IF
*
TIME = ( TIME-UNTIME ) / DBLE( IC )
OPS = DOPLA( 'DGETRS', M, NRHS, 0, 0, 0 )
RESLTS( I, IM, ILDA, 2 ) = DMFLOP( OPS, TIME, INFO )
80 CONTINUE
END IF
90 CONTINUE
100 CONTINUE
*
* Print a table of results for each timed routine.
*
DO 120 ISUB = 1, NSUBS
IF( .NOT.TIMSUB( ISUB ) )
$ GO TO 120
WRITE( NOUT, FMT = 9998 )SUBNAM( ISUB )
IF( NLDA.GT.1 ) THEN
DO 110 I = 1, NLDA
WRITE( NOUT, FMT = 9997 )I, LDAVAL( I )
110 CONTINUE
END IF
WRITE( NOUT, FMT = * )
IF( ISUB.EQ.1 ) THEN
CALL DPRTBL( 'NB', 'N', NNB, NBVAL, NM, MVAL, NLDA, RESLTS,
$ LDR1, LDR2, NOUT )
ELSE IF( ISUB.EQ.2 ) THEN
CALL DPRTBL( 'NRHS', 'N', NNS, NSVAL, NM, MVAL, NLDA,
$ RESLTS( 1, 1, 1, 2 ), LDR1, LDR2, NOUT )
ELSE IF( ISUB.EQ.3 ) THEN
CALL DPRTBL( 'NB', 'N', NNB, NBVAL, NM, MVAL, NLDA,
$ RESLTS( 1, 1, 1, 3 ), LDR1, LDR2, NOUT )
END IF
120 CONTINUE
*
130 CONTINUE
9999 FORMAT( 1X, A6, ' timing run not attempted', / )
9998 FORMAT( / ' *** Speed of ', A6, ' in megaflops ***' )
9997 FORMAT( 5X, 'line ', I2, ' with LDA = ', I5 )
RETURN
*
* End of DTIMGE
*
END
|
